📄 legendboxmultiple.aspx
字号:
<%@ Page Language="VB" Description="dotnetCHARTING Component" %>
<%@ Register TagPrefix="dotnet" Namespace="dotnetCHARTING" Assembly="dotnetCHARTING"%>
<%@ Import Namespace="System.Drawing" %>
<HTML>
<HEAD>
<TITLE>.netCHARTING Sample</TITLE>
<script runat="server">
Sub Page_Load(sender As [Object], e As EventArgs)
Chart.Type = ChartType.Combo 'Horizontal;
Chart.Width = Unit.Parse(600)
Chart.Height = Unit.Parse(350)
Chart.TempDirectory = "temp"
Chart.Debug = True
' This sample will demonstrate how multiple chart areas can have their data placed in separate legend boxes.
' By default all the data is placed in the main legend box, however, if you instantiate a legend box for a
' particular chart area, it's data will automatically be placed in it.
' *DYNAMIC DATA NOTE*
' This sample uses random data to populate the chart. To populate
' a chart with database data see the following resources:
' - Classic samples folder
' - Help File > Data Tutorials
' - Sample: features/DataEngine.aspx
Dim mySC As SeriesCollection = getRandomData()
' Set up chart areas. For more info see sample: ChartAreaRelationships.aspx --------------
Dim y1 As New Axis()
Dim y2 As New Axis()
mySC(0).YAxis = y1
mySC(1).YAxis = y1
mySC(2).YAxis = y2
mySC(3).YAxis = y2
Dim ca2 As New ChartArea()
Dim ca3 As New ChartArea()
Dim ca4 As New ChartArea()
Chart.ChartArea.SeriesCollection.Add(mySC(0))
ca2.SeriesCollection.Add(mySC(1))
ca3.SeriesCollection.Add(mySC(2))
ca4.SeriesCollection.Add(mySC(3))
Chart.ExtraChartAreas.Add(ca2)
Chart.ExtraChartAreas.Add(ca3)
Chart.ExtraChartAreas.Add(ca4)
Chart.ChartAreaLayout.Mode = ChartAreaLayoutMode.HorizontalPriority
' --------------
' Now we'll instantiate legend boxes for 2 of our areas. The main chart area already has a legend box.
ca2.LegendBox = New LegendBox()
ca3.LegendBox = New LegendBox()
' Orient the legend boxes in different positions.
ca3.LegendBox.Orientation = dotnetCHARTING.Orientation.Left
ca2.LegendBox.Orientation = dotnetCHARTING.Orientation.Right
Chart.ChartArea.LegendBox.Orientation = dotnetCHARTING.Orientation.Top
' Another option besides instantiating a legend box for a chart area is to instruct the tite box to act as the legend box.
ca4.TitleBox.Position = TitleBoxPosition.FullWithLegend
' This is all that is required, however, to control properties of this legend a box we'll need to instantiate a legend box
' and set them there. We will do so now.
ca4.LegendBox = New LegendBox()
ca4.LegendBox.LabelStyle.Font = New Font("verdana", 8)
' The same can be achieved by setting a font for the default entry
ca4.LegendBox.DefaultEntry.LabelStyle.Font = New Font("verdana", 8)
End Sub 'Page_Load
Function getRandomData() As SeriesCollection
Dim SC As New SeriesCollection()
Dim myR As New Random()
Dim a As Integer
For a = 0 To 3
Dim s As New Series()
s.Name = "Series " & a
Dim b As Integer
For b = 0 To 3
Dim e As New Element()
e.Name = "Element " & b
'e.YValue = -25 + myR.Next(50);
e.YValue = myR.Next(50)
s.Elements.Add(e)
Next b
SC.Add(s)
Next a
' Set Different Colors for our Series
SC(0).DefaultElement.Color = Color.FromArgb(49, 255, 49)
SC(1).DefaultElement.Color = Color.FromArgb(255, 255, 0)
SC(2).DefaultElement.Color = Color.FromArgb(255, 99, 49)
SC(3).DefaultElement.Color = Color.FromArgb(0, 156, 255)
Return SC
End Function 'getRandomData
</script>
</HEAD>
<BODY>
<DIV align="center">
<dotnet:Chart id="Chart" runat="server" Width="568px" Height="344px">
</dotnet:Chart>
</DIV>
</BODY>
</HTML>
⌨️ 快捷键说明
复制代码
Ctrl + C
搜索代码
Ctrl + F
全屏模式
F11
切换主题
Ctrl + Shift + D
显示快捷键
?
增大字号
Ctrl + =
减小字号
Ctrl + -