build.bat

一个j2me游戏代码

REM @ECHO OFF

set JAVA_HOME=Y:\j2sdk1.4.2
set KVEM_HOME=Y:\WTK20
set JDKLIB=%KVEM_HOME%\lib\midpapi.zip

set JAVACOMPL=%JAVA_HOME%\bin\javac
set FLAG=-g:none -O -verbose -deprecation
set JAR=%JAVA_HOME%\bin\jar
set JAVA=%JAVA_HOME%\bin\java
set PREVERIFY=%KVEM_HOME%\bin\preverify

set SRC=.\src
set DES=.\classes
set PRO=.\proguard
set TMP=.\temp
set MF=.\META-INF

set PACKAGE=pop2
set TARGET=POP2V600.jar

MD %SRC%
MD %SRC%\%PACKAGE%
MD %DES%
MD %DES%\%MF%
MD %PRO%
MD %TMP%

REM copy source file
copy ..\src\%PACKAGE%\*.java .\%SRC%\%PACKAGE%

REM copy correct legal texts file
:begin_legal
if /i (%1)==(eu) goto legal_eu
:legal_us
copy /y LegalUS.java .\%SRC%\%PACKAGE%\Legal.java
goto end_legal
:legal_eu
copy /y LegalEU.java .\%SRC%\%PACKAGE%\Legal.java
goto end_legal
:end_legal

REM compile source file, put in dir PRO for shrink & obfuscate
set JAVAC_FLAG=%FLAG% -classpath "%JDKLIB%" -bootclasspath "%JDKLIB%" -d %PRO%
%JAVACOMPL% %JAVAC_FLAG% %SRC%\%PACKAGE%\*.java

REM package class file for proguard
cd %PRO%
%JAR% -cvfM ..\POP2.jar *.*
cd ..

REM shrink & obfuscate class file by ProGuard
REM input package: POP2.jar; output package: POP2Pro.jar
java -jar proguard.jar @POP2V600.pro
del POP2.jar

REM extract shrinked & obfuscated class file for verification
copy POP2Pro.jar .\%TMP%
cd %TMP%
%JAR% -xvf .\POP2Pro.jar 
del POP2Pro.jar
cd ..
del POP2Pro.jar

REM prevify class file after shrink & obfuscate
set PREVE_FLAG=-classpath "%JDKLIB%" 
%PREVERIFY% %PREVE_FLAG% -d %DES% %TMP%

REM copy all resource to destination dir
copy ..\src\*.* .\%DES%

REM create final package 
cd %DES%
del /f /q *.scc
copy ..\MANIFEST.MF .\%MF%
%JAR% cvfM ..\%TARGET% *.*
cd ..

copy manifest.mf POP2V600.jad
..\..\tools\editor\stable\JarSize.exe POP2V600.jar POP2V600.jad

RD /S /Q %TMP%
RD /S /Q %PRO%
RD /S /Q %DES%
RD /S /Q %SRC%

@ECHO ON