ksskinsplitter.pas

来自「小区水费管理系统源代码水费收费管理系统 水费收费管理系统」· PAS 代码 · 共 176 行

{==============================================================================

  SkinEngine's Splitter
  Copyright (C) 2000-2002 by Evgeny Kryukov
  All rights reserved

  All conTeSkinnts of this file and all other files included in this archive
  are Copyright (C) 2002 Evgeny Kryukov. Use and/or distribution of
  them requires acceptance of the License Agreement.

  See License.txt for licence information

  $Id: ksskinsplitter.pas,v 1.1.1.1 2002/08/05 12:12:14 Evgeny Exp $

===============================================================================}

unit ksskinsplitter;

{$I se_define.inc}
{$T-,W-,X+,P+}

interface

uses
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms,
  se_controls, KsSkinEngine, KsSkinObjects, KsSkinVersion;

type

{ TSeSkinSplitter class }

  TSeSkinSplitter = class(TSeCustomSplitter)
  private
    FSkinEngine: TSeSkinEngine;
    FSkinSplitter: TSeSkinObject;
    FSkinObject: string;
    function GetVersion: TSeSkinVersion;
    procedure SetSkinEngine(const Value: TSeSkinEngine);
    procedure SetVersion(const Value: TSeSkinVersion);
    procedure SetSkinObject(const Value: string);
  protected
    procedure WMInvalidateSkinObject(var Msg: TMessage); message WM_INVALIDATESKINOBJECT;
    procedure WMBeforeChange(var Msg: TMessage); message WM_BEFORECHANGE;
    procedure WMSkinChange(var Msg: TMessage); message WM_SKINCHANGE;

    function UseSkin: boolean;
    { overrides }
    procedure PaintBuffer; override;
  public
    constructor Create(AOwner: TComponent); override;
    destructor Destroy; override;
  published
    property SkinEngine: TSeSkinEngine read FSkinEngine write SetSkinEngine;
    property SkinObject: string read FSkinObject write SetSkinObject;
    property Version: TSeSkinVersion read GetVersion write SetVersion
      stored false;
  end;

implementation {===============================================================}

{ TSeSkinSplitter ===============================================================}

constructor TSeSkinSplitter.Create(AOwner: TComponent);
begin
  inherited Create(AOwner);
  FSkinObject := 'Splitter';
end;

destructor TSeSkinSplitter.Destroy;
begin
  if FSkinSplitter <> nil then FSkinSplitter.Free;
  inherited Destroy;
end;

function TSeSkinSplitter.UseSkin: boolean;
begin
  if (csDestroying in ComponentState) or (csLoading in ComponentState) then
    Result := false
  else
    if (FSkinEngine <> nil) and (FSkinEngine.SkinSource <> nil) and
       (not FSkinEngine.SkinSource.IsChanging) and
       (FSkinEngine.SkinSource.Count > 0) and
       (FSkinEngine.SkinSource.GetObjectByName(FSkinObject) <> nil) and
       (FSkinSplitter <> nil)
    then
      Result := true
    else
      Result := false;
end;

procedure TSeSkinSplitter.PaintBuffer;
begin
  if not UseSkin then
    inherited
  else
  begin
    FSkinSplitter.State := ssNormal;
    FSkinSplitter.BoundsRect := Rect(0, 0, Width, Height);
    FSkinSplitter.Draw(Canvas);

    if csDesigning in ComponentState then
    with Canvas do
    begin
      Pen.Style := psDot;
      Pen.Mode := pmXor;
      Pen.Color := clBtnFace;
      Brush.Style := bsClear;
      Rectangle(0, 0, Width, Height);
    end;
  end;
end;

{ Properties }

function TSeSkinSplitter.GetVersion: TSeSkinVersion;
begin
  Result := sSeSkinVersion;
end;

procedure TSeSkinSplitter.SetSkinEngine(const Value: TSeSkinEngine);
begin
  FSkinEngine := Value;

  if (FSkinEngine <> nil) and (FSkinEngine.SkinSource <> nil) and
     (not FSkinEngine.SkinSource.IsChanging) and
     (FSkinEngine.SkinSource.Count > 0) then
  begin
    if FSkinSplitter <> nil then FSkinSplitter.Free;
    FSkinSplitter := nil;

    if FSkinEngine.SkinSource.GetObjectByName(FSkinObject) <> nil then
      FSkinSplitter := FSkinEngine.SkinSource.GetObjectByName(FSkinObject).CreateCopy(nil);
  end
  else
  begin
    if FSkinSplitter <> nil then FSkinSplitter.Free;
    FSkinSplitter := nil;
  end;

  Invalidate;
end;

procedure TSeSkinSplitter.SetVersion(const Value: TSeSkinVersion);
begin

end;

procedure TSeSkinSplitter.SetSkinObject(const Value: string);
begin
  FSkinObject := Value;
end;

procedure TSeSkinSplitter.WMInvalidateSkinObject(var Msg: TMessage);
begin
   Invalidate;
end;

procedure TSeSkinSplitter.WMBeforeChange(var Msg: TMessage);
begin
  if Pointer(Msg.LParam) = nil then Exit;
  if TSeSkinEngine(Msg.LParam) <> FSkinEngine then Exit;

  if FSkinSplitter <> nil then FSkinSplitter.Free;
  FSkinSplitter := nil;
end;

procedure TSeSkinSplitter.WMSkinChange(var Msg: TMessage);
begin
  if Pointer(Msg.LParam) = nil then Exit;
  if TSeSkinEngine(Msg.LParam) <> FSkinEngine then Exit;

  SkinEngine := FSkinEngine;
end;

end.