guest_syscode.asp

该程序采用FlashMX开发

		do while not rs.eof
			rs.delete
			rs.update
			rs.movenext
		loop
		call Guest_info("<li>删除留言成功！</li>")
	end if    
	rs.close
	set rs=nothing
end sub

'**************************************************
'函数名：KeywordReplace
'作  用：标示搜索关键字
'参  数：strChar-----要转换的字符
'返回值：转换后的字符
'**************************************************
function KeywordReplace(strChar)
	if strChar="" then
		KeywordReplace=""
	else
		KeywordReplace=	replace(strChar,""&keyword&"","<font color=red>"&keyword&"</font>")
	end if
end function

'=================================================
'过程名：SaveWriteGuest()
'作  用：保存留言
'参  数：无
'=================================================
sub SaveWriteGuest()
	dim SaveEditId,GuestName,GuestSex,GuestOicq,GuestEmail,GuestHomepage,GuestFace,GuestImages,GuestIcq,GuestMsn
	dim GuestTitle,GuestContent,GuestIsPrivate,GuestIsPassed
	dim GuestPassword,GuestPasswordConfirm,GuestQuestion,GuestAnswer,GuestUserlevel
	dim sqlMaxId,rsMaxId,MaxId,Saveinfo,sqlReg,rsReg,trs,tmpUserLevel

	GuestContent=request("GuestContent")
	if UserLogined=False then
		GuestName=dvHTMLEncode(trim(request("GuestName")))
		GuestSex=trim(request("GuestSex"))
		GuestOicq=dvHTMLEncode(trim(request("GuestOicq")))
		GuestIcq=dvHTMLEncode(trim(request("GuestIcq")))
		GuestMsn=dvHTMLEncode(trim(request("GuestMsn")))
		GuestEmail=dvHTMLEncode(trim(request("GuestEmail")))
		GuestHomepage=dvHTMLEncode(trim(request("GuestHomepage")))
		if GuestHomepage="http://" or isnull(GuestHomepage) then GuestHomepage=""
	else
		GuestName=UserName
	end if
	GuestImages=trim(request("GuestImages"))
	GuestFace=trim(request("GuestFace"))
	GuestTitle=dvHTMLEncode(trim(request("GuestTitle")))
	GuestIsPrivate=trim(request("GuestIsPrivate"))
	if GuestIsPrivate="yes" then
		GuestIsPrivate=True
	else
		GuestIsPrivate=False
	end if
	if EnableCheck=True then
		GuestIsPassed=False
	else
		GuestIsPassed=True
	end if
	SaveEdit=request("saveedit")
		
	if GuestName="" or GuestTitle="" or GuestContent="" then
		call Guest_info("<li>留言发送失败！</li><li>请将必要的信息填写完整！</li>")
		exit sub
	end if

	if SaveEdit=1 then
		SaveEditId=request("saveeditid")
		if SaveEditId="" then
			call Guest_info("<li>请指定要编辑的留言ID！</li>")
			exit sub
		else
			sqlMaxId="select max(GuestMaxId) as MaxId from PE_Guest"
			set rsMaxId=conn.execute(sqlMaxId)
			MaxId=rsMaxId("MaxId")
			set rsMaxId=nothing
			if MaxId="" or isnull(MaxId) then MaxId=0
			set rsGuest=server.createobject("adodb.recordset")
			sql="select * from PE_Guest where GuestID=" & clng(SaveEditId)
			rsGuest.open sql,conn,1,3
			rsGuest("GuestName")=GuestName
			rsGuest("GuestSex")=GuestSex
			rsGuest("GuestOicq")=GuestOicq
			rsGuest("GuestIcq")=GuestIcq
			rsGuest("GuestMsn")=GuestMsn
			rsGuest("GuestEmail")=GuestEmail
			rsGuest("GuestHomepage")=GuestHomepage
			rsGuest("GuestIP")=Request.ServerVariables("REMOTE_ADDR")
			rsGuest("GuestTitle")=GuestTitle
			rsGuest("GuestFace")=GuestFace
			rsGuest("GuestContent")=GuestContent
			rsGuest("GuestDatetime")=now()
			rsGuest("GuestImages")=GuestImages
			rsGuest("GuestMaxId")=MaxId+1
			rsGuest("GuestIsPrivate")=GuestIsPrivate
			rsGuest("GuestIsPassed")=GuestIsPassed
			rsGuest.update
			if EnableCheck=True then
				call Guest_info("<li>留言编辑成功！</li><li>只有管理员审核通过的留言才会显示出来。</li>")
			else
				call Guest_info("<li>留言编辑成功！</li>")
			end if
			rsGuest.close
			set rsGuest=nothing
		end if
	else
		if GuestContent<>session("OldGuestContent") then 
			session("OldGuestContent")=GuestContent
			sqlMaxId="select max(GuestMaxId) as MaxId from PE_Guest"
			set rsMaxId=conn.execute(sqlMaxId)
			MaxId=rsMaxId("MaxId")
			set rsMaxId=nothing
			if MaxId="" or isnull(MaxId) then MaxId=0
			set rsGuest=server.createobject("adodb.recordset")
			sql="select * from PE_Guest"
			rsGuest.open sql,conn,1,3
			rsGuest.addnew
			if UserLogined=False then
				rsGuest("GuestType")=0
			else
				rsGuest("GuestType")=1
			end if
			rsGuest("GuestName")=GuestName
			rsGuest("GuestSex")=GuestSex
			rsGuest("GuestOicq")=GuestOicq
			rsGuest("GuestIcq")=GuestIcq
			rsGuest("GuestMsn")=GuestMsn
			rsGuest("GuestEmail")=GuestEmail
			rsGuest("GuestHomepage")=GuestHomepage
			rsGuest("GuestIP")=Request.ServerVariables("REMOTE_ADDR")
			rsGuest("GuestTitle")=GuestTitle
			rsGuest("GuestFace")=GuestFace
			rsGuest("GuestContent")=GuestContent
			rsGuest("GuestDatetime")=now()
			rsGuest("GuestImages")=GuestImages
			rsGuest("GuestMaxId")=MaxId+1
			rsGuest("GuestIsPrivate")=GuestIsPrivate
			rsGuest("GuestIsPassed")=GuestIsPassed
			rsGuest.update
			if EnableCheck=True then
				Saveinfo="<li>您的留言已经发送成功！</li><li>只有管理员审核通过的留言才会显示出来。</li>"
			else
				Saveinfo="<li>您的留言已经发送成功！</li>"
			end if

			if request("reg")=1 and UserLogined=False then
				if EnableUserReg<>True then
					Saveinfo= Saveinfo & "<li>注册失败！本站暂停新用户注册服务！</li>"
				else
					GuestPassword=trim(request("psw"))
					GuestPasswordConfirm=trim(request("pswc"))
					GuestQuestion=trim(request("question"))
					GuestAnswer=trim(request("answer"))
					set rsReg=server.createobject("adodb.recordset")
					sql="select * from " & db_User_Table & " where " & db_User_Name & "='"&ReplaceBadChar(GuestName)&"'"
					rsReg.open sql,Conn_User,1,3
					if not rsReg.eof and not rsReg.bof then
						Saveinfo= Saveinfo & "<li>注册失败！您输入的名字已经被注册。</li>"
					elseif GuestName="" or strLength(GuestName)>14 or strLength(GuestName)<4 then
						Saveinfo= Saveinfo & "<li>注册失败！输入用户名不符合要求(不能大于14小于4)</li>"
					elseif GuestPassword<>GuestPasswordConfirm then
						Saveinfo= Saveinfo & "<li>注册失败！密码与确认密码不相符。</li>"
					elseif GuestEmail="" or IsValidEmail(GuestEmail)=false then
						Saveinfo= Saveinfo & "<li>注册失败！您的Email为空或有错误</li>"
					else
						rsReg.addnew
						rsReg(db_User_Name)=GuestName
						rsReg(db_User_Sex)=GuestSex
						rsReg(db_User_Password)=md5(GuestPassword)
						rsReg(db_User_Question)=GuestQuestion
						rsReg(db_User_Answer)=md5(GuestAnswer)
						rsReg(db_User_Email)=GuestEmail
						rsReg(db_User_Homepage)=GuestHomepage
						rsReg(db_User_QQ)=GuestOicq
						rsReg(db_User_Icq)=GuestIcq
						rsReg(db_User_Msn)=GuestMsn
						rsReg(db_User_LoginTimes)=1
						rsReg(db_User_RegDate)=now()
						'rsReg(db_User_LastLoginTime)=NOW()
						rsReg("ArticleCount")=0
						rsReg("ArticleChecked")=0
						set trs=conn.execute("select * from PE_UserLevel where UserLevel=999")
						tmpUserLevel=trs("UserLevel")
						rsReg("UserLevel")=tmpUserLevel
						rsReg("ChargeType")=trs("DefaultChargeType")
						rsReg("UserPoint")=trs("DefaultPoint")
						rsReg("BeginDate")=formatdatetime(now(),2)
						rsReg("Valid_Num")=trs("DefaultValidNum")
						rsReg("Valid_Unit")=trs("DefaultValidUnit")
						set trs=nothing

						randomize
						CheckNum = int(7999*rnd+2000) '随机验证码
						rsReg("CheckNum")=CheckNum
						if EmailCheckReg=True then
							rsReg("UserState")=3000
							CheckUrl=Request.ServerVariables("HTTP_REFERER")
							CheckUrl=left(CheckUrl,instrrev(CheckUrl,"/")) & "User_RegCheck.asp?Action=Check&UserName=" & GuestName & "&Password=" & GuestPassword & "&CheckNum=" & CheckNum
							call SendRegEmail(GuestEmail,GuestName)
						else
							if AdminCheckReg=True then
								rsReg("UserState")=2000
							else			
								rsReg("UserState")=999
								Response.Cookies("asp163")("UserName")=GuestName
								Response.Cookies("asp163")("Password") =md5(GuestPassword)
								Response.Cookies("asp163")("UserLevel")=tmpUserLevel
							end if
						end if

						if UserTableType="Dvbbs6.0" or UserTableType="Dvbbs6.1" then
							rsReg(db_User_UserClass) = FU_UserClass
							rsReg(db_User_TitlePic) = FU_TitlePic
							rsReg(db_User_UserGroupID) = FU_UserGroupID
							rsReg(db_User_Face) = FU_Face
							rsReg(db_User_FaceWidth) = FU_FaceWidth
							rsReg(db_User_FaceHeight) = FU_FaceHeight
							rsReg(db_User_UserWealth) = FU_UserWealth
							rsReg(db_User_UserEP) = FU_UserEP
							rsReg(db_User_UserCP) = FU_UserCP
							rsReg(db_User_UserGroup) = FU_UserGroup
							rsReg(db_User_Showre) = FU_Showre
						end if 
						rsReg.update
						call UpdateUserNum(GuestName)

						if EmailCheckReg=True then
							Saveinfo= Saveinfo & "<li>系统已经发送了一封确认信到你注册时填写的信箱中，你必须在收到确认信并通过确认信中链接进行确认后，你才能正式成为本站的注册用户。</li>"
						else
							if AdminCheckReg="Yes" then
								Saveinfo= Saveinfo & "<li>请等待管理通过你的注册申请后，你就可以正式成为本站的注册用户了。</li>"
							else			
								Saveinfo= Saveinfo & "<li>用户注册成功！欢迎您的加入！！！</li>"
							end if
						end if		
					end if
					rsReg.close
					set rsReg=nothing
				end if
			end if
			rsGuest.close
			set rsGuest=nothing

			call Guest_info(Saveinfo)
		else
			call Guest_info("<li>请不要连续发送内容相同的留言或空留言！</li>")
		end if
	end if
