frmudpclient.frm

用WinSocket创建客户机服务器--UDP,为了写这个程序,花了我好长时间,无奈水平有限,是初学,请多指教

VERSION 5.00
Object = "{248DD890-BB45-11CF-9ABC-0080C7E7B78D}#1.0#0"; "MSWINSCK.OCX"
Begin VB.Form frmUDPClient 
   Caption         =   "Simple UDP Client"
   ClientHeight    =   3750
   ClientLeft      =   60
   ClientTop       =   345
   ClientWidth     =   4710
   LinkTopic       =   "Form1"
   ScaleHeight     =   3750
   ScaleWidth      =   4710
   StartUpPosition =   3  'Windows Default
   Begin MSWinsockLib.Winsock udpClient 
      Left            =   2160
      Top             =   1680
      _ExtentX        =   741
      _ExtentY        =   741
      _Version        =   393216
      Protocol        =   1
   End
   Begin VB.TextBox txtOutput 
      Height          =   3375
      Left            =   0
      MultiLine       =   -1  'True
      ScrollBars      =   2  'Vertical
      TabIndex        =   2
      Top             =   360
      Width           =   4695
   End
   Begin VB.CommandButton cmdSend 
      Caption         =   "Send Text"
      Height          =   285
      Left            =   3480
      TabIndex        =   1
      Top             =   0
      Width           =   1215
   End
   Begin VB.TextBox txtSend 
      Height          =   285
      Left            =   0
      TabIndex        =   0
      Top             =   0
      Width           =   3375
   End
End
Attribute VB_Name = "frmUDPClient"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = False
Attribute VB_PredeclaredId = True
Attribute VB_Exposed = False
' Fig. 19.17
' A simple client using UDP protocol
Option Explicit

Private Sub Form_Load()
   ' determine remote machine
   udpClient.RemoteHost = _
      InputBox("Enter the remote host IP address", _
         "IP Address", "localhost")
   
   If udpClient.RemoteHost = "" Then
      udpClient.RemoteHost = "localhost"
   End If
   
   udpClient.RemotePort = 5000
End Sub

Private Sub Form_Terminate()
   Call udpClient.Close
End Sub

Private Sub Form_Resize()
   On Error Resume Next
   Call cmdSend.Move(ScaleWidth - cmdSend.Width, 0)
   Call txtSend.Move(0, 0, ScaleWidth - cmdSend.Width)
   Call txtOutput.Move(0, txtSend.Height, ScaleWidth, _
      ScaleHeight - txtSend.Height)
End Sub

Private Sub udpClient_DataArrival(ByVal bytesTotal As Long)
   Dim message As String
   Call udpClient.GetData(message)  ' get data from server
   txtOutput.Text = txtOutput.Text & _
      "From IP address: " & udpClient.RemoteHostIP & _
      vbCrLf & "Port #: " & Str$(udpClient.RemotePort) & _
      vbCrLf & "Bytes received: " & Str$(bytesTotal) & _
      vbCrLf & "Message: " & message & vbCrLf & vbCrLf
   txtOutput.SelStart = Len(txtOutput.Text)
End Sub

Private Sub cmdSend_Click()
   Call udpClient.SendData(txtSend.Text)  ' send data to server
   txtOutput.Text = txtOutput.Text & _
      "Sent message: " & txtSend.Text & vbCrLf & vbCrLf
   txtOutput.SelStart = Len(txtOutput.Text)
   txtSend.Text = ""
End Sub