thumbnail.as

FlashStore是Kyoji独立开发的RIA实验性项目。综合运用了ASP.NET、Flash Remoting和Action Script 2.0等技术

import FStore.data.ProductObject;

/**
 * @class		: FStore.view.component.Thumbnail
 * @_parent		: FStore.view.ThumbnailView
 * @summary	: 商品略图
 * @version		: 1.0(2004.05.20)
 * @author		: kyoji
 */
class FStore.view.component.Thumbnail extends MovieClip {
	private var picHolder_mc:MovieClip;
	private var loadingfx_mc:MovieClip;
	public var index:Number;
	private var product:ProductObject;
	
	public function Thumbnail() {

	}
	
	private function onLoad():Void {
		loadingfx_mc._visible = false;
		setData(index, product);
	}
	
	public function setData(i:Number, po:ProductObject):Void {
		loadingfx_mc._visible = true;
		if(po) {
			picHolder_mc.loadMovie("images/products/thumbnail/" + product.Image);
			onEnterFrame = function() {
				var bl:Number = picHolder_mc.getBytesLoaded();
				var bt:Number = picHolder_mc.getBytesTotal();
				if(bl > 4 && bt > 4 && bl >= bt) {
					loadingfx_mc._visible = false;
					delete onEnterFrame;
				}
			}
			product = po;
		}		
	}
	
	private function onRollOver():Void {
		// 放大
		_xscale = _yscale = 120;
		// 放到最顶端
		this.swapDepths(_parent._parent.topThumb);
		_parent._parent.topThumb = this;
		// 信息提示
		_parent._parent.tooltip_mc.setLabel(product.ProductName);
		_parent._parent.tooltip_mc._x = _parent._xmouse;
		_parent._parent.tooltip_mc._y = _parent._ymouse;
		onMouseMove = function() {
			_parent._parent.tooltip_mc._x = Math.round(_parent._parent._xmouse);
			_parent._parent.tooltip_mc._y = Math.round(_parent._parent._ymouse);
			updateAfterEvent();
		}
		_parent._parent.dragger_mc._x = this._x - 36;
		_parent._parent.dragger_mc._y = this._y + 17;
	}
	
	private function onRollOut():Void {
		// 还原
		_xscale = _yscale = 100;
		// 隐藏信息提示
		_parent._parent.tooltip_mc._x= -500;
		_parent._parent.dragger_mc._x= -500;
		delete onMouseMove;
	}
	
	private function onRelease():Void {
		onRollOver();
		_parent._parent.viewDetail(index);
	}
	
	private function onDragOut():Void {
		onRollOut();
	}
	
	private function onDragOver():Void {
		onRollOver();
	}
}