idl.ll

这是广泛使用的通信开源项目,对于大容量,高并发的通讯要求完全能够胜任,他广泛可用于网络游戏医学图像网关的高qos要求.更详细的内容可阅读相应的材料

%{
/*  idl.ll,v 1.88 2004/01/07 02:53:51 parsons Exp

COPYRIGHT

Copyright 1992, 1993, 1994 Sun Microsystems, Inc.  Printed in the United
States of America.  All Rights Reserved.

This product is protected by copyright and distributed under the following
license restricting its use.

The Interface Definition Language Compiler Front End (CFE) is made
available for your use provided that you include this license and copyright
notice on all media and documentation and the software program in which
this product is incorporated in whole or part. You may copy and extend
functionality (but may not remove functionality) of the Interface
Definition Language CFE without charge, but you are not authorized to
license or distribute it to anyone else except as part of a product or
program developed by you or with the express written consent of Sun
Microsystems, Inc. ("Sun").

The names of Sun Microsystems, Inc. and any of its subsidiaries or
affiliates may not be used in advertising or publicity pertaining to
distribution of Interface Definition Language CFE as permitted herein.

This license is effective until terminated by Sun for failure to comply
with this license.  Upon termination, you shall destroy or return all code
and documentation for the Interface Definition Language CFE.

IDL_INTERFACE DEFINITION LANGUAGE CFE IS PROVIDED AS IS WITH NO WARRANTIES OF
IDL_ANY KIND INCLUDING THE WARRANTIES OF DESIGN, MERCHANTIBILITY AND FITNESS
FOR A PARTICULAR PURPOSE, NONINFRINGEMENT, OR ARISING FROM A COURSE OF
DEALING, USAGE OR TRADE PRACTICE.

IDL_INTERFACE DEFINITION LANGUAGE CFE IS PROVIDED WITH NO SUPPORT AND WITHOUT
IDL_ANY OBLIGATION ON THE PART OF Sun OR IDL_ANY OF ITS SUBSIDIARIES OR AFFILIATES
TO ASSIST IDL_IN ITS USE, CORRECTION, MODIFICATION OR ENHANCEMENT.

SUN OR IDL_ANY OF ITS SUBSIDIARIES OR AFFILIATES SHALL HAVE NO LIABILITY WITH
RESPECT TO THE INFRINGEMENT OF COPYRIGHTS, TRADE SECRETS OR IDL_ANY PATENTS BY
IDL_INTERFACE DEFINITION LANGUAGE CFE OR IDL_ANY PART THEREOF.

IDL_IN NO EVENT WILL SUN OR IDL_ANY OF ITS SUBSIDIARIES OR AFFILIATES BE LIABLE FOR
IDL_ANY LOST REVENUE OR PROFITS OR OTHER SPECIAL, INDIRECT AND CONSEQUENTIAL
DAMAGES, EVEN IF SUN HAS BEEN ADVISED OF THE POSSIBILITY OF SUCH DAMAGES.

Use, duplication, or disclosure by the government is subject to
restrictions as set forth in subparagraph (c)(1)(ii) of the Rights in
Technical Data and Computer Software clause at DFARS 252.227-7013 and FAR
52.227-19.

Sun, Sun Microsystems and the Sun logo are trademarks or registered
trademarks of Sun Microsystems, Inc.

SunSoft, Inc.
2550 Garcia Avenue
Mountain View, California  94043

NOTE:

SunOS, SunSoft, Sun, Solaris, Sun Microsystems or the Sun logo are
trademarks or registered trademarks of Sun Microsystems, Inc.

 */

/*
 * idl.ll - Lexical scanner for IDL 1.1
 */

#include "utl_strlist.h"
#include "utl_exprlist.h"
#include "utl_labellist.h"
#include "utl_decllist.h"
#include "utl_string.h"
#include "utl_err.h"
#include "ast_union_label.h"
#include "ast_field.h"
#include "ast_expression.h"
#include "ast_argument.h"
#include "ast_operation.h"
#include "fe_interface_header.h"
#include "global_extern.h"
#include "fe_private.h"
#include "nr_extern.h"
#include "y.tab.h"

static char *           idl_wstring_escape_reader (char *);
static ACE_CDR::WChar   idl_wchar_escape_reader (char *);
static char             idl_escape_reader (char *);
static double           idl_atof (char *);
static long             idl_atoi (char *, long);
static ACE_UINT64	idl_atoui (char *, long);
static void		idl_parse_line_and_file (char *);
static void		idl_store_pragma (char *);
static char *           idl_get_pragma_string (char *);
static idl_bool         idl_valid_version (char *);
static AST_Decl *       idl_find_node (char *);

#if 0 /* defined (HPUX) */
// HPUX has yytext typed to unsigned char *. We make sure here that
// we'll always use char * static char* __yytext = (char*) yytext;
// NOTE: This will not work under flex(1) were yytext is not a fixed
// buffer, but a dynamically allocated one. This function should do
// the trick for us.
inline char *__yytext()
{
  return (char *) yytext;
}
#define ace_yytext __yytext()
#else
#define ace_yytext yytext
#endif /* 0 */

%}

