marcospb.asp

程序网络论坛HigroupBBS v4.00 默认管理员帐号密码都是Marcos

<%
	dim skinCss,mySkinId,borderColor

	function getPageCode(skinId,pageName)
		getPageCode=getApp(pageName&"_"&mySkinId)
	end function

	function getMainCode(skinId)
		dim userName,copyRights
		styleRoot=getApp("styleRoot_"&mySkinId)
		getMainCode=getApp("PageMain_"&mySkinId)
		if getValue("userMessage")<>"" then
			getMainCode=replace(getMainCode,"{$messClass}",getValue("userMessage"))
		end if
		getMainCode=replace(getMainCode,"{$skinCss}",getApp("skinCss_"&mySkinId))
		
		copyRights="<font face=""Wingdings"">v</font> {$sysName} <font face=""Wingdings"">v</font><br>Powered By <a href=""javascript:;"" title=""QQ 26696782"">Marcos</a> 2004.10"
		getMainCode=replace(getMainCode,"{$copyRights}",copyRights)

		getMainCode=replace(getMainCode,"{$topTitle}",getApp("sysTitle"))
		getMainCode=replace(getMainCode,"{$sysName}",getApp("sysName"))
		getMainCode=replace(getMainCode,"{$welcomeWords}",getApp("welcomeWords"))
		if getValue("userName")="" then
			userName="游客"
		 else
			userName=getValue("userName")
			if left(userName,2)="游客" then
				userName="游客"
			end if
		end if
		getMainCode=replace(getMainCode,"{$userName}",userName)
		if fixNull(getApp("siteLogo"))<>"" then
			getMainCode=replace(getMainCode,"{$siteLogo}",getApp("siteLogo"))
		 else
			getMainCode=replace(getMainCode,"{$siteLogo}","")
		end if
		if fixNull(getApp("siteBanner"))<>"siteBanner" then
			getMainCode=replace(getMainCode,"{$siteBanner}",getApp("siteBanner"))
		 else
			getMainCode=replace(getMainCode,"{$siteBanner}","")
		end if
	end function
	
	sub showHead(str,pageTitle,pageOther)
		dim top,code,topMenu1,topMenu2,topMenu3,menu
		code=split(str,"$$$")
		top=code(0)
		menu=code(4)
		topMenu1=code(1)
		topMenu2=code(2)
		topMenu3=code(3)
		select case getValue("userLevel")
			case ""
				top=replace(top,"{$topMenu}",topMenu1)
			case "1"
				top=replace(top,"{$topMenu}",topMenu2)
			case "999"
				top=replace(top,"{$topMenu}",topMenu3)
		end select
		top=replace(top,"{$userId}",getValue("userId"))
		menu=replace(menu,"{$pageTitle}",pageTitle)
		menu=replace(menu,"{$pageOther}",pageOther)
		echo top & "<script language=""javascript"" src=""MarcosJS.js""></script>" & menu
	end sub
	
	sub showFoot(str)
		dim code
		code="<div id='dypopLayer' style='position:absolute;z-index:1000;' class='cPopText'></div>"
		code=code & split(str,"$$$")(5)
		code=replace(code,"{$executeTime}",(timer-sTime)*1000 & " ms")
		code=replace(code,"{$queryTimes}",queryTimes)
		echo code
	end sub
	
	sub updateSkin(id)
		dim rs
		set rs=server.createObject("adodb.recordSet")
		sql="select * from Marcos_Skin where skinId=" & id
		rs.open sql,conn,1,1
		setApp "skinName_"&rs("skinId"),rs("skinName")
		setApp "skinCss_"&rs("skinId"),rs("skinCss")
		setApp "pageMain_"&rs("skinId"),rs("pageMain")
		setApp "pageIndex_"&rs("skinId"),rs("pageIndex")
		setApp "pageRegister_"&rs("skinId"),rs("pageRegister")
		setApp "pageProfile_"&rs("skinId"),rs("pageProfile")
		setApp "pageUserInfo_"&rs("skinId"),rs("pageUserInfo")
		setApp "pageLogin_"&rs("skinId"),rs("pageLogin")
		setApp "pageFormx_"&rs("skinId"),rs("pageFormx")
		setApp "pageShow_"&rs("skinId"),rs("pageShow")
		setApp "pageList_"&rs("skinId"),rs("pageList")
		setApp "pageOnline_"&rs("skinId"),rs("pageOnline")
		setApp "pageSearch_"&rs("skinId"),rs("pageSearch")
		setApp "pageStyle_"&rs("skinId"),rs("pageStyle")
		setApp "styleRoot_"&rs("skinId"),rs("dirRoot")
		setApp "borderColor_"&rs("skinId"),rs("borderColor")
		setApp "tableWidth_"&rs("skinId"),rs("tableWidth")
		rs.close
		queryTimes=queryTimes+1
		set rs=nothing
		delPageIndex()
	end sub

	sub updateAllSkin()
		dim rs,skinIdList
		set rs=server.createObject("adodb.recordSet")
		sql="select * from Marcos_Skin order by theOrder"
		rs.open sql,conn,1,1
		setApp "skinIdList",""
		for i=1 to rs.recordCount
			skinIdList=skinIdList&","&i
			setApp "skinName_"&i,rs("skinName")
			setApp "skinCss_"&i,rs("skinCss")
			setApp "pageMain_"&i,rs("pageMain")
			setApp "pageIndex_"&i,rs("pageIndex")
			setApp "pageRegister_"&i,rs("pageRegister")
			setApp "pageProfile_"&i,rs("pageProfile")
			setApp "pageUserInfo_"&i,rs("pageUserInfo")
			setApp "pageLogin_"&i,rs("pageLogin")
			setApp "pageFormx_"&i,rs("pageFormx")
			setApp "pageShow_"&i,rs("pageShow")
			setApp "pageList_"&i,rs("pageList")
			setApp "pageOnline_"&i,rs("pageOnline")
			setApp "pageSearch_"&i,rs("pageSearch")
			setApp "pageStyle_"&i,rs("pageStyle")
			setApp "styleRoot_"&i,rs("dirRoot")
			setApp "borderColor_"&i,rs("borderColor")
			setApp "tableWidth_"&i,rs("tableWidth")
			rs.movenext
		next
		skinIdList=mid(skinIdList,2)
		setApp "skinIdList",skinIdList
		rs.close
		queryTimes=queryTimes+1
		set rs=nothing
		delPageIndex()
	end sub
	
	sub updateSysInfo()
		dim rs
		set rs=server.createObject("adodb.recordSet")
		sql="select sysTitle,sysName,welcomeWords,siteLogo,siteBanner,isHalted,haltInfo,noGuest from Marcos_Config"
		rs.open sql,conn,1,1
		setApp "sysTitle",rs(0)
		setApp "sysName",rs(1)
		setApp "welcomeWords",rs(2)
		setApp "siteLogo",rs(3)
		setApp "siteBanner",rs(4)
		setApp "isHalted",rs(5)
		setApp "haltInfo",rs(6)
		setApp "noGuest",rs(7)
		rs.close
		queryTimes=queryTimes+1
		set rs=nothing
		delPageIndex()
	end sub
	
	sub updateUsage(skinId)
		dim i
		i=instr(getApp("skinIdList"),skinId)
		if i<=0 then
			skinId=""
		end if
		if skinId="" then
			skinId="1"
		end if
		skinCss=getApp("skinCss_"&skinId)
		skinCss=replace(skinCss,"{$styleRoot}",getApp("styleRoot_"&skinId))
		borderColor=getApp("borderColor_"&skinId)
		mySkinId=skinId
	end sub

	sub delApp()
		dim i,app,appList
		appList=split("skinName,tableWidth,skinCss,pageMain,pageIndex,pageIndexCode,pageListCode,pageRegister,pageProfile,pageUserInfo,pageLogin,pageFormx,pageShow,pageList,pageOnline,pageSearch,pageStyle,borderColor",",")
		for each app in application.contents
			for i=0 to uBound(appList)
				if instr(lcase(app),lcase(m&appList(i)&"_"))>0 then
					application.lock
					application.contents.remove(app)
					echo " 重建 "&app&"<br>"
					application.unLock
				end if
			next
		next
		application.lock()
		application.Contents.Remove(m&"skinIdList")
		application.unLock()
	end sub
	
	sub delPageIndex()
		dim i,j,n
		n=ubound(split(getApp("skinIdList"),","))+1
		for i=1 to n
			application.lock
			for j=1 to (200/listNum+1)
				application.contents.remove(m&"pageListCode_"&i&"_"&j)
			next
			application.contents.remove(m&"PageIndexCode_"&i)
			application.unLock
		next
	end sub
	
	sub haveNewMess()
		if getValue("userId")<>"" then
			if getValue("userMessageTimer")="" then
				setValue "userMessageTimer",timer()
			end if
			if timer()-getValue("userMessageTimer")>30 and getValue("userMessage")="" then
				sql="select isRead from Marcos_Message where toUser='"&getValue("userName")&"' and isRead=False"
				getConn()
				set rs_sys=conn.execute(sql)
				queryTimes=queryTimes+1
				if not rs_sys.eof then
					setValue "userMessage","class=warningColor"
				 else
					setValue "userMessage",""
				end if
				closeConn()
				setValue "userMessageTimer",timer()
			end if
		end if
	end sub

	sub setApp(var,val)
		application.lock()
		application(m&var)=val
		application.unLock()
	end sub
	
	function getApp(var)
		getApp=trim(application(m&var))
	end function
%>