index.asp

程序网络论坛HigroupBBS v4.00 默认管理员帐号密码都是Marcos

<!--#include file="MarcosCB.asp"-->
<%
	dim i,str,list,mList,pageCode,pageTitle,pageOther,PageIndex

	getConn()
	str=getMainCode(mySkinId)
	
	pageTitle="<a href=index.asp>首页</a>"
	pageOther="<script>document.title+=' - 首页';</script>"
	nowWhere "论坛首页","index.asp"

	pageCode=getPageCode(mySkinId,"PageIndex")
	PageIndex=split(pageCode,"$$$")

	showHead str,pageTitle,pageOther
	showBody()
	showFoot(str)

	sub showBody()
		
		dim str,body,theBody,tableEnd,tableStart

		if getApp("pageIndexCode_"&mySkinId)<>"" then
			echo getApp("pageIndexCode_"&mySkinId)
			exit sub
		end if

		sql="select boardId,boardName from Marcos_Board where topBoardId=0 order by bigOrder"
		set rs_sys=conn.execute(sql)
		queryTimes=queryTimes+1
		do until rs_sys.eof
			theBody=""
			tableStart=PageIndex(0)
			tableEnd=PageIndex(2)
			tableStart=replace(tableStart,"{$fatherBoardName}",rs_sys(1))
			sql="select * from Marcos_Board where topBoardId="&rs_sys(0)&" order by smallOrder"
			rs.open sql,conn,1,1
			queryTimes=queryTimes+1
			do until rs.eof
				body=PageIndex(1)
				body=replace(body,"{$boardName}",rs("boardName"))
				body=replace(body,"{$topicCount}",rs("topicCount"))
				body=replace(body,"{$replyCount}",rs("replyCount"))
				if rs("lastPostInfo")<>"" then
					body=replace(body,"{$lastPostInfo}",rs("lastPostInfo"))
				 else
					body=replace(body,"{$lastPostInfo}","<div align=center>暂无帖子</div>")
				end if
				if rs("boardManagerList")<>"" then
					mList=""
					list=split(rs("boardManagerList"),",")
					for i=0 to ubound(list)
						mList=mList & "<a href=""userInfo.asp?userName="&list(i)&""" target=_blank>"&list(i)&"</a><br>"
					next
				 else
					mList="暂无版主"
				end if
				body=replace(body,"{$boardManagerList}",mList)
				body=replace(body,"{$boardDescription}",enCodeStr(rs("boardDescription")))
				body=replace(body,"{$boardLink}","topicList.asp?boardName=" & rs("boardName") & "&boardId=" & rs("boardId"))
				theBody=theBody&body
				rs.movenext
			loop
			rs.close

			str=str&tableStart&theBody&tableEnd
			rs_sys.movenext
		loop

		str=str&PageIndex(0)
		str=replace(str,"{$fatherBoardName}","<a href=""voteList.asp"">系统投票区</a>")
		sql="select top 1 * from Marcos_Vote order by lastVoteTime desc"
		rs.open sql,conn,1,1
		if rs.eof then
			str=str&"<tr height=""53""><td align=""center"" colspan=6>暂时没有任何投票</td></tr>"
		 else
			str=str&"<tr align=center height=""39""><td colspan=6><img src="""&rs("voteMood")&"""> "&rs("voteTitle")&_
				"&nbsp;&nbsp;&nbsp;&nbsp;作者:"&rs("userName")&"&nbsp;&nbsp;&nbsp;&nbsp;最后更新:"&rs("lastVoteTime")&"</td></tr>"
		end if
		rs.close
		queryTimes=queryTimes+1
		str=str&PageIndex(2)
		setApp "pageIndexCode_"&mySkinId,str
		echo str
	end sub
	
	closeConn()
%>