comment.xsl

Copyright&copy 2004 Sergiu Dumitriu, Marta G&icirc rdea, C&#259 t&#259 lin Hri&#355 cu Permission is

<?xml version="1.0" encoding="UTF-8"?>
<!--
Template: Comment.xsl

Displays a (usually) yellow rectangle with the upper right corner bent.
-->
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns="http://www.w3.org/2000/svg" xmlns:UML="org.omg.xmi.namespace.UML">
	<xsl:import href="Styling.xsl"/>
	<xsl:import href="StringTSpan.xsl"/>
	<xsl:output media-type="image/svg+xml" method="xml" indent="yes"/>

	<!-- Comment -->
	<xsl:template name="Comment">
		<xsl:param name="DiagramID" select="@xmi.id"/>
		<xsl:param name="SemanticID" select="UML:GraphElement.semanticModel/UML:Uml1SemanticModelBridge/UML:Uml1SemanticModelBridge.element/UML:Comment/@xmi.idref"/>

		<!-- Comment outline parameters -->
		<xsl:variable name="rx">
			<xsl:value-of select="UML:GraphNode.size/XMI.field[1] div 2"/>
		</xsl:variable>
		<xsl:variable name="ry">
			<xsl:value-of select="UML:GraphNode.size/XMI.field[2] div 2"/>
		</xsl:variable>

		<!-- Main Comment group -->
		<g transform="translate({UML:GraphElement.position/XMI.field[1]}, {UML:GraphElement.position/XMI.field[2]})" id="{$DiagramID}">
			<xsl:apply-templates select="." mode="FontStyle"/>
			<xsl:apply-templates select="." mode="StrokeStyle"/>
			<xsl:apply-templates select="." mode="isVisible"/>

			<desc><xsl:text>Comment</xsl:text></desc>

			<!-- Comment outline -->
			<path d="M 0 0 L {UML:GraphNode.size/XMI.field[1] - 12} 0 {UML:GraphNode.size/XMI.field[1]} 12 {UML:GraphNode.size/XMI.field[1]} {UML:GraphNode.size/XMI.field[2]} 0 {UML:GraphNode.size/XMI.field[2]} z M {UML:GraphNode.size/XMI.field[1]} 12 L {UML:GraphNode.size/XMI.field[1] - 12} 12 {UML:GraphNode.size/XMI.field[1] - 12} 0">
				<xsl:apply-templates select="." mode="FillStyle"/>
			</path>

			<!-- Comment text -->
			<text baseline-shift="-100%" stroke="none">
				<xsl:call-template name="StringTSpan">
					<xsl:with-param name="String" select="key('xmi.id', $SemanticID)/@body"/>
				</xsl:call-template>
			</text>
		</g>
	</xsl:template>
</xsl:stylesheet>