bootsect.asm

这是一本操作系统辅导教材的辅助资料

;Ver 2.2  @2003 5.28
;Ver 2.1  By Charles @ 2003.4.13
;Ver 2.00 By Toby    @ 2003.3.27
;Ver 1.1  By Charles
;Ver 1.00 Created by Toby
			;NASM-IDE ASM Assistant Assembler Project File
[BITS 16]		;Set code generation to 16 bit mode
[ORG 0x7C00]		;Set code start address to 7C00h
MEMSTART      EQU  8000h; The Fat&Root Temp Position in Memory
[SEGMENT .text]		;Main code segment
;Before Our Code BIOS Using Real Mode
JMP START
NOP                     ;Must Be 3 Bytes Long
db 'PCOS'               ;Sign Must Be 8 Bytes Long
TIMES 0xB-($-$$) db 0   ;Next Line Start at 0x000B
dw 0x200                ;512 bytes per track
db 0x1                  ;An Alloc Unit Have Only One Sector
ReservedSectors dw 0x1  ;Only One Sector Reserved (Hiden)
NumberOfFat db 0x2      ;The Number Of FAT
RootEntries dw 0xE0     ;The Number Of Root Entries
dw 0xB40                ;Total Sector
                        ;For 3.5 Floppy 2*18*80
db 0xF0                 ;F0 3.5, 2S, 18Sec 1.44 MB 2.88 MB
                        ;F9 5.25, 2S, 15Sec 720 KB 1.2 MB
                        ;FC 5.25", 1S, 9Sec 180 KB
                        ;FD 5.25", 2S, 9Sec 360 KB
                        ;FE 5.25", 1S, 8Sec 160 KB
                        ;FF 5.25", 2S, 8Sec 320 KB
                        ;F8 N/A Fixed Disk
FatSize dw 0x9          ;2880 units * 12 bits per units
                        ;/ 8 bits per bytes
                        ;/ 512 bytes per sector
SectorsPerTrack dw 0x12 ;18 sector per track
NumberOfHeads dw 0x2    ;The Number Of Heads
dw 0,0                  ;Hiden Sector ??
TIMES 0x3E-($-$$) db 0  ;Must Start at 3E

;----------------------Load A Sector From Flopppy-----------------
;----Load File predo------
ReadDataSector:
mov ax,[SaveEs]         ;The File should be stored at SaveEs:SavePoint
mov es,ax               ;Limit 1000:0000 -- 9000:9E00  512k+40k
mov ax,[SavePoint]      ;The Sector will be stored at ES:ReadPoint
mov [ReadPoint],ax      ;So I do saved the Es:Readpoint
jmp StartRead
ReadSector:
mov ax,MEMSTART           ;Put 8000h in AX for init Readpoint
mov [ReadPoint],ax      ;init ReadPoint with 8000h
jmp ReadFat
ReadSecond:
mov ax,MEMSTART+200h
mov [ReadPoint],ax
ReadFat:
xor ax,ax
mov es,ax               ;ES:BX must be 0000:8000 or 0000:8200
StartRead:
mov ax,[SectorToRead]   ;Get the SectorToRead to Judge if we should read
cmp ax,[Sector]         ;if the Sector is loaded ,don't do again
je .Return              ;if don't need read ,go back
.Reset:
xor ah,ah               ;clear AH for reset drive
xor dl,dl
int 13h                 ;reset drive
jc .Reset               ;redo if failed
.Read:
xor dx,dx
mov ax,[SectorToRead]   ;Get to SectorToRead to calc int 13 parameter
mov cx,[SectorsPerTrack] ;put sector number of a cluster in CL
                        ;to calc Sector Position
div cx                  ;divide ax to two parts
mov cx,dx               ;the part AL means sector position ,Put in cl
inc cl                  ;sector start at 1 not 0
xor dx,dx
mov bx,[NumberOfHeads]
div bx
mov dh,dl               ;the part AH means head and cluster
xor dl,dl
mov ch,al               ;the part AH put in CH to calc cluster
mov ax,0201h            ;AH is 2 mean read,AL is 1 mean read only one sector
mov bx,[ReadPoint]      ;the sector will be stored in ReadPoint
int 13h                 ;read a data sector
jc .Read                ;if failed ,redo
.Return:
ret                     ;read successful ,go back

