ksskinheader.pas

来自「小区水费管理系统源代码水费收费管理系统 水费收费管理系统」· PAS 代码 · 共 225 行

{==============================================================================

  SkinEngine's Header
  Copyright (C) 2000-2002 by Evgeny Kryukov
  All rights reserved

  All conTeThements of this file and all other files included in this archive
  are Copyright (C) 2002 Evgeny Kryukov. Use and/or distribution of
  them requires acceptance of the License Agreement.

  See License.txt for licence information

  $Id: ksskinheader.pas,v 1.1.1.1 2002/08/05 12:12:13 Evgeny Exp $

===============================================================================}

unit ksskinheader;

{$I se_define.inc}
{$T-,W-,X+,P+}

interface

uses
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms,
  se_controls, KsSkinEngine, KsSkinObjects, KsSkinVersion;

type

{ TSeSkinHeaderControl class }

  TSeSkinHeaderControl = class(TSeCustomHeaderControl)
  private
    FSkinEngine: TSeSkinEngine;
    FSkinHeader: TSeSkinObject;
    FSkinObject: string;
    function GetVersion: TSeSkinVersion;
    procedure SetSkinEngine(const Value: TSeSkinEngine);
    procedure SetVersion(const Value: TSeSkinVersion);
    procedure SetSkinObject(const Value: string);
  protected
    procedure WMInvalidateSkinObject(var Msg: TMessage); message WM_INVALIDATESKINOBJECT;
    procedure WMBeforeChange(var Msg: TMessage); message WM_BEFORECHANGE;
    procedure WMSkinChange(var Msg: TMessage); message WM_SKINCHANGE;

    function UseSkin: boolean;
    { overrides }
    procedure DrawSection(Section: TSeHeaderSection; ARect: TRect;
      AState: TSeSectionState); override;
    procedure DrawTailSection(ARect: TRect); override;
  public
    constructor Create(AOwner: TComponent); override;
    destructor Destroy; override;
  published
    property SkinEngine: TSeSkinEngine read FSkinEngine write SetSkinEngine;
    property SkinObject: string read FSkinObject write SetSkinObject;
    property Version: TSeSkinVersion read GetVersion write SetVersion
      stored false;
  end;

implementation {===============================================================}

{ TSeSkinHeaderControl ===============================================================}

constructor TSeSkinHeaderControl.Create(AOwner: TComponent);
begin
  inherited Create(AOwner);
  FSkinObject := 'Header';
end;

destructor TSeSkinHeaderControl.Destroy;
begin
  if FSkinHeader <> nil then FSkinHeader.Free;
  inherited Destroy;
end;

function TSeSkinHeaderControl.UseSkin: boolean;
begin
  if (csDestroying in ComponentState) or (csLoading in ComponentState) then
    Result := false
  else
    if (FSkinEngine <> nil) and (FSkinEngine.SkinSource <> nil) and
       (not FSkinEngine.SkinSource.IsChanging) and
       (FSkinEngine.SkinSource.Count > 0) and
       (FSkinEngine.SkinSource.GetObjectByName(FSkinObject) <> nil) and
       (FSkinHeader <> nil)
    then
      Result := true
    else
      Result := false;
end;

procedure TSeSkinHeaderControl.WMInvalidateSkinObject(var Msg: TMessage);
begin
  Invalidate;
end;

procedure TSeSkinHeaderControl.WMBeforeChange(var Msg: TMessage);
begin
  if Pointer(Msg.LParam) = nil then Exit;
  if TSeSkinEngine(Msg.LParam) <> FSkinEngine then Exit;

  if FSkinHeader <> nil then FSkinHeader.Free;
  FSkinHeader := nil;
end;

procedure TSeSkinHeaderControl.WMSkinChange(var Msg: TMessage);
begin
  if Pointer(Msg.LParam) = nil then Exit;
  if TSeSkinEngine(Msg.LParam) <> FSkinEngine then Exit;

  SkinEngine := FSkinEngine;
end;

procedure TSeSkinHeaderControl.DrawSection(Section: TSeHeaderSection;
  ARect: TRect; AState: TSeSectionState);
var
  Offset: TPoint;
  SkinObject: TSeSkinObject;
begin
  if UseSkin then
  begin
    SkinObject := FSkinHeader.FindObjectByName('Section');
    if SkinObject = nil then
      SkinObject := FSkinHeader;

    if AState = ssDraggedOut then
      SkinObject.State := ssDisabled
    else
      if AState = ssUnderDrag then
        SkinObject.State := ssPressed
      else
        if AState in [se_controls.ssPressed] then
          SkinObject.State := ssPressed
        else
          if AState in [se_controls.ssHot, ssDraggin] then
            SkinObject.State := ssHot
          else
            SkinObject.State := ssNormal;

    SkinObject.BoundsRect := ARect;
    SkinObject.Draw(Canvas);

    ControlFont.Assign(SkinObject.Font);

    { Drwa text and glyph } 
    Offset := Point(0,0);
    if AState in [se_Controls.ssPressed, ssDraggedOut, ssUnderDrag] then Offset := Point(1,1);

    if Section.Style = hsOwnerDraw then
      DoDrawSection(Self, Section, ARect, AState)
    else
    begin
      DrawSectionText(Section, ARect, Offset, AState);
      if Section.ShowImage then
        DrawSectionImage(Section, ARect, Offset, AState);
    end;
  end
  else
    inherited;
end;

procedure TSeSkinHeaderControl.DrawTailSection(ARect: TRect);
var
  SkinObject: TSeSkinObject;
begin
  if UseSkin then
  begin
    SkinObject := FSkinHeader.FindObjectByName('Section');
    if SkinObject = nil then
      SkinObject := FSkinHeader;

    SkinObject.State := ssNormal;
    SkinObject.BoundsRect := ARect;
    SkinObject.Draw(Canvas);
  end
  else
    inherited;
end;

{ Properties }

function TSeSkinHeaderControl.GetVersion: TSeSkinVersion;
begin
  Result := sSeSkinVersion;
end;

procedure TSeSkinHeaderControl.SetSkinEngine(const Value: TSeSkinEngine);
begin
  FSkinEngine := Value;

  if (FSkinEngine <> nil) and (FSkinEngine.SkinSource <> nil) and
     (not FSkinEngine.SkinSource.IsChanging) and
     (FSkinEngine.SkinSource.Count > 0) then
  begin
    if FSkinHeader <> nil then FSkinHeader.Free;
    FSkinHeader := nil;

    if FSkinEngine.SkinSource.GetObjectByName(FSkinObject) <> nil then
      FSkinHeader := FSkinEngine.SkinSource.GetObjectByName(FSkinObject).CreateCopy(nil);

    if FSkinHeader <> nil then
      FSkinHeader.ParentControl := Self;
  end
  else
  begin
    if FSkinHeader <> nil then FSkinHeader.Free;
    FSkinHeader := nil;
  end;

  Invalidate;
end;

procedure TSeSkinHeaderControl.SetVersion(const Value: TSeSkinVersion);
begin

end;

procedure TSeSkinHeaderControl.SetSkinObject(const Value: string);
begin
  FSkinObject := Value;
end;

end.