dropdownitem.as

FlashStore是Kyoji独立开发的RIA实验性项目。综合运用了ASP.NET、Flash Remoting和Action Script 2.0等技术

/**
 * @class		: FStore.view.component.DropdownItem
 * @_parent		: FStore.view.component.DropdownMenu.holder_mc
 * @summary	: 下拉菜单选项
 * @version		: 1.0(2004.05.22)
 * @see			: FStore.component.LinkButton
 * @author		: kyoji
 */
class FStore.view.component.DropdownItem extends FStore.component.LinkButton {
	private var background_mc:MovieClip;
	private var cl:Color;
	private var value:Number;
	private var label:String;
	
	public function DropdownItem() {

	}
	
	private function onLoad():Void {
		lbl_txt.autoSize = "left";
		cl = new Color(background_mc);
		cl.setRGB(0x333333);
		setData(label, value);
	}
	
	/// @summary : 设置文本和链接地址
	/// @params[l] : 标签文本
	/// @params[v] : 保存值
	public function setData(l:String, v:Number):Void {
		lbl_txt.text = l;
		if(v != null) {
			onRelease = function () {
				_parent._parent.dropdownHead_mc.onRollOut();
				handlerClip[method](v);
				var sd:Sound = new Sound();
				sd.attachSound("btndown2");
				sd.start();
			};
			onRollOver = function () {
				_parent._parent.dropdownHead_mc.onRollOver();
				lbl_txt.textColor = 0xFFFFFF;
				cl.setRGB(0x336699);
			};
			onDragOver = function () {
				onRollOver();
			};
			onRollOut = function () {
				_parent._parent.dropdownHead_mc.onRollOut();
				lbl_txt.textColor = 0xCCCCCC;
				cl.setRGB(0x333333);
			};
			onDragOut = function () {
				onRollOut();
			};
		} else {
			cl.setRGB(0x000000);
			lbl_txt.textColor = 0xFFFFFF;
			onRollOver = function () {
				_parent._parent.dropdownHead_mc.onRollOver();
			};
			onDragOver = function () {
				onRollOver();
			};
			onRollOut = function () {
				_parent._parent.dropdownHead_mc.onRollOut();
			};
			onDragOut = function () {
				onRollOut();
			};
		}
	}
}