luostress.txt

自己用Ansys命令编得求试验台架应力分析得一个例子

/CLEAR
*SET,RAD_I,1250/2
*SET,RAD_PANI,705
*SET,RAD_O,2450/2
*SET,RAD_PANO,1830
*SET,RAD_B,180/2
*SET,M_BOLT,160
*SET,M_BH1,350+170+50
*SET,M_BH2,350+170+250
*SET,M_NUT,280/2
*SET,H_NUT,170
*SET,RAD_DRILL,2140/2
*SET,RAD_M,750+150
*SET,H_M,18
*SET,RAD_BI,1950/2
*SET,RAD_BO,2330/2
*SET,RAD_BH,5
*SET,F_RAD,45
*SET,FH_RAD,1855/2
*SET,R_FILLT,125
*SET,N,15
*SET,KEY_W,290
*SET,KEY_H,130
*SET,TH,200
*SET,FLANG_H1,350
*SET,FLANG_H2,350
*SET,H_SHAFT,350+490
*SET,H_SH,H_SHAFT+500
*SET,PI,ACOS(-1)
*SET,ELEMSIZE,60
/GRAPHICS,POWER
*SET,DISP_B,0.75
*SET,ZMAX,H_SH
*SET,F_EXT,22.9215E+5*12
*SET,F_EEF,30.827E+5*12
*SET,R_OUT,RAD_PANO
*SET,T_W,375
*SET,U_R,R_OUT-T_W

/PREP7  

!*  
ET,1,185 
MP,EX,1,2.06e5
MP,NUXY,1,0.29
MP,DENS,1,7.85E9
!* 
MP,EX,2,2.06e5
MP,NUXY,2,0.29
MP,DENS,2,7.85E9
!* 
MP,EX,3,2.06e5
MP,NUXY,3,0.29
MP,DENS,3,7.85E9
MP,MU,4,0.15
!*
K,1,RAD_I,0,H_M,
K,2,RAD_M,0,0,  
K,3,RAD_I+TH,0,0, 
K,4,RAD_O,0,0,
K,5,RAD_O,0,FLANG_H1,  
K,6,RAD_M,0,FLANG_H1,   
K,7,RAD_I+TH,0,FLANG_H1,
K,8,RAD_I+TH,0,H_SHAFT, 
K,9,RAD_I,0,H_SHAFT,  
K,10,RAD_I,0,FLANG_H1,
K,11,RAD_M,0,H_M,
K,12,RAD_I+TH,0,H_SH,
K,13,RAD_I,0,H_SH, 
K,14,RAD_BI,0,RAD_BH,
K,15,RAD_BO,0,RAD_BH,
K,16,RAD_BI,0,0,
K,17,RAD_BO,0,0,
K,18,RAD_BI,0,FLANG_H1,
K,19,RAD_BO,0,FLANG_H1,
K,20,RAD_I+TH+F_RAD,0,FLANG_H1,
K,21,FH_RAD,0,0,
K,22,FH_RAD,0,FLANG_H1+H_SHAFT,
K,23,FH_RAD,0,FLANG_H1,
!*
L,8,20
L,20,5
L,21,22
LFILLT,1,2,125
LSTR,1,10
LSTR,10,9
LSTR,9,13
LSTR,13,12
LSTR,12,8
LSTR,8,9
LSTR,8,24
LSTR,1,11
LSTR,11,2
LSTR,2,21
LSTR,21,4
LSTR,4,5
LSTR,10,23
LSTR,5,23
LPTN,ALL

AL,7,8,9,10
AL,1,22,21,16,6,10
AL,5,11,12,13,18,16
A,5,4,21,23
ALLS
LSLA
LSEL,INVERT
LDELE,ALL
KSLL
KSEL,INVERT
KDELE,ALL
!*
ALLS
CSYS,1
KGEN,2,1,,,,N,,,0
!K,30,RAD_I,N,H_M,
L,1,3
VDRAG,ALL,,,,,,2

