java.syntax

java 词法分析器,用于一般的C,C++,VB,PS/SQL 语句的翻译

		switch_block_statement_group
	|	switch_block_statement_groups switch_block_statement_group
	;
switch_block_statement_group ::=
		switch_labels block_statements
	;
switch_labels ::=
		switch_label
	|	switch_labels switch_label
	;
switch_label ::=
		CASE constant_expression COLON
	|	DEFAULT COLON
	;

while_statement ::=
		WHILE LPAREN expression RPAREN statement
	;
while_statement_no_short_if ::=
		WHILE LPAREN expression RPAREN statement_no_short_if
	;
do_statement ::=
		DO statement WHILE LPAREN expression RPAREN SEMICOLON
	;
for_statement ::=
		FOR LPAREN for_init_opt SEMICOLON expression_opt SEMICOLON
			for_update_opt RPAREN statement
	;
for_statement_no_short_if ::=
		FOR LPAREN for_init_opt SEMICOLON expression_opt SEMICOLON
			for_update_opt RPAREN statement_no_short_if
	;
for_init_opt ::=
	|	for_init
	;
for_init ::=	statement_expression_list
	|	local_variable_declaration
	;
for_update_opt ::=
	|	for_update
	;
for_update ::=	statement_expression_list
	;
statement_expression_list ::=
		statement_expression
	|	statement_expression_list COMMA statement_expression
	;

identifier_opt ::= 
	|	IDENTIFIER
	;

break_statement ::=
		BREAK identifier_opt SEMICOLON
	;

continue_statement ::=
		CONTINUE identifier_opt SEMICOLON
	;
return_statement ::=
		RETURN expression_opt SEMICOLON
	;
throw_statement ::=
		THROW expression SEMICOLON
	;
synchronized_statement ::=
		SYNCHRONIZED LPAREN expression RPAREN block
	;
try_statement ::=
		TRY block catches
	|	TRY block catches_opt _finally
	;
catches_opt ::=
	|	catches
	;
catches ::=	catch_clause
	|	catches catch_clause
	;
catch_clause ::=
		CATCH LPAREN formal_parameter RPAREN block
	;
_finally ::=	FINALLY block
	;

// 19.12) Expressions
primary ::=	primary_no_new_array
	|	array_creation_expression
	;
primary_no_new_array ::=
		literal
	|	THIS
	|	LPAREN expression RPAREN
	|	class_instance_creation_expression
	|	field_access
	|	method_invocation
	|	array_access
	|	primitive_type DOT CLASS
	|	VOID DOT CLASS
	|	array_type DOT CLASS
	|	name DOT CLASS
	|	name DOT THIS
	;
class_instance_creation_expression ::=
		NEW class_type LPAREN argument_list_opt RPAREN
	|	NEW class_type LPAREN argument_list_opt RPAREN class_body
	|	primary DOT NEW IDENTIFIER
			LPAREN argument_list_opt RPAREN
	|	primary DOT NEW IDENTIFIER
			LPAREN argument_list_opt RPAREN class_body
	;
argument_list_opt ::=
	|	argument_list
	;
argument_list ::=
		expression
	|	argument_list COMMA expression
	;
array_creation_expression ::=
		NEW primitive_type dim_exprs dims_opt
	|	NEW class_or_interface_type dim_exprs dims_opt
	|	NEW primitive_type dims array_initializer
	|	NEW class_or_interface_type dims array_initializer
	;
dim_exprs ::=	dim_expr
	|	dim_exprs dim_expr
	;
dim_expr ::=	LBRACK expression RBRACK
	;
dims_opt ::=
	|	dims
	;
dims ::=	LBRACK RBRACK
	|	dims LBRACK RBRACK
	;
field_access ::=
		primary DOT IDENTIFIER
	|	SUPER DOT IDENTIFIER
	|	name DOT SUPER DOT IDENTIFIER
	;
