storehouse.cls

用ｖｂ编的一个商品库存管理系统

VERSION 1.0 CLASS
BEGIN
  MultiUse = -1  'True
  Persistable = 0  'NotPersistable
  DataBindingBehavior = 0  'vbNone
  DataSourceBehavior  = 0  'vbNone
  MTSTransactionMode  = 0  'NotAnMTSObject
END
Attribute VB_Name = "Storehouse"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = True
Attribute VB_PredeclaredId = False
Attribute VB_Exposed = False
'1 StoreId 自动编号  仓库编号
'2 StoreName 文本 / 50 仓库名称
'3 Describe  文本 / 100  仓库说明

Public StoreId As Long
Public StoreName As String
Public Describe As String

Public Sub Init()
  StoreId = 0
  StoreName = ""
  Describe = ""
End Sub

'删除数据
Public Sub Delete(ByVal TmpId As Long)
  DB_Connect
  
  SqlStmt = "DELETE FROM Storehouse WHERE StoreId=" _
          + Trim(Str(TmpId))
  OdbcExt (SqlStmt)
  Rc = SQLFreeStmt(Hstmt, SQL_DROP)
  
  DB_Disconnect
End Sub

Public Function GetId(ByVal TmpName As String) As Long
  If TmpName = "" Then
    GetId = 0
    Exit Function
  End If
  DB_Connect
  
  SqlStmt = "SELECT StoreId FROM Storehouse WHERE StoreName='" _
          + Trim(TmpName) + "'"
  OdbcExt (SqlStmt)
  If SQLFetch(Hstmt) <> SQL_NO_DATA_FOUND Then
    ColVal = String(40, 0)
    Rc = SQLGetData(Hstmt, 1, 1, ColVal, Len(ColVal), pcblen)
    GetId = Val(ColVal)
  Else
    GetId = 0
  End If
  Rc = SQLFreeStmt(Hstmt, SQL_DROP)
  
  DB_Disconnect
End Function

Public Function GetInfo(ByVal TmpId As Long) As Boolean
  If TmpId <= 0 Then
    Init
    GetInfo = False
    Exit Function
  End If
  
  StoreId = TmpId
  
  DB_Connect
  SqlStmt = "SELECT * FROM Storehouse WHERE StoreId=" _
          + Trim(Str(StoreId))
  OdbcExt (SqlStmt)
  If SQLFetch(Hstmt) = SQL_NO_DATA_FOUND Then
    GetInfo = False
    Exit Function
  Else
    ColVal = String(400, 0)
    Rc = SQLGetData(Hstmt, 2, 1, ColVal, Lench(ColVal), pcblench)
    StoreName = TrimStr(ColVal)
    
    ColVal = String(400, 0)
    Rc = SQLGetData(Hstmt, 3, 1, ColVal, Lench(ColVal), pcblench)
    Describe = TrimStr(ColVal)
  End If
    
  Rc = SQLFreeStmt(Hstmt, SQL_DROP)
  
  GetInfo = True
  DB_Disconnect
End Function

Public Function In_DB(ByVal TmpStoreName As String) As Boolean
  DB_Connect
  
  SqlStmt = "SELECT * FROM Storehouse WHERE StoreName='" _
          + Trim(TmpStoreName) + "'"
  OdbcExt (SqlStmt)
  If SQLFetch(Hstmt) = SQL_NO_DATA_FOUND Then
    In_DB = False
  Else
    In_DB = True
  End If
  Rc = SQLFreeStmt(Hstmt, SQL_DROP)

  DB_Disconnect
End Function

Public Sub Insert()
  DB_Connect
  
  SqlStmt = "INSERT INTO Storehouse (StoreName, Describe)" _
     + " Values('" + Trim(StoreName) + "','" _
     + Trim(Describe) + "')"
  OdbcExt (SqlStmt)
  Rc = SQLFreeStmt(Hstmt, SQL_DROP)
  DB_Disconnect
End Sub

Public Sub Load_Store()
  '初始化数组
  Erase Arr_Store
  ReDim Arr_Store(0)
  '连接数据库
  DB_Connect
  '设置SQL语句，读取仓库名
  SqlStmt = "SELECT StoreName FROM Storehouse ORDER BY StoreName"
  '执行SQL语句
  OdbcExt (SqlStmt)
  '依次从结果集中读取数据，并赋值到数组中
  i = 0
  Do Until SQLFetch(Hstmt) = SQL_NO_DATA_FOUND
    ColVal = String(400, 0)
    Rc = SQLGetData(Hstmt, 1, 1, ColVal, Len(ColVal), pcblen)
    ReDim Preserve Arr_Store(i + 1)
    Arr_Store(i) = TrimStr(ColVal)
    i = i + 1
  Loop
  Rc = SQLFreeStmt(Hstmt, SQL_DROP)
  '断开与数据库的连接
  DB_Disconnect
End Sub

Public Sub Update(ByVal TmpId As Long)
  DB_Connect
  
  SqlStmt = "Update Storehouse Set StoreName='" _
          + Trim(StoreName) + "',Describe='" _
          + Trim(Describe) + "' WHERE StoreId=" _
          + Trim(Str(TmpId))
  OdbcExt (SqlStmt)
  Rc = SQLFreeStmt(Hstmt, SQL_DROP)
  DB_Disconnect
End Sub