associationclass.xsl

Copyright&copy 2004 Sergiu Dumitriu, Marta G&icirc rdea, C&#259 t&#259 lin Hri&#355 cu Permission is

<?xml version="1.0" encoding="UTF-8"?>
<!--
Template: AssociationClass.xsl

Displays AssociationClass
-->
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns="http://www.w3.org/2000/svg" xmlns:UML="org.omg.xmi.namespace.UML">
	<xsl:import href="../Common/Styling.xsl"/>
	<xsl:import href="../ClassDiagrams/Class.xsl"/>
	<xsl:import href="../Common/Lines.xsl"/>
	<xsl:output media-type="image/svg+xml" method="xml" indent="yes"/>

	<!-- AssociationClass -->
	<xsl:template name="AssociationClass">
		<xsl:param name="DiagramID" select="@xmi.id"/>
		<xsl:param name="SemanticID" select="UML:GraphElement.semanticModel/UML:Uml1SemanticModelBridge/UML:Uml1SemanticModelBridge.element/*/@xmi.idref"/>

		<!-- AssociationClass outline parameters -->
		<xsl:variable name="rx">
			<xsl:value-of select="UML:GraphNode.size/XMI.field[1] div 2"/>
		</xsl:variable>
		<xsl:variable name="ry">
			<xsl:value-of select="UML:GraphNode.size/XMI.field[2] div 2"/>
		</xsl:variable>

		<!-- Main AssociationClass group -->
		<g transform="translate({UML:GraphElement.position/XMI.field[1]}, {UML:GraphElement.position/XMI.field[2]})" id="{$DiagramID}">
			<xsl:apply-templates select="." mode="FontStyle"/>
			<xsl:apply-templates select="." mode="StrokeStyle"/>
			<xsl:apply-templates select="." mode="isVisible"/>

			<title><xsl:text>AssociationClass </xsl:text><xsl:value-of select="key('xmi.id', $SemanticID)/@name"/></title>
			<desc><xsl:text>Main AssociationClass group</xsl:text></desc>

			<!-- The outline shape, an Association Line -->
			<xsl:call-template name="Association_Line"/>

			<!-- Contained nodes -->
			<xsl:for-each select="UML:GraphElement.contained/*">
				<xsl:choose>
					<xsl:when test="UML:GraphElement.semanticModel/UML:SimpleSemanticModelElement/@typeInfo = 'AssociationClassNode'">
						<!-- Association Node, a Class -->
						<xsl:call-template name="Class">
							<xsl:with-param name="SemanticID" select="$SemanticID"/>
						</xsl:call-template>
					</xsl:when>
					<xsl:when test="UML:GraphElement.semanticModel/UML:SimpleSemanticModelElement/@typeInfo = 'AssociationClassEdge'">
						<!-- Association Edge -->
						<xsl:call-template name="AssociationClassEdge_Line"/>
					</xsl:when>
				</xsl:choose>
			</xsl:for-each>
		</g>
	</xsl:template>
</xsl:stylesheet>