method_invocation ::=
		name LPAREN argument_list_opt RPAREN
	|	primary DOT IDENTIFIER LPAREN argument_list_opt RPAREN
	|	SUPER DOT IDENTIFIER LPAREN argument_list_opt RPAREN
	|	name DOT SUPER DOT IDENTIFIER LPAREN argument_list_opt RPAREN
	;
array_access ::=
		name LBRACK expression RBRACK
	|	primary_no_new_array LBRACK expression RBRACK
	;
postfix_expression ::=
		primary
	|	name
	|	postincrement_expression
	|	postdecrement_expression
	;
postincrement_expression ::=
		postfix_expression PLUSPLUS
	;
postdecrement_expression ::=
		postfix_expression MINUSMINUS
	;
unary_expression ::=
		preincrement_expression
	|	predecrement_expression
	|	PLUS unary_expression
	|	MINUS unary_expression
	|	unary_expression_not_plus_minus
	;
preincrement_expression ::=
		PLUSPLUS unary_expression
	;
predecrement_expression ::=
		MINUSMINUS unary_expression
	;
unary_expression_not_plus_minus ::=
		postfix_expression
	|	COMP unary_expression
	|	NOT unary_expression
	|	cast_expression
	;
cast_expression ::=
		LPAREN primitive_type dims_opt RPAREN unary_expression
	|	LPAREN expression RPAREN unary_expression_not_plus_minus
	|	LPAREN name dims RPAREN unary_expression_not_plus_minus
	;
multiplicative_expression ::=
		unary_expression
	|	multiplicative_expression MULT unary_expression
	|	multiplicative_expression DIV unary_expression
	|	multiplicative_expression MOD unary_expression
	;
additive_expression ::=
		multiplicative_expression
	|	additive_expression PLUS multiplicative_expression
	|	additive_expression MINUS multiplicative_expression
	;
shift_expression ::=
		additive_expression
	|	shift_expression LSHIFT additive_expression
	|	shift_expression RSHIFT additive_expression
	|	shift_expression URSHIFT additive_expression
	;
relational_expression ::=
		shift_expression
	|	relational_expression LT shift_expression
	|	relational_expression GT shift_expression
	|	relational_expression LTEQ shift_expression
	|	relational_expression GTEQ shift_expression
	|	relational_expression INSTANCEOF reference_type
	;
equality_expression ::=
		relational_expression
	|	equality_expression EQEQ relational_expression
	|	equality_expression NOTEQ relational_expression
	;
and_expression ::=
		equality_expression
	|	and_expression AND equality_expression
	;
exclusive_or_expression ::=
		and_expression
	|	exclusive_or_expression XOR and_expression
	;
inclusive_or_expression ::=
		exclusive_or_expression
	|	inclusive_or_expression OR exclusive_or_expression
	;
conditional_and_expression ::=
		inclusive_or_expression
	|	conditional_and_expression ANDAND inclusive_or_expression
	;
conditional_or_expression ::=
		conditional_and_expression
	|	conditional_or_expression OROR conditional_and_expression
	;
conditional_expression ::=
		conditional_or_expression
	|	conditional_or_expression QUESTION expression 
			COLON conditional_expression
	;
assignment_expression ::=
		conditional_expression
	|	assignment
	;
assignment ::=	left_hand_side assignment_operator assignment_expression
	;
left_hand_side ::=
		name
	|	field_access
	|	array_access
	;
assignment_operator ::=
		EQ
	|	MULTEQ
	|	DIVEQ
	|	MODEQ
	|	PLUSEQ
	|	MINUSEQ
	|	LSHIFTEQ
	|	RSHIFTEQ
	|	URSHIFTEQ
	|	ANDEQ
	|	XOREQ
	|	OREQ
	;
expression_opt ::=
	|	expression
	;
expression ::=	assignment_expression
	;
constant_expression ::=
		expression
	;
	
	