START:
xor ax,ax
cli                     ;Stop Interupt for init Stack
mov ss,ax
mov sp,7c00h            ;reset Stack
sti                     ;Recover Interrupt
mov ds,ax               ;Set DS=0
;----------------------Read Root & Find File---------------
;---Calc Root Position---
mov ax,[FatSize]
mov bl,[NumberOfFat]
mul bl
add ax,[ReservedSectors];AX=FatSize*NumberOfFat+ReservedSectors
                        ;1.44M AX=9*2+1=13
mov [SectorToRead],ax   ;AX mean where RootSector is
;---Calc Data Position--
mov ax,[RootEntries]
shr ax,4                ;AX=RootEntries/10,AX is RootSize 1.44M AX=E
add ax,[SectorToRead]   ;Data is saved after Root 1.44M 21
dec ax
dec ax                  ;I don't why there is two,but there is
mov [DataSector],ax     ;Saved DataSector 1.44M 1F
;---End Calc------

ReadRoot:
call ReadSector         ;Read One RootSector
mov di,[ReadPoint]      ;Put Sector Begin in DI for search file
mov dx,10h              ;A Sector can save 10h fileitems
                        ;so we have to compare 10h times
FindFile:
mov si,FileName         ;Put target filename Begin in SI for compare
                        ;the name is OS.PCS
mov cx,0bh              ;FileName is 0bh bytes long
repz cmpsb               ;compare FileName if it is OS.PCS
jz .YetFind
add di,cx               ;Mov DI to End of the FileName
add di,15h              ;Mov DI to First of Next FileItem
mov cx,[RootEntries]
inc word [RootPoint]
cmp [RootPoint],cx
.Hang:
jae .Hang
dec dx                  ;If not Find,Dec DX to Continue Find
cmp dx,0                ;compare DX with 0 to Judge If the Sector is end
jne FindFile            ;If Not End Continue Comp
inc word [SectorToRead] ;Move Point to Next Sector
jmp ReadRoot            ;If End Read Next Sector And Compare
.YetFind:
mov cx,[es:di+0fh]        ;Get File Position
jcxz .YetFind           ;If the file is blank,stop
;----------------End of FindFile----------------

;-----------------Read File---------------------
;----Read A Sector------
ReadASector:
add cx,[DataSector]     ;Calc the Absolute Position
                        ;CX=DataSector+FileSector
mov [SectorToRead],cx   ;Put the FilePosition in SectorToRead
call ReadDataSector     ;Read One Sector of File Content
;----Find Next Sector---
mov bx,[SectorToRead]   ;Put SectorToRead in BX for calc Fat Position
sub bx,[DataSector]     ;Calc the Position in Data Table
                        ;BX=SectorToRead-DataSector
mov cx,bx
push bx                 ;Save Data Position to Judge First 12 or Last 12
shr bx,1                ;Div BX,2
add bx,cx               ;BX=(SectorToRead-DataSector)*1.5
push bx                 ;Save Floppy Position to Read Fat Item
shr bx,9                ;Calc Position in Fat Sectors
add bx,[ReservedSectors];Calc Position in Floppy
mov [SectorToRead],bx   ;Put BX in SectorToRead
call ReadSector
mov bx,word [SectorToRead]
mov [Sector],bx
inc word [SectorToRead]
call ReadSecond
mov ax,[SavePoint]      ;Begin Calc Next Data sector position in memory
add ax,200h             ;Add sector size to get new memory position
mov [SavePoint],ax      ;Put New Memory Position to SavePoint
;######JMP INSIDE
jnc .NOADDES
mov bx,[SaveEs]         ;Get Now Section Position
add bx,1000h            ;Add Section Size to get new section position
mov [SaveEs],bx         ;End Calc
.NOADDES:
;######
pop bx                  ;Load Floppy Position to Read Fat Item
;---------OK POP SECOND BX------------------------/
and bx,01ffh            ;Mod BX,200h to Calc Fat Item Position in Fat Memory
add bx,MEMSTART         ;Calc Fat Item Position in Memory
mov cx,[es:bx]          ;Load Next Data Sector Position
pop bx                  ;Load Data Position to Judge First 12 or Last 12
;---------OK POP FIRST BX-------------------------------/
test bx,1               ;test BX odd or even
je .NOMOVE              ;if even,mean Last 12,if odd mean First 12
shr cx,4                ;Div cx,16 to move the First 12 to the Last 12
.NOMOVE:
and cx,0fffh            ;Mod cx,1000h to get the Last 12
cmp cx,0ff8h            ;compare CX with ff8 to test if the file is end
jb ReadASector          ;if above the file is end otheswise not end
;-------------Reset Floppy For Our Driver
xor ah,ah               ;clear AH for reset drive
xor dl,dl
int 13h                 ;reset drive
;-----------Ready To Boot -------

