operation.xsl

Copyright&copy 2004 Sergiu Dumitriu, Marta G&icirc rdea, C&#259 t&#259 lin Hri&#355 cu Permission is

<?xml version="1.0" encoding="UTF-8"?>
<!--
Template: Operation.xsl

Displays Operations
-->
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns="http://www.w3.org/2000/svg" xmlns:UML="org.omg.xmi.namespace.UML">
	<xsl:import href="../Common/Styling.xsl"/>
	<xsl:import href="../Common/Stereotype.xsl"/>
	<xsl:import href="../Common/Expression.xsl"/>
	<xsl:import href="../Common/Visibility.xsl"/>
	<xsl:import href="../ClassDiagrams/Parameter.xsl"/>
	<xsl:output media-type="image/svg+xml" method="xml" indent="yes"/>

	<!-- Operation -->
	<xsl:template name="Operation">
		<xsl:param name="DiagramID" select="@xmi.id"/>
		<xsl:param name="SemanticID" select="UML:GraphElement.semanticModel/UML:Uml1SemanticModelBridge/UML:Uml1SemanticModelBridge.element/*/@xmi.idref"/>

		<!-- Main Operation group -->
		<g transform="translate({UML:GraphElement.position/XMI.field[1]}, {UML:GraphElement.position/XMI.field[2]})" id="{$DiagramID}">
			<xsl:apply-templates select="." mode="FontStyle"/>
			<xsl:apply-templates select="." mode="StrokeStyle"/>
			<xsl:apply-templates select="." mode="isVisible"/>

			<title><xsl:text>Operation </xsl:text><xsl:value-of select="key('xmi.id', $SemanticID)/@name"/></title>
			<desc><xsl:text>Operation</xsl:text></desc>

			<!-- Contained nodes -->
			<text>
				<xsl:for-each select="UML:GraphElement.contained/*">
					<xsl:choose>
						<xsl:when test="UML:GraphElement.semanticModel/UML:SimpleSemanticModelElement/@typeInfo = 'StereotypeCompartment'">
							<!-- Stereotype compartment -->
							<xsl:call-template name="Stereotype">
								<xsl:with-param name="SemanticID" select="$SemanticID"/>
							</xsl:call-template>
						</xsl:when>

						<xsl:when test="UML:GraphElement.semanticModel/UML:SimpleSemanticModelElement/@typeInfo = 'Visibility'">
							<!-- Visibility -->
							<tspan x="{UML:GraphElement.position/XMI.field[1]}" y="{UML:GraphElement.position/XMI.field[2]}">
								<xsl:call-template name="Visibility">
									<xsl:with-param name="SemanticID" select="$SemanticID"/>
								</xsl:call-template>
							</tspan>
						</xsl:when>

						<xsl:when test="UML:GraphElement.semanticModel/UML:SimpleSemanticModelElement/@typeInfo = 'Name'">
							<!-- Name -->
							<xsl:call-template name="StringTSpan">
								<xsl:with-param name="SemanticID" select="$SemanticID" />
								<xsl:with-param name="String" select="key('xmi.id', $SemanticID)/@name"/>
								<xsl:with-param name="x" select="UML:GraphElement.position/XMI.field [1]"/>
								<xsl:with-param name="y" select="UML:GraphElement.position/XMI.field [2]"/>
							</xsl:call-template>
						</xsl:when>

						<xsl:when test="UML:GraphElement.semanticModel/UML:SimpleSemanticModelElement/@typeInfo = 'ParameterStart'">
							<!-- Parameter Start -->
							<tspan x="{UML:GraphElement.position/XMI.field [1]}" y="{UML:GraphElement.position/XMI.field [2]}">(</tspan>
						</xsl:when>

						<xsl:when test="UML:GraphElement.semanticModel/UML:Uml1SemanticModelBridge/UML:Uml1SemanticModelBridge.element/UML:Parameter">
							<!-- Parameter -->
							<xsl:call-template name="Parameter"/>
						</xsl:when>

						<xsl:when test="UML:GraphElement.semanticModel/UML:SimpleSemanticModelElement/@typeInfo = 'ParameterSeparator'">
							<!-- Parameter Separator -->
							<tspan x="{UML:GraphElement.position/XMI.field [1]}" y="{UML:GraphElement.position/XMI.field [2]}">,</tspan>
						</xsl:when>

						<xsl:when test="UML:GraphElement.semanticModel/UML:SimpleSemanticModelElement/@typeInfo = 'ParameterEnd'">
							<!-- Parameter End -->
							<tspan x="{UML:GraphElement.position/XMI.field [1]}" y="{UML:GraphElement.position/XMI.field [2]}">)</tspan>
						</xsl:when>

						<xsl:when test="UML:GraphElement.semanticModel/UML:SimpleSemanticModelElement/@typeInfo = 'TypeSeparator'">
							<!-- Type separator -->
							<tspan x="{UML:GraphElement.position/XMI.field [1]}" y="{UML:GraphElement.position/XMI.field [2]}">:</tspan>
						</xsl:when>

						<xsl:when test="UML:GraphElement.semanticModel/UML:SimpleSemanticModelElement/@typeInfo = 'ExpressionCompartment'">
							<!-- Expression compartment -->
							<xsl:call-template name="Expression">
								<xsl:with-param name="SemanticID" select="$SemanticID"/>
							</xsl:call-template>
						</xsl:when>
					</xsl:choose>
				</xsl:for-each>
			</text>
		</g>
	</xsl:template>
</xsl:stylesheet>