ad_infoproperty.asp

该软件是帮助大学生更好的生活

<%@language=vbscript codepage=936 %>
<%
option explicit
response.buffer=true	
Const PurviewLevel=2
Const CheckChannelID=2
Const PurviewLevel_Article=3
%>
<!--#include file="inc/conn.asp"-->
<!--#include file="inc/config.asp"-->
<!--#include file="ad_ChkPurview.asp"-->
<!--#include file="inc/Conn_User.asp"-->
<!--#include file="inc/func.asp"-->
<!--#include file="inc/ad_code_info.asp"-->
<%
dim ArticleID,Action,sqlProperty,rsProperty,FoundErr,ErrMsg,PurviewChecked
dim ClassID,tClass,ClassName,RootID,ParentID,Depth,ParentPath,Child,ChildID,tID,tChild,ClassMaster
ArticleID=trim(request("ArticleID"))
Action=Trim(Request("Action"))
FoundErr=False
if ArticleId="" then
	FoundErr=True
	ErrMsg=ErrMsg & "<br><li>请先选定文章！</li>"
end if
if Action="" then
	FoundErr=True
	ErrMsg=ErrMsg & "<br><li>参数不足！</li>"
end if
if FoundErr=False then
	call SetProperty()
end if
if FoundErr=False then
	call CloseConn()
	response.Redirect ComeUrl
else
	call CloseConn()
	call WriteErrMsg()
end if

sub SetProperty()
	if instr(ArticleID,",")>0 then
		ArticleID=replace(ArticleID," ","")
		sqlProperty="select * from Article where ArticleID in (" & ArticleID & ")"
	else
		ArticleID=Clng(ArticleID)
		sqlProperty="select * from article where ArticleID=" & ArticleID
	end if
	Set rsProperty= Server.CreateObject("ADODB.Recordset")
	rsProperty.open sqlProperty,conn,1,3
	do while not rsProperty.eof
		PurviewChecked=False
		ClassID=rsProperty("ClassID")
		if AdminPurview=1 or AdminPurview_Article<=2 then
			PurviewChecked=True
		else
			if Action="SetPassed" or Action="CancelPassed" then
				set tClass=conn.execute("select ClassName,RootID,ParentID,Depth,ParentPath,Child,ClassChecker From ArticleClass where ClassID=" & ClassID)
			else
				set tClass=conn.execute("select ClassName,RootID,ParentID,Depth,ParentPath,Child,ClassMaster From ArticleClass where ClassID=" & ClassID)
			end if
			if tClass.bof and tClass.eof then
				founderr=True
				ErrMsg=ErrMsg & "<br><li>找不到指定的栏目</li>"
			else
				ClassName=tClass(0)
				RootID=tClass(1)
				ParentID=tClass(2)
				Depth=tClass(3)
				ParentPath=tClass(4)
				Child=tClass(5)
				ClassMaster=tClass(6)
				PurviewChecked=CheckClassMaster(tClass(6),AdminName)
				if PurviewChecked=False and ParentID>0 then
					if Action="SetPassed" or Action="CancelPassed" then
						set tClass=conn.execute("select ClassChecker from ArticleClass where ClassID in (" & ParentPath & ")")
					else
						set tClass=conn.execute("select ClassMaster from ArticleClass where ClassID in (" & ParentPath & ")")
					end if
					do while not tClass.eof
						PurviewChecked=CheckClassMaster(tClass(0),AdminName)
						if PurviewChecked=True then exit do
						tClass.movenext
					loop
				end if
			end if
		end if
		if PurviewChecked=False then
			FoundErr=True
			ErrMsg=ErrMsg & "<br><li>对 " & rsProperty("ArticleID") & " 没有操作权限！</li>"
		else
			select case Action
			case "SetOnTop"
				rsProperty("OnTop") = True
			case "CancelOnTop"
				rsProperty("OnTop") = False
			case "SetElite"
				rsProperty("Elite") = True
			case "CancelElite"
				rsProperty("Elite") = False
			case "SetPassed"
				rsProperty("Passed") =True
				Conn_User.execute("update " & db_User_Table & " set " & db_User_ArticleChecked & "=" & db_User_ArticleChecked & "+1 where " & db_User_Name & "='" & rsProperty("Editor") & "'")
			case "CancelPassed"
				rsProPerty("Passed") =False
				Conn_User.execute("update " & db_User_Table & " set " & db_User_ArticleChecked & "=" & db_User_ArticleChecked & "-1 where " & db_User_Name & "='" & rsProperty("Editor") & "'")
			end select
			rsProperty.update
		end if
		rsProperty.movenext
	loop
	rsProperty.close
	set rsProperty=nothing
end sub
%>