/* SO we don't choke on files that use \r\n */
NL [\r?\n]

%array
%option never-interactive

%%

any             return IDL_ANY;
Object          return IDL_OBJECT;
module		return IDL_MODULE;
raises		return IDL_RAISES;
readonly	return IDL_READONLY;
attribute	return IDL_ATTRIBUTE;
exception	return IDL_EXCEPTION;
context		return IDL_CONTEXT;
interface	return IDL_INTERFACE;
const		return IDL_CONST;
typedef		return IDL_TYPEDEF;
struct		return IDL_STRUCT;
enum		return IDL_ENUM;
string		return IDL_STRING;
wstring 	return IDL_WSTRING;
sequence	return IDL_SEQUENCE;
union		return IDL_UNION;
fixed		return IDL_FIXED;
switch		return IDL_SWITCH;
case		return IDL_CASE;
default		return IDL_DEFAULT;
float		return IDL_FLOAT;
double		return IDL_DOUBLE;
long		return IDL_LONG;
short		return IDL_SHORT;
unsigned	return IDL_UNSIGNED;
char		return IDL_CHAR;
wchar		return IDL_WCHAR;
boolean		return IDL_BOOLEAN;
octet		return IDL_OCTET;
void		return IDL_VOID;
native          return IDL_NATIVE;
local           return IDL_LOCAL;
abstract        return IDL_ABSTRACT;
custom          return IDL_CUSTOM;
factory         return IDL_FACTORY;
private         return IDL_PRIVATE;
public          return IDL_PUBLIC;
supports        return IDL_SUPPORTS;
truncatable     return IDL_TRUNCATABLE;
valuetype       return IDL_VALUETYPE;
component       return IDL_COMPONENT;
consumes        return IDL_CONSUMES;
emits           return IDL_EMITS;
eventtype       return IDL_EVENTTYPE;
finder          return IDL_FINDER;
getraises       return IDL_GETRAISES;
home            return IDL_HOME;
import          return IDL_IMPORT;
multiple        return IDL_MULTIPLE;
primarykey      return IDL_PRIMARYKEY;
provides        return IDL_PROVIDES;
publishes       return IDL_PUBLISHES;
setraises       return IDL_SETRAISES;
typeid          return IDL_TYPEID;
typeprefix      return IDL_TYPEPREFIX;
uses            return IDL_USES;
manages         return IDL_MANAGES;

TRUE		return IDL_TRUETOK;
FALSE		return IDL_FALSETOK;

inout		return IDL_INOUT;
in		return IDL_IN;
out		return IDL_OUT;
oneway		return IDL_ONEWAY;

\<\<		return IDL_LEFT_SHIFT;
\>\>		return IDL_RIGHT_SHIFT;
\:\:		{
		  yylval.strval = (char *) "::";
		  return IDL_SCOPE_DELIMITOR;
		}

[a-ij-rs-zA-IJ-RS-Z_][a-ij-rs-zA-IJ-RS-Z0-9_]*	{
  // Make sure that this identifier is not a C++ keyword. If it is,
  // prepend it with a _cxx_. Lookup in the perfect hash table for C++
  // keyword and grab the mapping.  BTW, the reason for the odd
  // regular expression is to handle EBCDIC, as well as ASCII.

  TAO_IDL_CPP_Keyword_Table cpp_key_tbl;
  const TAO_IDL_CPP_Keyword_Entry *entry = 0;
  if (!idl_global->preserve_cpp_keywords())
    {
      // This check will ensure that escaped C++ keywords will be
      // caught and prepended with '_cxx' as non-escaped keywords
      // are now prepended with '_cxx_'.
      const char *tmp = 
        ace_tao_yytext[0] == '_' ? ace_tao_yytext + 1 : ace_tao_yytext;

      entry = 
        cpp_key_tbl.lookup (tmp,
                            ACE_static_cast (unsigned int,
                                             ACE_OS::strlen (tmp)));
    }

  if (entry)
    {
      tao_yylval.strval = ACE_OS::strdup (entry->mapping_);
    }
  else
    {
      tao_yylval.strval = ACE_OS::strdup (ace_tao_yytext);
    }

  return IDENTIFIER;
}

"-"?(([0-9]+"."[0-9]*)|("."[0-9]+))([eE][+-]?[0-9]+)?[lLfF]?      {
                  yylval.dval = idl_atof(ace_yytext);
                  return IDL_FLOATING_PT_LITERAL;
                }
