ft_replica.idl

来自「这是广泛使用的通信开源项目,对于大容量,高并发的通讯要求完全能够胜任,他广泛可用」· IDL 代码 · 共 52 行

//FT_Replica.idl,v 1.2 2003/12/22 01:44:38 wilson_d Exp
// FT_replica.idl
#ifndef _FT_REPLICA_IDL_
#define _FT_REPLICA_IDL_

// The OMG FT file has been split into sevaral pieces.  This is one of them.
// It contains the interfaces that a typical FT Replica (replicated servant)
// will need to implement.

#include "FT_CORBA.idl"   // common FT definitions

#pragma prefix "omg.org"

module FT
{
  // Specification of PullMonitorable Interface
  // which Application Objects Inherit
  interface PullMonitorable {
    boolean is_alive();
  };

  // Specifications for Logging and Recovery
  typedef sequence<octet> State;

  exception NoStateAvailable {};
  exception InvalidState {};

  exception NoUpdateAvailable {};
  exception InvalidUpdate {};

  // Specification of Checkpointable Interface
  // which Updateable and Application Objects Inherit
  interface Checkpointable {
    State get_state()
      raises(NoStateAvailable);
    void set_state(in State s)
      raises(InvalidState);
  };

  // Specification of Updateable Interface
  // which Application Objects Inherit
  interface Updateable : Checkpointable
  {
    State get_update()
      raises(NoUpdateAvailable);
    void set_update(in State s)
      raises(InvalidUpdate);
  };
};

#endif // for #ifndef _FT_REPLICA_IDL_