BOOLEAN    ::= "boolean" ;
BYTE       ::= "byte" ;
SHORT      ::= "short" ;
INT        ::= "int" ;
LONG       ::= "long" ;
CHAR       ::= "char" ;
FLOAT      ::= "float" ;
DOUBLE     ::= "double" ;
LBRACK     ::= '[' ;
RBRACK     ::= ']' ;
DOT        ::= '.' ;
SEMICOLON  ::= ';' ;
MULT       ::= '*' ;
COMMA      ::= ',' ;
LBRACE     ::= '{' ;
RBRACE     ::= '}' ;
EQ         ::= '=' ;
LPAREN     ::= '(' ;
RPAREN     ::= ')' ;
COLON      ::= ':' ;
ABSTRACT   ::=   "abstract" ;
BREAK      ::=   "break" ;
CASE       ::=   "case" ;
CATCH      ::=   "catch" ;
CLASS      ::=   "class" ;
# CONST      ::=   "const" ;
CONTINUE   ::=   "continue" ;
DEFAULT    ::=   "default" ;
DO         ::=   "do" ;
ELSE       ::=   "else" ;
EXTENDS    ::=   "extends" ;
FINAL      ::=   "final" ;
FINALLY    ::=   "finally" ;
FOR        ::=   "for" ;
# GOTO       ::=   "goto" ;
IF         ::=   "if" ;
IMPLEMENTS ::=   "implements" ;
IMPORT     ::=   "import" ;
INSTANCEOF ::=   "instanceof" ;
INTERFACE  ::=   "interface" ;
NATIVE     ::=   "native" ;
NEW        ::=   "new" ;
PACKAGE    ::=   "package" ;
PUBLIC     ::=   "public" ;
PROTECTED  ::=   "protected" ;
PRIVATE    ::=   "private" ;
RETURN     ::=   "return" ;
STATIC     ::=   "static" ;
STRICTFP   ::=   "strictfp" ;
SUPER      ::=   "super" ;
SWITCH     ::=   "switch" ;
SYNCHRONIZED::=  "synchronized" ;
THIS       ::=   "this" ;
THROW      ::=   "throw" ;
THROWS     ::=   "throws" ;
TRANSIENT  ::=   "transient" ;
TRY        ::=   "try" ;
VOLATILE   ::=   "volatile" ;
VOID       ::=   "void" ;
WHILE      ::=   "while" ;
PLUSPLUS   ::= "++" ;
MINUSMINUS ::= "--" ;
PLUS       ::= '+' ;
MINUS      ::= '-' ;
COMP       ::= '~' ;
NOT        ::= '!' ;
DIV        ::= '/' ;
MOD        ::= '%' ;
LSHIFT     ::= "<<" ;
RSHIFT     ::= ">>" ;
URSHIFT    ::= ">>>" ;
LT         ::= '<' ;
GT         ::= '>' ;
LTEQ       ::= "<=" ;
GTEQ       ::= ">=" ;
EQEQ       ::= "==" ;
NOTEQ      ::= "!=" ;
AND        ::= '&' ;
XOR        ::= '^' ;
OR         ::= '|' ;
ANDAND     ::= "&&" ;
OROR       ::= "||" ;
QUESTION   ::= '?' ;
MULTEQ     ::= "*=" ;
DIVEQ      ::= "/=" ;
MODEQ      ::= "%=" ;
PLUSEQ     ::= "+=" ;
MINUSEQ    ::= "-=" ;
LSHIFTEQ   ::= "<<=" ;
RSHIFTEQ   ::= ">>=" ;
URSHIFTEQ  ::= ">>>=" ;
ANDEQ      ::= "&=" ;
XOREQ      ::= "^=" ;
OREQ       ::= "|=" ;

NULL_LITERAL           ::= "null" ;
BOOLEAN_LITERAL        ::= "true" | "false" ;

IDENTIFIER             ::= `identifier` ;

INTEGER_LITERAL        ::= `integer` ;
FLOATING_POINT_LITERAL ::= `float` ;

CHARACTER_LITERAL      ::= `chardef` ;
STRING_LITERAL         ::= `stringdef` ;


ignored ::= `cstylecomment` | `spaces` | `newlines`
	;