page.asp

新闻采集系统1.0.2 For 4.03(2005.05.15更新) 【使用环境】 本系统是基于动易4.03免费版的基础上的新闻采集系统

<%
'=================翻页代码================
Function GetUrl()
Dim strURL,TempURL,i,j,SearchStr,ResultURL,StrParams,StrLeftParams,StrRightParams
SearchStr="page="  
strURL=Request.ServerVariables("URL")  
strURL=split(strURL,"/")  
i=UBound(strURL,1)  
TempURL=strURL(i)'得到当前页文件名  

StrParams=Trim(Request.ServerVariables("QUERY_STRING"))  
IF(StrParams="")THEN  
  ResultURL=TempURL & "?"  
ELSE  
  IF(InstrRev(StrParams,SearchStr)=0)THEN  
    ResultURL=TempURL & "?" & StrParams &"&"  
  ELSE  
    j=InstrRev(StrParams,SearchStr)-2  
    IF(j=-1)THEN  
      ResultURL=TempURL & "?"  
    ELSE  
      StrLeftParams=Left(StrParams,j)  
      StrRightParams=right(StrParams,len(StrParams)-j-1)  
      IF(InStr(StrRightParams,"&")<>0)THEN  
        StrRightParams=right(StrRightParams,len(StrRightParams)-InStr(StrRightParams,"&")+1)  
      ELSE  
        StrRightParams = ""  
      END IF  
      ResultURL=TempURL & "?" & StrLeftParams&StrRightParams&"&"  
    END IF  
  END IF  
END IF  
GetURL=ResultURL
End Function

Sub RollPage(GetPageSize,GetPageCount,GetCurrPage,GetRecCounts)
	Dim MultiPage,OffSet,ShowPageNums,FromPage,ToPage,PageI
	OffSet = 3
	ShowPageNums = 7
	FromPage=GetCurrPage-OffSet
	ToPage=GetCurrPage+ShowPageNums-OffSet-1

	IF(ShowPageNums>GetPageCount)THEN
		FromPage=1
		ToPage=GetPageCount
	END IF
	IF(FromPage<1)THEN
		Topage=GetCurrPage+1-FromPage
		FromPage=1
		IF((ToPage-FromPage)<ShowPageNums And (ToPage-FromPage)<GetPageCount)THEN ToPage=ShowPageNums
	ELSEIF(topage>GetPageCount)THEN
		FromPage =GetCurrPage-GetPageCount +ToPage
		ToPage=GetPageCount
		IF((ToPage-FromPage)<ShowPageNums And (ToPage-FromPage)<GetPageCount)THEN FromPage=GetPageCount-ShowPageNums+1
	END IF
	For PageI=FromPage TO ToPage
		IF(PageI<>GetCurrPage)THEN
			MultiPage=MultiPage&"<a href="""&GetURL&"page="&PageI&""">["&PageI&"]</a>"
		ELSE
			MultiPage=MultiPage&"<strong style=""color:#FF0000"">["&PageI&"]</strong>"
		END IF
	Next

	Response.Write("<table border=0 width=""100%"" cellspacing=""0"" cellpadding=""0""><tr>")
	Response.Write"<td align=""left"">共<font color='#FF0000'>"&GetRecCounts&"</font>个,<font color='#FF0000'>"&GetPageSize&"</font>个/页,第<font color='#FF0000'>"&GetCurrPage&"</font>/<font color='#FF0000'>"&GetPageCount&"</font>页</td>"
	Response.Write("<td align=right>")
	
	IF(GetCurrPage=1)THEN 
	  Response.Write"<span disabled>[首页]</span>" 
	ELSE
	  Response.Write"[<a href="""&GetURL&"page=1"">首页</a>]"
	END IF
			
	IF(GetCurrPage=1)THEN
	  Response.Write"<span disabled>[上页]</span> "
	ELSE
	  Response.Write"[<a href="""&GetURL&"page="&GetCurrPage-1&""">上页</a>] "
	END IF
	Response.Write(VBCrlf & MultiPage & VBCrlf)
	IF(GetCurrPage=GetPageCount)THEN
	  Response.Write"<span disabled>[下页]</span>"
	ELSE
	  Response.Write"[<a href="""&GetURL&"page="&GetCurrPage+1&""">下页</a>]"
	END IF
			
	IF(GetCurrPage=GetPageCount)THEN
	  Response.Write"<span disabled>[尾页]</span>"
	ELSE
	  Response.Write"[<a href="""&GetURL&"page="&GetPageCount&""">尾页</a>]"
	END IF 
	
	Response.Write(" <input type=""text"" maxlenght=""4"" class=""input2"" value="""&GetCurrPage&""" onfocus=""select()"" onkeydown=""if(event.keyCode==13)window.location='"&GetURL&"page='+this.value"" />")
	Response.Write("</td>")
	Response.Write("</tr></table>")
End Sub
%>