end sub

'=================================================
'过程名：SendRegEmail()
'作  用：发送注册确认信
'参  数：无
'=================================================
sub SendRegEmail(Email,RegUserName)
	dim MailtoAddress,MailtoName,Subject,MailBody,FromName,MailFrom,Priority
	MailtoAddress=Email
	MailtoName=RegUserName
	Subject="注册确认信"
	MailBody="这是一封注册确认信。你的验证码是：" & CheckNum & vbcrlf & "<br>请点此进行确认：<a href='" & CheckUrl & "'>" & CheckUrl & "</a>"
	FromName=SiteName
	MailFrom=WebmasterEmail
	Priority=3
	ErrMsg=SendMail(MailtoAddress,MailtoName,Subject,MailBody,FromName,MailFrom,Priority)
	if ErrMsg<>"" then FoundErr=True
end sub


'=================================================
'过程名：Guest_info()
'作  用：留言操作信息
'参  数：info 提示信息内容
'=================================================
sub Guest_info(info)
	dim strInfo
	strInfo=strInfo & "<table cellpadding=0 cellspacing=0 border=0 width=100% align=center>" & vbcrlf
	strInfo=strInfo & "<tr align='center'><td class='main_title_575'>留言操作反馈信息</td></tr>" & vbcrlf
	strInfo=strInfo & "<tr><td class='main_tdbg_575'><table cellpadding=5 cellspacing=0 border=0 width=100% align=center><tr><td height='100' valign='top'>" & info &"</td></tr>" & vbcrlf
	strInfo=strInfo & "<tr align='center' class='tdbg'><td><a href='" & FileName & "'>【查看留言】</a><a href='" & FileName & "?action=write'>【签写留言】</a>" & vbcrlf
	strInfo=strInfo & "</td></tr></table></td></tr></table><br>" & vbcrlf
	response.write strInfo
end sub
%>