displaysmallworkrec.asp

一个用asp和sql server开发的网上办公系统

<!--#include file="office_open.asp"-->
<%
function displaysmallworkrec(myday,username)
'在日历表中显示myday的日期,如果是当前日期显示成红色
if cdate(myday)=cdate(date) then
   displaysmallworkrec="<a href='displayworkrec.asp?username=" & username &  "&recdate=" & myday & "'><font color=red><b>" & Day(myday) & "号</b></font></a>"
else
   displaysmallworkrec="<a href='displayworkrec.asp?username=" & username & "&recdate=" & myday & "'>" & Day(myday) & "号</a>"
end if
'打开数据库，读出日期为myday，用户名为username的记录
set conn=opendb
set rs=server.createobject("adodb.recordset")
  sql="select * from workrep where username=" & sqlstr(username) & " and recdate='"& myday &"'"
rs.open sql,conn,1
'读出纪录
if not rs.eof and not rs.bof then
   displaysmallworkrec=displaysmallworkrec & "<hr size=1 color=red width='80%'><table>"
   while not rs.eof and not rs.bof
        '判断完成程度，并显示不同的颜色
        Select case  rs("finished")        
             case -1   titlecolorfront="<font color='red'>"
             case 0      titlecolorfront="<font color='blue'>"
             case 1      titlecolorfront="<font color=''>"
        End select
        titlecolorback="</font>"
		'分行显示同一天的每一个工作计划
        displaysmallworkrec=displaysmallworkrec & "<tr><td><font color=red>△</font><a href=#  title='计划主题：" &rs("title")& VbCrLf &"简要说明："&rs("remark")& VbCrLf &"执行时间："&rs("recdate")&"'>"& titlecolorfront & rs("title") & titlecolorback & "</a></td></tr>"
   rs.movenext
   wend
   displaysmallworkrec=displaysmallworkrec & "</table>"
end if
set rs=nothing
closedb(conn)   '关闭数据库
end function
%>