"-"?[0-9]+[eE][+-]?[0-9]+[lLfF]?  {
                  yylval.dval = idl_atof(ace_yytext);
                  return IDL_FLOATING_PT_LITERAL;
                }

"-"[1-9][0-9]*	{
		  yylval.ival = idl_atoi(ace_yytext, 10);
		  return IDL_INTEGER_LITERAL;
	        }
[1-9][0-9]*     {
		  yylval.uival = idl_atoui(ace_yytext, 10);
		  return IDL_UINTEGER_LITERAL;
		}
"-"0[xX][a-fA-F0-9]+ {
		  yylval.ival = idl_atoi(ace_yytext, 16);
		  return IDL_INTEGER_LITERAL;
	        }
0[xX][a-fA-F0-9]+    {
                  yylval.uival = idl_atoui(ace_yytext, 16);
		  return IDL_UINTEGER_LITERAL;
		}
"-"0[0-7]*	{
		  yylval.ival = idl_atoi(ace_yytext, 8);
		  return IDL_INTEGER_LITERAL;
	      	}
0[0-7]*	        {
		  yylval.uival = idl_atoui(ace_yytext, 8);
		  return IDL_UINTEGER_LITERAL;
	      	}

(\"([^\\\"]*|\\[ntvbrfax\\\?\'\"])*\"[ \t]*)+	{
		  /* Skip the quotes */
		  char *tmp = ace_yytext;
                  for(int i = strlen(tmp) - 1; i >= 0; --i) {
                    if (isspace(tmp[i])) {
                      tmp[i] = '\0';
                    }
                    else {
                      break;
                    }
                  }
		  tmp[strlen (tmp) - 1] = '\0';
		  ACE_NEW_RETURN (yylval.sval,
                                  UTL_String (tmp + 1),
                                  IDL_STRING_LITERAL);
		  return IDL_STRING_LITERAL;
	      	}
L\"([^\\\"]*|\\u([0-9a-fA-F]{1,4}))*\"	{
		  /* Skip the bookends */
		  char *tmp = ACE_OS::strdup (ace_yytext);
		  tmp[strlen (tmp) - 1] = '\0';
		  yylval.wsval = idl_wstring_escape_reader(tmp + 2);
		  return IDL_WSTRING_LITERAL;
		}
"'"."'"		{
		  yylval.cval = ace_yytext [1];
		  return IDL_CHARACTER_LITERAL;
	      	}
"'"\\([0-7]{1,3})"'"	{
		  // octal character constant
		  yylval.cval = idl_escape_reader(ace_yytext + 1);
		  return IDL_CHARACTER_LITERAL;
		}
"'"\\[xX]([0-9a-fA-F]{1,2})"'"	{
		  // hexadecimal character constant
		  yylval.cval = idl_escape_reader(ace_yytext + 1);
		  return IDL_CHARACTER_LITERAL;
		}
"'"\\."'"	{
		  yylval.cval = idl_escape_reader(ace_yytext + 1);
		  return IDL_CHARACTER_LITERAL;
		}
L"'"."'"	{
		  // wide character constant
		  yylval.wcval = ace_yytext [2];
		  return IDL_WCHAR_LITERAL;
		}
L"'"\\u([0-9a-fA-F]{1,4})"'"	{
		  // hexadecimal wide character constant
		  yylval.wcval = idl_wchar_escape_reader(ace_yytext + 2);
		  return IDL_WCHAR_LITERAL;
		}
^[ \t]*#[ \t]*pragma[ \t].*{NL}	|
^\?\?=[ \t]*pragma[ \t].*{NL}	{/* remember pragma */
  		  idl_global->set_lineno(idl_global->lineno() + 1);
		  idl_store_pragma(ace_yytext);
		}
^[ \t]*#file[ \t].*{NL}	|
^\?\?=[ \t]*file[ \t].*{NL}	{/* ignore file */
  		  idl_global->set_lineno(idl_global->lineno() + 1);
		}
