nameandtype.xsl

Copyright&copy 2004 Sergiu Dumitriu, Marta G&icirc rdea, C&#259 t&#259 lin Hri&#355 cu Permission is

<?xml version="1.0" encoding="UTF-8"?>
<!--
Template: NameAndType.xsl

Displays name and type for use cases
-->
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns="http://www.w3.org/2000/svg" xmlns:UML="org.omg.xmi.namespace.UML">
	<xsl:import href="Styling.xsl"/>
	<xsl:import href="StringTSpan.xsl"/>
	<xsl:output media-type="image/svg+xml" method="xml" indent="yes"/>

	<!-- NameAndType -->
	<xsl:template name="NameAndType">
		<xsl:param name="DiagramID" select="@xmi.id"/>
		<xsl:param name="SemanticID" select="../../../../UML:GraphElement.semanticModel/UML:Uml1SemanticModelBridge/UML:Uml1SemanticModelBridge.element/*/@xmi.idref"/>

		<!-- Main NameAndType group -->
		<g transform="translate({UML:GraphElement.position/XMI.field[1]}, {UML:GraphElement.position/XMI.field[2]})" id="{$DiagramID}">
			<xsl:apply-templates select="." mode="FontStyle"/>
			<xsl:apply-templates select="." mode="isVisible"/>

			<title><xsl:text>NameAndType for </xsl:text><xsl:value-of select="$SemanticID"/></title>
			<desc><xsl:text>Main NameAndType group</xsl:text></desc>

			<!-- NameAndType text -->
			<text stroke="none" baseline-shift="-100%" text-decoration="underline">
				<xsl:for-each select="UML:GraphElement.contained/UML:GraphNode">
					<xsl:choose>
						<xsl:when test="UML:GraphElement.semanticModel/UML:SimpleSemanticModelElement/@typeInfo = 'Name'">
							<!-- Name -->
							<xsl:call-template name="StringTSpan">
								<xsl:with-param name="SemanticID" select="$SemanticID" />
								<xsl:with-param name="String">
									<xsl:value-of select="key('xmi.id', $SemanticID)/@name"/>
								</xsl:with-param>
								<xsl:with-param name="x" select="UML:GraphElement.position/XMI.field[1]" />
								<xsl:with-param name="y" select="UML:GraphElement.position/XMI.field[2]" />
							</xsl:call-template>
						</xsl:when>

						<xsl:when test="UML:GraphElement.semanticModel/UML:SimpleSemanticModelElement/@typeInfo = 'TypeSeparator'">
							<!-- Type separators, ':' -->
							<tspan x="{UML:GraphElement.position/XMI.field[1]}" y="{UML:GraphElement.position/XMI.field[2]}"><xsl:text>:</xsl:text></tspan>
						</xsl:when>

						<xsl:when test="UML:GraphElement.semanticModel/UML:Uml1SemanticModelBridge/UML:Uml1SemanticModelBridge.element/*">
							<!-- Type -->
							<xsl:variable name="TypeID">
								<xsl:value-of select="UML:GraphElement.semanticModel/UML:Uml1SemanticModelBridge/UML:Uml1SemanticModelBridge.element/*/@xmi.idref"/>
							</xsl:variable>
							<xsl:variable name="x1" select="UML:GraphElement.position/XMI.field[1]"/>
							<xsl:variable name="y1" select="UML:GraphElement.position/XMI.field[2]"/>
							<xsl:for-each select="UML:GraphElement.contained/UML:GraphNode">
								<xsl:choose>
									<xsl:when test="UML:GraphElement.semanticModel/UML:SimpleSemanticModelElement/@typeInfo = 'Name'">
										<!-- Type Name -->
										<xsl:call-template name="StringTSpan">
											<xsl:with-param name="SemanticID" select="$TypeID" />
											<xsl:with-param name="String">
												<xsl:value-of select="key('xmi.id', $TypeID)/@name"/>
											</xsl:with-param>
											<xsl:with-param name="x" select="UML:GraphElement.position/XMI.field[1] + $x1" />
											<xsl:with-param name="y" select="UML:GraphElement.position/XMI.field[2] + $y1" />
										</xsl:call-template>
									</xsl:when>
								</xsl:choose>
							</xsl:for-each>
						</xsl:when>
					</xsl:choose>
				</xsl:for-each>
			</text>
		</g>
	</xsl:template>
</xsl:stylesheet>