configure.in

WinCE平台上的语音识别程序

dnl Welcome to the Sphinx automated build system.
dnl try not to hurt yourself ;)

AC_INIT(pocketsphinx, 0.3)
AM_INIT_AUTOMAKE([no-define dist-bzip2 dist-zip])

CFLAGS=${CFLAGS:--g -O2 -Wall}

AC_CANONICAL_HOST

dnl
dnl Set proper compiler flags and such for some platforms
dnl
case $host in
     arm-wince-pe*)
	CFLAGS=${CFLAGS:--march=armv4 -mapcs-32 -malignment-traps}
	LIBS='-lc -lgcc -lwinsock -lcoredll'
	CFLAGS="$CFLAGS -DNEWLIB -DSARM -DWIN32 -DGNUWINCE"
	;;
     *uclinux*)
	# uClinux needs special "flat" binaries
	LDFLAGS="$LDFLAGS -Wl,-elf2flt"
	;;
     *)
     ;;
esac     

AC_ISC_POSIX
AC_PROG_CC
AM_PROG_CC_STDC
AM_PROG_AS
AC_HEADER_STDC
AC_WORDS_BIGENDIAN
AC_TYPE_SIGNAL
AC_CHECK_TYPES(long long)
AC_CHECK_SIZEOF(long long)

dnl
dnl Get SphinxBase source from command line if given
dnl
AC_ARG_WITH(sphinxbase,
	AS_HELP_STRING([--with-sphinxbase=DIRECTORY],
			[look for SphinxBase source files in DIRECTORY]),
			sphinxbase=$withval)

dnl
dnl Get SphinxBase build directory from command line if given
dnl
AC_ARG_WITH(sphinxbase-build,
	AS_HELP_STRING([--with-sphinxbase-build=DIRECTORY],
			[look for SphinxBase object files in DIRECTORY]),
	sphinxbasebuild=$withval)

dnl
dnl Check for installed SphinxBase
dnl FIXME: How do we find the installed headers robustly?
dnl
AC_CHECK_HEADER(sphinxbase/sphinx_config.h,
CPPFLAGS="-I/usr/include/sphinxbase -I/usr/local/include/sphinxbase",[
if test x$sphinxbase = x; then
   # Look for sphinxbase in the parent directory
   for sb in ../sphinxbase*; do
       AC_MSG_CHECKING([for sphinxbase in $sb])
       if test -f "$sb/include/prim_type.h"; then
          sphinxbase="`pwd`/$sb"
	  AC_MSG_RESULT(yes)
       else
	  AC_MSG_RESULT(no)
       fi
   done
fi
])

dnl
dnl Now verify SphinxBase if defined
dnl Sadly, this doesn't work when cross-compiling (for some dumb reason...)
dnl
: ${sphinxbasebuild=$sphinxbase}
if test x$sphinxbase != x && test x$cross_compiling = xyes; then
   CPPFLAGS="-I$sphinxbase/include -I$sphinxbasebuild/include $CPPFLAGS"
   LDFLAGS="$LDFLAGS -L$sphinxbasebuild/src/libsphinxfe -L$sphinxbasebuild/src/libsphinxfeat \
		     -L$sphinxbasebuild/src/libsphinxutil -L$sphinxbasebuild/src/libsphinxad"
fi
if test x$sphinxbase != x && test x$cross_compiling != xyes; then
   AC_CHECK_FILE($sphinxbase/include/prim_type.h,CPPFLAGS="-I$sphinxbase/include $CPPFLAGS",
   AC_ERROR(
[SphinxBase headers not found in $sphinxbase.  Please use the
--with-sphinxbase option to `configure' to specify the location of
SphinxBase.  Run $0 --help for more information.]))
fi
if test x$sphinxbasebuild != x && test x$cross_compiling != xyes; then
   AC_CHECK_FILE($sphinxbasebuild/src/libsphinxutil/libsphinxutil.la,
[CPPFLAGS="-I$sphinxbasebuild/include $CPPFLAGS"
LDFLAGS="$LDFLAGS -L$sphinxbasebuild/src/libsphinxfe -L$sphinxbasebuild/src/libsphinxfeat \
		  -L$sphinxbasebuild/src/libsphinxutil -L$sphinxbasebuild/src/libsphinxad"],
		   AC_ERROR(
[SphinxBase libraries were not found in $sphinxbasebuild.
Use the --with-sphinxbase-build option to `configure' to specify
the build directory for SphinxBase.  Run $0 --help for more information.]))
fi

AC_PATH_PROG(PERL,perl)
AC_PATH_PROG(CSH,csh)
AC_SUBST(PERL)
AC_SUBST(CSH)

AM_PROG_LIBTOOL

AC_OUTPUT([
Makefile
include/Makefile
src/Makefile
src/libpocketsphinx/Makefile
src/programs/Makefile
model/Makefile
model/hmm/Makefile
model/hmm/wsj0/Makefile
model/hmm/tidigits/Makefile
model/lm/Makefile
model/lm/turtle/Makefile
model/lm/swb/Makefile
model/lm/tidigits/Makefile
scripts/Makefile
scripts/pocketsphinx_test
scripts/pocketsphinx_swb
scripts/pocketsphinx_tidigits
test/Makefile
test/testfuncs.sh
test/unit/Makefile
test/regression/Makefile
])

chmod +x scripts/pocketsphinx_test