ubb.asp

中国网站网贴吧程序源码（ASP+ACCESS） 实现功能： 多级分类查找,可按多级分类查找贴吧,多用户申请,任何人都可以申请自己的贴吧, 用户三种权限管理,1,普通会员,2,普通版主(只有管理自己的贴

<%
function UBB(Content)
	Content = HTMLcode(Content)
dim re
Set re=new RegExp
re.IgnoreCase =true
re.Global=True
	
	re.Pattern="(javascript)"
	Content=re.Replace(Content,"&#106avascript")
	re.Pattern="(jscript:)"
	Content=re.Replace(Content,"&#106script:")
	re.Pattern="(js:)"
	Content=re.Replace(Content,"&#106s:")
	re.Pattern="(value)"
	Content=re.Replace(Content,"&#118alue")
	re.Pattern="(about:)"
	Content=re.Replace(Content,"about&#58")
	re.Pattern="(file:)"
	Content=re.Replace(Content,"file&#58")
	re.Pattern="(document.cookie)"
	Content=re.Replace(Content,"documents&#46cookie")
	re.Pattern="(vbscript:)"
	Content=re.Replace(Content,"&#118bscript:")
	re.Pattern="(vbs:)"
	Content=re.Replace(Content,"&#118bs:")
	re.Pattern="(on(mouse|exit|error|click|key))"
	Content=re.Replace(Content,"&#111n$2")

	re.Pattern = "\[IMG\](http|https|ftp)://(.[^\[]*)\[\/IMG\]"
	Content = re.Replace(Content,"<IMG SRC=Images/photo.gif border=0> 帖子相关图片:<br><A onfocus=this.blur() href=""$1://$2"" TARGET=_blank><IMG SRC=""$1://$2"" border=0 onload=""javascript:if(this.width>screen.width-380){this.width=screen.width-380;}""></A><br>")

	re.Pattern="\[FACE=(.[^\[]*)\](.[^\[]*)\[\/FACE\]"
	Content=re.Replace(Content,"<FONT FACE=$1>$2</FONT>")

	re.Pattern="\[COLOR=(.[^\[]*)\](.[^\[]*)\[\/COLOR\]"
	Content=re.Replace(Content,"<FONT COLOR=$1>$2</FONT>")

	re.Pattern="\[ALIGN=(center|left|right)\](.[^\[]*)\[\/ALIGN\]"
	Content=re.Replace(Content,"<DIV ALIGN=$1>$2</DIV>")

	re.Pattern="\[B\](.[^\[]*)(\[\/B\])"
	Content=re.Replace(Content,"<B>$1</B>")

	re.Pattern="\[I\](.[^\[]*)\[\/I\]"
	Content=re.Replace(Content,"<I>$1</I>")

	re.Pattern="\[U\](.[^\[]*)(\[\/U\])"
	Content=re.Replace(Content,"<U>$1</U>")

	re.Pattern="\[SIZE=([1-5])\](.[^\[]*)\[\/SIZE\]"
	Content=re.Replace(Content,"<FONT SIZE=$1>$2</FONT>")
	Content=replace(Content,"<I></I>","")


set re=Nothing
UBB=Content
end function

Function FilterJS(v)
	if not isnull(v) then
		dim t
		dim re
		dim reContent
		Set re=new RegExp
		re.IgnoreCase =true
		re.Global=True
		re.Pattern="(javascript)"
		t=re.Replace(v,"&#106avascript")
		re.Pattern="(jscript:)"
		t=re.Replace(t,"&#106script:")
		re.Pattern="(js:)"
		t=re.Replace(t,"&#106s:")
		re.Pattern="(value)"
		t=re.Replace(t,"&#118alue")
		re.Pattern="(about:)"
		t=re.Replace(t,"about&#58")
		re.Pattern="(file:)"
		t=re.Replace(t,"file&#58")
		re.Pattern="(document.cookie)"
		t=re.Replace(t,"documents&#46cookie")
		re.Pattern="(vbscript:)"
		t=re.Replace(t,"&#118bscript:")
		re.Pattern="(vbs:)"
		t=re.Replace(t,"&#118bs:")
		re.Pattern="(on(mouse|exit|error|click|key))"
		t=re.Replace(t,"&#111n$2")
		re.Pattern="(&#)"
		t=re.Replace(t,"＆#")
		FilterJS=t
		set re=nothing
	end if
End Function

function HTMLcode(Content)
	if not isnull(Content) then
		Content = Replace(Content, "  ","&nbsp;&nbsp;")
		Content = Replace(Content, ">", "&gt;")
		Content = Replace(Content, "<", "&lt;")
		Content = Replace(Content, "\", "\\")
		Content = Replace(Content, CHR(34), "&quot;")
		Content = Replace(Content, CHR(39), "&#39;")
		Content = Replace(Content, CHR(13), "")
		Content = Replace(Content, CHR(10) & CHR(10), "</P><P> ")
		Content = Replace(Content, CHR(10), "<BR>")
		HTMLcode = Content
	end if
end function
%>

<%
Function PostString(Content)
	if not isnull(Content) then
		Content = Replace(Content, "'","''")
		PostString = Content
	end if
End Function

Function ShowString(Content)
	if not isnull(Content) then
		Content = Replace(Content, "  ","&nbsp;&nbsp;")
		Content = Replace(Content, ">", "&gt;")
		Content = Replace(Content, "<", "&lt;")
		Content = Replace(Content, CHR(13), "")
		Content = Replace(Content, CHR(10), "<BR>")
		Content = Replace(Content, CHR(34), "&quot;")
		Content = Replace(Content, CHR(39), "&#39;")
		ShowString = Content
	end if
End Function
%>