mov ah,0                ;Set Video
mov al,3h              ;To 640*480
int 10h                 ;Call BIOS
cli                     ; Clear or disable interrupts
lgdt [gdtr]             ; Load GDT
mov eax,cr0             ; The lsb of cr0 is the protected mode bit
or al,0x01              ; Set protected mode bit
mov cr0,eax             ; Mov modified word to the control register
jmp codesel:go_pm       ; Protected Mode Jump

[BITS 32]
go_pm :                 ; Now Protected Mode
mov ax,datasel
mov ds,ax               ; Initialise ds & es to data segment
mov es,ax
mov fs,ax
mov gs,ax
mov ss,ax
mov eax,0x7c00
mov esp,eax
jmp dword 0x10000
;----------------------------------------------------------
FileName      db 'OS      PCS' ; file to load
SaveEs        dw 1000h         ; Section for Read File
SavePoint     dw 0             ; Position for Read File
gdtr :
dw gdt_end-gdt-1        ; Length of the gdt
dd gdt                  ; Physical address of gdt
gdt:
nullsel equ $-gdt       ; $->current location,so nullsel = 0h
gdt0:                   ; Null descriptor,as per convention gdt0 is 0
dd 0                    ; Each gdt entry is 8 bytes, so at 08h it is CS
dd 0                    ; In all the segment descriptor is 64 bits
codesel equ $-gdt       ; This is 8h,ie 2nd descriptor in gdt
code_gdt:               ; Code descriptor 4Gb flat segment at 0000:0000h
dw 0x0ffff              ; Limit 4Gb  bits 0-15 of segment descriptor
dw 0x0000               ; Base 0h bits 16-31 of segment descriptor (sd)
db 0x00                 ; Base addr of seg 16-23 of 32bit addr,32-39 of sd
db 0x09a                ; P,DPL(2),S,TYPE(3),A->Present bit 1,Descriptor
                        ; privilege level 0-3,Segment descriptor 1 ie code
                        ; or data seg descriptor,Type of seg,Accessed bit
db 0x0cf                ; Upper 4 bits G,D,0,AVL ->1 segment len is page
                        ; granula, 1 default operation size is 32bit seg
                        ; AVL : Available field for user or OS
                        ; Lower nibble bits 16-19 of segment limit
db 0x00                 ; Base addr of seg 24-31 of 32bit addr,56-63 of sd
datasel equ $-gdt       ; ie 10h, beginning of next 8 bytes or data sd
data_gdt:               ; Data descriptor 4Gb flat seg at 0000:0000h
dw 0x0ffff              ; Limit 4Gb
dw 0x0000               ; Base 0000:0000h
db 0x00                 ; Descriptor format same as above
db 0x092
db 0x0cf
db 0x00
gdt_end:
ReadPoint     dw 0             ; Memory Position for Read operation
SectorToRead  dw 0             ; Sector will be read
DataSector    dw 0             ; Data Sector begin
Sector        dw 0             ; Sector in memory
RootPoint     dw 0
TIMES 0x1FE-($-$$) db 0
ENDSTAMP dw 0xAA55