CSYS,0
CYL4,,,RAD_BI,,RAD_BO,,RAD_BH
VSBV,4,5
CYL4,RAD_DRILL,0,RAD_B,,,,FLANG_H1+100
CSYS,1
VGEN,,4,,,,N,,,,1
VSBV,6,4
WPRO,N,,
CSYS,4
VSYMM,Y,ALL,,,,0,0
WPRO,-N,,
CSYS,0
RECTING,0,RAD_O+100,0,KEY_W/2,
VSEL,ALL
ASLV
ASEL,INVERT
VEXT,ALL,,,0,0,KEY_H,,,,
ALLS
VPTN,ALL
VDELE,11,,,1
VDELE,12,,,1
VDELE,15,,,1
VDELE,16,,,1
VDELE,18,,,1

WPOFF,0,KEY_W/2,0
WPRO,,90,
VSBW,ALL
WPCSYS,-1,0
WPOFF,0,0,KEY_H
VSBW,ALL
WPCSYS,-1,0

CSYS,0
CYL4,,,RAD_BI,,RAD_BO,,FLANG_H1

VPTN,ALL
VDELE,33,,,1

WPOFF,0,0,RAD_BH
VSBW,ALL
WPOFF,0,0,-RAD_BH
!创建下园盘
CYLIND,RAD_PANI,RAD_PANO,0,-FLANG_H2,0,2*N,
CYL4,RAD_DRILL,0,RAD_B,,,,FLANG_H2+100
CSYS,1
VGEN,,16,,,,N,-FLANG_H2,,,1
VSBV,15,16

VSEL,S,LOC,Z,0,H_SH+100
CM,SHAFT,VOLU
ALLS
VSEL,S,LOC,Z,0,-FLANG_H2-100
CM,PAN,VOLU
ALL

ESIZE,ELEMSIZE,0,
MAT,1
CMSEL,,SHAFT
VSWEEP,ALL
MAT,2
ALLS
CMSEL,,PAN
VSWEEP,ALL
!铐贝轴
ALLS
CMSEL,,SHAFT
ASLV
LSLA
KSLL
WPRO,2*N
CSYS,1
CMSEL,R,LOC,Y,N,2*N
CSYS,4
VSYMM,Y,ALL,,,,0,0
WPRO,N,,
VSEL,S,LOC,Z,0,H_SH+100
VSYMM,Y,ALL,,,,0,0
ESLV
NSLE
NUMMRG,KP
NUMMRG,NODE
!拷贝园盘
ALLA
WPCSYS,-1,0
CMSEL,,PAN
ASLV
LSLA
KSLL
WPRO,2*N,,
CSYS,4
VSYMM,Y,ALL,,,,0,0
WPRO,2*N,,
CSYS,1
VSEL,R,LOC,Y,2*N,4*N
CSYS,4
VSYMM,Y,ALL,,,,0,0
ALLS
WPCSYS,-1,0
VSEL,S,LOC,Z,0,-FLANG_H2-100
ASLV
LSLA
KSLL
ESLV
NSLE
NUMMRG,KP
NUMMRG,NODE

VSEL,S,LOC,Z,0,H_SH+100
CM,SHAFT,VOLU
ALLS
VSEL,S,LOC,Z,0,-FLANG_H2-100
CM,PAN,VOLU
ALLS

!*创建螺栓螺母并画网格
CSYS,0
CYLIND,M_BOLT/2,,M_BH1,-M_BH2,0,360,
RPR4,6,,,M_NUT,2*N,H_NUT,
VGEN,,95,,,,,FLANG_H1,,,1
VGEN,2,95,,,,,-FLANG_H2-FLANG_H1-H_NUT,,0
CMSEL,U,PAN
CMSEL,U,SHAFT
VPTN,ALL
CM,B_TEMP,VOLU
VGEN,,ALL,,,RAD_DRILL,,,,,1
CSYS,1
VGEN,,ALL,,,,N,,,,1
MAT,3
ESIZE,ELEMSIZE/2,0,
VSWEEP,ALL
VGEN,4,ALL,,,,N*2,,,0
VCLEAR,B_TEMP
VDELE,B_TEMP
VGEN,,ALL,,,,-N*2,,,,1
CM,BVOLU,VOLU
ALLS
!应用节点约束
CMSEL,S,PAN
NSLV,R,1
NSEL,R,LOC,Z,0
CSYS,1
NSEL,R,LOC,X,U_R,R_OUT
D,ALL,ALL
ALLS
SBCTRAN
LSWRITE,1,