fet410_wdt01.s43

MSP430常用的程序源代码,很全的,一定适合你(初学者)!

#include  "msp430x41x.h"
;******************************************************************************
;   MSP-FET430P410 Demo - WDT Toggle P5.1 Interval overflow ISR, DCO SMCLK 
;
;   Description; Toggle P5.1 using software timed by the WDT ISR. Toggle rate 
;   is approximately 30ms based on default ~ 800khz DCO/SMCLK clock source 
;   used in this example for the WDT.  
;   ACLK = n/a, MCLK = SMCLK = default DCO
;
;                 MSP430F413
;             -----------------
;         /|\|              XIN|-  
;          | |                 |
;          --|RST          XOUT|-
;            |                 |
;            |             P5.1|-->LED
;
;   M.Buccini
;   Texas Instruments, Inc
;   January 2002
;******************************************************************************
;------------------------------------------------------------------------------ 
            ORG     0E000h                  ; Program Start
;------------------------------------------------------------------------------ 
RESET       mov.w   #300h,SP                ; Initialize stackpointer
SetupWDT    mov.w   #WDT_MDLY_32,&WDTCTL    ; WDT ~32ms interval timer 
            bis.b   #WDTIE,&IE1             ; Enable WDT interrupt 
SetupP1     bis.b   #002h,&P5DIR            ; P5.1 output
            eint                            ; Enable interrupts
                                            ;						  
Mainloop    bis.w   #CPUOFF,SR              ; CPU off
            nop                             ; Required for C-spy
                                            ;
;------------------------------------------------------------------------------
WDT_ISR;    Toggle P5.1
;------------------------------------------------------------------------------
            xor.b   #002h,&P5OUT            ; Toggle P5.1
            reti                            ;		 
                                            ;   
;----------------------------------------------------------------------------- 
;           Interrupt Vectors Used MSP430F41x          
;----------------------------------------------------------------------------- 
            ORG     0FFFEh                  ; MSP430 RESET Vector
            DW      RESET                   ; 
            ORG     0FFF4h                  ; WDT Vector
            DW      WDT_ISR                 ; 
            END