thml2asp.vbs

较为详细的介绍了asp自定义的各种函数,方便asp的各种开发.

Option Explicit

'类
Class clsHTML2ASP
	Private objFSO
	Private strHTMLurl
	Private ForReading
	Private ForWriting

	'类初始
	Private Sub Class_Initialize
		ForReading = 1
		ForWriting = 2
		Set objFSO = CreateObject("Scripting.FileSystemObject")
	End Sub
	'类销毁
	Private Sub Class_Terminate
		Set objFSO = Nothing
	End Sub
	
	'设置属性
	Public Property Let Path(getHTMLurl)
		strHTMLurl = getHTMLurl
	End Property

	'进行HTML到ASP文件的转换
	Public Function HTML2ASP(strASPurl)
		Dim objFile,arrText
		Dim strHTML,strASP
		Dim i

		'读取HTML文件内容
		On Error Resume Next
		Set objFile = objFSO.OpenTextFile(strHTMLurl, ForReading)
		strHTML = objFile.ReadAll
		objFile.Close
		If Err.Number<>0 Then HTML2ASP = Err.Description:Err.Clear:Exit Function

		arrText = Split(strHTML,vbCrLf)
		For i=0 to UBound(arrText)
			strASP = strASP & "Response.Write """ & Replace(arrText(i),"""","""""") & """" & vbCrLf
		Next

		'写入ASP文件内容
		On Error Resume Next
		Set objFile = objFSO.OpenTextFile(strASPurl, ForWriting, True)
		objFile.Write strASP
		objFile.Close
		If Err.Number<>0 Then HTML2ASP = Err.Description:Err.Clear:Exit Function

		HTML2ASP = "转换成功"
	End Function
End Class


Dim HTML2ASP
Set HTML2ASP = New clsHTML2ASP
With HTML2ASP
	.Path="c:\test.htm"
	MsgBox(.HTML2ASP("c:\test.asp"))
End With