^[ \t]*#[ \t]*[0-9]*" ""\""[^\"]*"\""" "[0-9]*([ \t]*[0-9]*)?{NL}		|
^\?\?=[ \t]*[0-9]*" ""\""[^\"]*"\""" "[0-9]*([ \t]*[0-9]*)?{NL}		{
		  idl_parse_line_and_file(ace_yytext);
		}
^[ \t]*#[ \t]*[0-9]*" ""\""[^\"]*"\""{NL}		|
^\?\?=[ \t]*[0-9]*" ""\""[^\"]*"\""{NL}		{
		  idl_parse_line_and_file(ace_yytext);
		}
^[ \t]*#line[ \t]*[0-9]+[ \t]*("\""[^\"]*"\"")?{NL}		|
^\?\?=line[ \t]*[0-9]*" ""\""[^\"]*"\""{NL}		{
		  idl_parse_line_and_file(ace_yytext);
		}
^[ \t]*#[ \t]*[0-9]*{NL} |
^\?\?=[ \t]*[0-9]*{NL} {
		  idl_parse_line_and_file(ace_yytext);
	        }
^[ \t]*#[ \t]*ident[ \t].*{NL}	|
^\?\?=[ \t]*ident[ \t].*{NL}	{
		  /* ignore cpp ident */
  		  idl_global->set_lineno(idl_global->lineno() + 1);
		}
\/\/.*{NL}	{
		  /* ignore comments */
  		  idl_global->set_lineno(idl_global->lineno() + 1);
		}
"/*"		{
		  for(;;) {
		    char c = yyinput();
		    if (c == '*') {
		      char next = yyinput();
		      if (next == '/')
			break;
		      else
			yyunput(c, NULL);
	              if (c == '\n')
		        idl_global->set_lineno(idl_global->lineno() + 1);
		    }
	          }
	        }
[ \t]*		;
{NL}		{
  		  idl_global->set_lineno(idl_global->lineno() + 1);
		}
.		return ace_yytext [0];

%%
	/* subroutines */

// Parse a #line statement generated by the C preprocessor
static void
idl_parse_line_and_file (char *buf)
{
  char *r = buf;
  char *h = 0;
  UTL_String *nm = 0;

  // Skip initial '#'.
  if (*r != '#')
    {
      return;
    }
  else
    {
      r++;
    }

  // Check to see if we're running under the screwy Microsoft scheme
  // of putting #line num instead of #num.

  if (ACE_OS::strncmp (r, "line", 4) == 0)
    {
      r += 5;
    }

  // Find line number.
  while (isspace (*r))
    {
      r++;
    }

  h = r;

  for (; isdigit (*r); r++)
    {
      continue;
    }

  *r++ = 0;
  idl_global->set_lineno ((long) idl_atoui (h, 10));

  // Find file name, if present.
  for (; *r != '"'; r++)
    {
      if (*r == '\n' || *r == '\0')
        {
          return;
        }
    }

  h = ++r;

  for (; *r != '"'; r++)
    {
      continue;
    }

  *r = 0;
  UTL_String *tmp = 0;

  if (*h == '\0')
    {
      ACE_NEW (tmp,
               UTL_String ("standard input"));
      idl_global->set_filename (tmp);
      return;
    }
  else
    {
      long i;
      long j;

      // Put Microsoft-style pathnames into a canonical form.
      for (i = 0, j = 0; h[j] != '\0'; i++, j++)
        {
          if (h[j] == '\\' && h[j + 1] == '\\')
            {
	            j++;
            }

	        h[i] = h[j];
        }

      h[i] = '\0';
      ACE_NEW (tmp,
               UTL_String (h));
      idl_global->update_prefix (tmp->get_string ());
      idl_global->set_filename (tmp);
    }

  UTL_String *fname = idl_global->filename ();
  idl_bool in_main_file = I_FALSE;
  idl_bool is_real_filename = fname->compare (idl_global->real_filename ());
  idl_bool is_main_filename = I_FALSE;

  if (!is_real_filename)
    {
      is_main_filename = fname->compare (idl_global->main_filename ());
    }

  if (is_real_filename || is_main_filename)
    {
      in_main_file = I_TRUE;
    }

  idl_global->set_in_main_file (in_main_file);

  // Strip off any command line -I prefix that may have been added
  // by the preprocessor.
  if (!(idl_global->in_main_file ()) && idl_global->import ()) 
    {
      ACE_NEW (
          nm,
          UTL_String (
              idl_global->stripped_preproc_include (fname->get_string ())
            )
        );

      // This call also manages the #pragma prefix.
      idl_global->store_include_file_name (nm);
    }
}

// Store a #pragma line into the list of pragmas
static void
idl_store_pragma (char *buf)
{
  char *sp = buf + 1;
  int crunched = 0;

  // Remove all the blanks between the '#' and the 'pragma'.
  while (*sp != 'p')
    {
      ++sp;
      ++crunched;
    }

  char *tp = buf + 1;

  // This copies the crunched string back to the original, and
  // also compensates for the behavior of the Sun preprocessor,
  // which put spaces around the double colons of a non-quoted
  // scoped name, a case which is possible in #pragma version.
  while (*sp != '\n')
    {
      if (*sp == ' ' && *(sp + 1) == ':')
        {
          ++crunched;
        }
      else if (*sp == ':' && *(sp + 1) == ' ')
        {
          *tp = *sp;
          ++crunched;
          ++sp;