muadd.asm

PIC子程序大全

;********************MUADD********************
;本程序实现多字节无符号数加法。
;入口参数：被加数首地址在SADR中,加数首地址在DADR中，字节数在CNT中。
;出口参数：结果首地址在SADR中,字节数在CNT中,进位位在STATUS:C中。
;占用资源：W,FSR,020H,021H,022H,023H,028H,029H,一重堆栈。
;说明：    1.程序执行后，被加数被冲掉。

           IFNDEF       MUADD1
            #DEFINE     MUADD1
                        
MUADD       MOVF        SADR,W
            MOVWF       SADRH       ;保护结果首地址
            CLRF        TEMP2       ;进位清零
NEXT1       MOVF        DADR,W
            MOVWF       FSR
            MOVF        INDF,W      ;取出加数
            MOVWF       TEMP1       ;暂存
            MOVF   	SADR,W
            MOVWF       FSR
            MOVF        TEMP1,W
            ADDWF       INDF,F 
            RLF         TEMP2,F     ;暂存当前进位，并使上一次进位前移
            BCF         STATUS,C    ;清除进位
            MOVLW       1
            BTFSC       TEMP2,1
            ADDWF       INDF,F
            BTFSC       STATUS,C    ;加进位位的过程中是否产生了进位
            BSF         TEMP2,0
            INCF        DADR,F           
            INCF        SADR,F
            DECFSZ      CNT,F
            GOTO        NEXT1
            MOVF        SADRH,W
            SUBWF       SADR,W
            MOVWF       CNT         ;恢复字节数
            MOVF        SADRH,W
            MOVWF       SADR        ;结果首地址
            RRF         TEMP2,W     ;进位位放到C中
            RETLW       0
                        
           ENDIF