viliosn.asp

本《华军软件园》软件小偷完美的实现asp《华军软件园》软件小偷的空缺!速度很快,完全过滤广告,可以自己任意添加广告,方便个人小站使用!

<% 
Class clsThief
'____________________
Private value_   
Private src_     
Private isGet_   
private ss

public property let src(str) 
src_=str
end property

public property get value 
value=value_
end property

Public Property get Version
	Version="www.wz899.008.net Version 2005"
End Property

private sub class_initialize()
value_=""
src_=""
isGet_= false
end sub
	
private sub class_terminate()
end sub


Public Function Cen(content)
Cen=content
if content <> "" then
Cen=replace(Cen,chr(13),"<br>")
Cen=replace(Cen,chr(32),"&nbsp;")
end if
End function

Public Function RemoveHTML(fString)
dim objRegExp
set objRegExp = New RegExp	
objRegExp.Global = True
objRegExp.IgnoreCase = True
if not isnull(fString) then
objRegExp.Pattern = "<(.[^>]*)>"
fString = objRegExp.Replace(fString,"")
RemoveHTML = fString
end if
set objRegExp=nothing
end function
Public Function ReplaceBadChar(strChar)
    If strChar = "" Or IsNull(strChar) Then
        ReplaceBadChar = ""
        Exit Function
    End If
    Dim strBadChar, arrBadChar, tempChar, i
    strBadChar = "',%,^,&,?,(,),<,>,[,],{,},/,\,;,:," & Chr(34) & "," & Chr(0) & ""
    arrBadChar = Split(strBadChar, ",")
    tempChar = strChar
    For i = 0 To UBound(arrBadChar)
        tempChar = Replace(tempChar, arrBadChar(i), "")
    Next
    ReplaceBadChar = tempChar
End Function

private Function BytesToBstr(body,Cset) 
dim objstream
set objstream = Server.CreateObject("adodb.stream")
objstream.Type = 1
objstream.Mode =3
objstream.Open
objstream.Write body
objstream.Position = 0
objstream.Type = 2
objstream.Charset = Cset
BytesToBstr = objstream.ReadText 
objstream.Close
set objstream = nothing
End Function

public sub steal() 
if src_<>"" then
	dim Http
	set Http=server.createobject("MSXML2.XMLHTTP")
	Http.open "GET",src_ ,false
    Http.setRequestHeader "referer", "http://onlinedown.net/" 
	Http.send()
	if Http.readystate<>4 then 
		exit sub
	end if
	value_=BytesToBSTR(Http.responseBody,"gb2312")
	isGet_= True
	set http=nothing
	if err.number<>0 then err.Clear
else 
	response.Write("<script>alert(""请先设置src属性！"")</script>")
end if
end sub

public sub noReturn() 
if isGet_= false then call steal()
value_=replace(replace(value_ , vbCr,""),vbLf,"")
end sub

public sub FilterHTML()
if isGet_= false then call steal()
  While Instr(1,value_,"<") AND Instr(1, value_, ">")
    value_= Left(value_, Instr(1, value_, "<")-1) & Right(value_, Len(value_)-Instr(1,value_, ">"))
  WEnd
end sub
public sub change(oldStr,str) 
if isGet_= false then call steal()
value_=replace(value_ , oldStr,str)
end sub
public sub cut(head,bot) 
'head=replace(head,"""","""""")
'bot=replace(bot,"""","""""")
if isGet_= false then call steal()
		if instr(value_ , head)>0 and instr(value_ , bot)>0 then
			value_=mid(value_ ,instr(value_ ,head)+len(head),instr(value_ ,bot)-instr(value_ ,head)-len(head))
		else
			response.end
		end if
end sub
public sub cutX(head,bot) 
if isGet_= false then call steal()
		if instr(value_,head)>0 and instr(value_,bot)>0 then
			value_=mid(value_ ,instr(value_ ,head),instr(value_ ,bot)-instr(value_ ,head)+len(bot))
		else
			response.end
		end if
end sub
public sub cutBy(head,headCusor,bot,botCusor) 
if isGet_= false then call steal()
		if instr(value_,head)>0 and instr(value_,bot)>0 then
			value_=mid(value_ ,instr(value_ ,head)+len(head)+headCusor,instr(value_ ,bot)-1+botCusor-instr(value_ ,head)-len(head)-headcusor)
		else
			response.end
		end if
end sub
public sub filt(head,bot,str) 
if isGet_= false then call steal()
		if instr(value_,head)>0 and instr(value_,bot)>0 then
			value_=replace(value_,mid(value_ ,instr(value_ ,head)+len(head),instr(value_ ,bot)-1),str)
		else
			value_= "<p align=""center"">函数filt指定替换的内容不存在"
		end if
end sub
public sub filtX(head,bot,str) 
if isGet_= false then call steal()
		if instr(value_,head)>0 and instr(value_,bot)>0 then
			value_=replace(value_,mid(value_ ,instr(value_ ,head),instr(value_ ,bot)+len(bot)-1),str)
		else
			value_= "<p align=""center"">函数filtX指定替换的内容不存在"
		end if
end sub
public sub filtBy(head,headCusor,bot,botCusor,str) 
if isGet_= false then call steal()
		if instr(value_,head)>0 and instr(value_,bot)>0 then
			value_=replace(value_ ,mid(value_ ,instr(value_ ,head)+len(head)+headCusor,instr(value_ ,bot)-1+botCusor-instr(value_ ,head)-len(head)-headcusor),str)
		else
			value_= "<p align=""center"">函数filtBy指定替换的内容不存在"
		end if
end sub
public sub local()
dim tempReg
set tempReg=new RegExp
tempReg.IgnoreCase=true
tempReg.Global=true
tempReg.Pattern="^(http|https|ftp):(\/\/|////)(\w+.)+(com|net|org|cc|tv|cn|biz|com.cn|net.cn|sh.cn)\/"
value_=tempReg.replace(value_ ,"")
set tempReg=nothing
end sub
public sub replaceByReg(patrn,str) 
if isGet_= false then call steal()
dim tempReg
set tempReg=new RegExp
tempReg.IgnoreCase=true
tempReg.Global=true
tempReg.Pattern=patrn
value_=tempReg.replace(value_ ,str)
set tempReg=nothing
end sub
public sub pickByReg(patrn)
if isGet_= false then call steal()
dim tempReg,match,matches,content
set tempReg=new RegExp
tempReg.IgnoreCase=true
tempReg.Global=true
tempReg.Pattern=patrn
set matches=tempReg.execute(value_)
for each match in matches
content=content&match.value&"<!--lkstar-->"
next
value_=content
set matches=nothing
set tempReg=nothing
end sub
end class
%>