添加系统托盘图标.frm

个人VB学习源码精选,自己学习时的一些编程小程序,希望对大家有帮助

VERSION 5.00
Begin VB.Form Form1 
   Caption         =   "Form1"
   ClientHeight    =   3195
   ClientLeft      =   60
   ClientTop       =   345
   ClientWidth     =   4680
   LinkTopic       =   "Form1"
   ScaleHeight     =   3195
   ScaleWidth      =   4680
   StartUpPosition =   3  '窗口缺省
   Begin VB.Menu popMenu 
      Caption         =   "popMenu"
      Visible         =   0   'False
      Begin VB.Menu mnuShow 
         Caption         =   "显示窗口"
      End
      Begin VB.Menu mnuHide 
         Caption         =   "隐藏窗口"
      End
      Begin VB.Menu mnuExit 
         Caption         =   "退出程序"
      End
   End
End
Attribute VB_Name = "Form1"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = False
Attribute VB_PredeclaredId = True
Attribute VB_Exposed = False
Private Declare Function Shell_NotifyIcon Lib "shell32.dll" Alias "Shell_NotifyIconA" (ByVal dwMessage As Long, lpData As NOTIFYICONDATA) As Long
Private Type NOTIFYICONDATA
        cbSize As Long
        hwnd As Long
        uID As Long
        uFlags As Long
        uCallbackMessage As Long
        hIcon As Long
        szTip As String * 64
End Type
Private Const NIM_ADD = &H0
Private Const NIM_MODIFY = &H1
Private Const NIM_DELETE = &H2
Private Const NIF_MESSAGE = &H1
Private Const NIF_ICON = &H2
Private Const NIF_TIP = &H4
Private Const WM_MOUSEMOVE = &H200
Private Const WM_LBUTTONDBLCLK = &H203
Private Const WM_LBUTTONDOWN = &H201
Private Const WM_LBUTTONUP = &H202
Private Const WM_RBUTTONDBLCLK = &H206
Private Const WM_RBUTTONDOWN = &H204
Private Const WM_RBUTTONUP = &H205
Dim Nid As NOTIFYICONDATA

Private Sub Form_Load()
    If App.PrevInstance Then Unload Me
    Nid.cbSize = Len(Nid)
    Nid.hwnd = hwnd
    Nid.uID = vbNull
    Nid.uFlags = NIF_ICON Or NIF_TIP Or NIF_MESSAGE
    Nid.uCallbackMessage = WM_MOUSEMOVE
    Nid.hIcon = Form1.Icon
    Nid.szTip = "托盘图标演示" & vbNullChar
    Shell_NotifyIcon NIM_ADD, Nid
End Sub

Private Sub Form_MouseMove(Button As Integer, Shift As Integer, X As Single, Y As Single)
    Dim msg As Single
    On Error Resume Next
    msg = X / Screen.TwipsPerPixelX
    Select Case msg
        Case WM_RBUTTONDOWN
        Case WM_RBUTTONUP
            PopupMenu popMenu
        Case WM_LBUTTONDBLCLK
            Form1.Show
    End Select
End Sub

Private Sub Form_Unload(Cancel As Integer)
    Shell_NotifyIcon NIM_DELETE, Nid
End Sub

Private Sub mnuExit_Click()
    Unload Me
End Sub

Private Sub mnuHide_Click()
    Form1.Hide
End Sub

Private Sub mnuShow_Click()
    Form1.Show
End Sub