admin_login.asp

BBS源码 利用ASP的一个功能齐全的BBS论坛源码

<!--#include file="Inc.asp"-->
<!--#include file="inc/md5.asp"-->
<link rel=stylesheet type=text/css href=style.css>
<%Dim Action
Action=request.querystring("Action")
Select Case Action
Case"exit"
	ExitLogin()
Case"login"
	CheckLogin()
Case Else
	Main()
End select
Set BBS94KK=Nothing

Sub Main()
	Response.Write"<title>论坛登陆</title>"&_
	"<br><br><form method=POST action='?action=login' style='margin:0'>"&_
	"<table width='500' border='1' bordercolordark=#aCd7fF bordercolorlight=#145AA0 cellspacing='0' cellpadding='3' align='center'>"&_
	"<tr  bgcolor='#73B2EF'><th height='25' align='center'><strong> 论坛后台管理登陆</strong></th></tr>"&_
	"<tr><td align='center' bgcolor='#9CC7EF'>"&_
	"<table width='100%' height='118'  border='0' cellpadding='0' cellspacing='0'>"&_
	"<tr><td width='40%' align='right'>用 户 名：</td><td width='60%'><input name='AdminName' type=text size='22'></td></tr>"&_
	"<tr><td align='right'>管理密码：</td><td><input name='Password' type=password size='22'></td></tr>"&_
	"<tr><td align='right'>验 证 码：</td><td><input type=text name='PassCode' size=10> <img align='absmiddle' src=Inc/Code.asp ></td></tr></table> "&_
	"</td></tr><tr bgcolor='#73B2EF'><th height='25' align='center'><input type=submit class=submit value=' 提  交 '>"&_
	"</td></tr></table></form>"
End Sub
Sub CheckLogin()
	Dim AdminName,AdminPassword,PassCode
	If BBS94KK.GetCookiesInfo("AdminLogin",0)=>3 Then Call Alert("您已经超过三次错误的尝试，今天不能再登陆论坛后台了！","Index.asp")
	AdminName=BBS94KK.Fun.GetStr("AdminName")
	AdminPassword=BBS94KK.Fun.GetStr("Password")
	PassCode=BBS94KK.Fun.GetStr("PassCode")
	If not BBS94KK.Fun.CheckName(AdminName) or not BBS94KK.Fun.CheckPassword(AdminPassword) Or PassCode="" then
		Call Alert("您输入的用户名不存在或者密码错误或者随机验证码错误！\n错误操作 "&BBS94KK.UpdateCookiesInfo("AdminLogin",1)&" 次！","Admin_login.asp")
	End if
	If BBS94KK.execute("select name From [KK_admin] where name='"&AdminName&"' And Password='"&Md5(AdminPassword)&"' And boardID=0").eof Or Session("CheckCode")<>PassCode  Then
		Session(BBS94KK.CacheName&"AdminName")=""
		Session(BBS94KK.CacheName&"AdminPassword")=""
		Session("CheckCode")=""
		Call Alert("您输入的用户名不存在或者密码错误或者随机验证码错误！\n错误操作 "&BBS94KK.UpdateCookiesInfo("AdminLogin",1) &" 次！","Admin_login.asp")
	Else
		Session(BBS94KK.CacheName&"AdminName")=AdminName
		Session(BBS94KK.CacheName&"AdminPassword")=AdminPassword
		Session("CheckCode")=""
		Call BBS94KK.UpdateCookiesInfo("AdminLogin",0)
		Response.Redirect"Admin_index.asp"
		Response.End
	End if
End Sub
Sub Alert(message,url)
	message = replace(message,"'","\'")
	Url = replace(Url,"'","\'")
	Response.Write ("<script LANGUAGE='javascript'>alert('" & message & "');window.location.href='" & Url & "';</script>")
	Response.End
End Sub
Sub ExitLogin()
	Session(BBS94KK.CacheName&"AdminName")=""
	Session(BBS94KK.CacheName&"AdminPassword")=""
	Session("CheckCode")=""
	'Session.Abandon
	Response.redirect"Index.asp"
End Sub
%>