shopdisplaycategories.asp

本软件可以实现的功能如下： 用户管理

<!--#include file="shop$db.asp"-->
<%
'****************************************************************
' VP-ASP Version 2.0  Display shop categories
' displays a list of categories from Shopping Database
' April 5, 2000 Fix Error handling
' Version 2.3     Add Subcategories
'****************************************************************
'
ShopPageHeader               ' Page header for shop
CategoryHeader               ' category header on this page
Showcategories               ' format categories on this page
ShopPageTrailer              ' shop page trailer
'
' Show Categories
Sub ShowCategories()
'****************************************************************
' VP-ASP Version 2.0  Display shop categories
' loops through category table and calls FormatCategory
' Dear Developer you may want to alter
' CategoryHeader    ' at bottom
' FormatCategory    ' at bottom 
'****************************************************************
Dim rs
dim lngcatid
dim strcategory
Dim dbc
ShopOpenDatabase dbc
Set rs = Server.CreateObject ("ADODB.Recordset")
rs.Open "categories", dbc, adOpenForwardOnly,adLockReadOnly,adCmdTable
While Not rs.EOF
   lngcatid=rs("类别ID")
   strcategory=rs("商品类别")
   strsubcategory=rs("子类别")
   if isNULL(strsubcategory) then
       strsubcategory=""
   end if 
   FormatCategory lngcatid, strcategory
   rs.MoveNext
Wend
response.write "</table>"
rs.Close
set rs=nothing
ShopCloseDatabase dbc
end sub
'*************************************
Sub CategoryHeader
' displays header for categories
%>
<p align="center">商品类别如下：</p>
<table width="200"  cellspacing="1" cellpadding="2" align="center" bgcolor="#000000">
<%
end sub
' ***********Format Category
Sub FormatCategory (id, name)
dim mycolor
mycolor="#00aa99"
Response.write " <TR bgColor=" & mycolor & "><TD><p align=center>"
response.write "<a HREF=shopdisplayproducts.asp?id=" & id & "&amp;cat=" & Server.URLEncode(name) & ">" &  name & "</a></td></tr>"
end sub 
%>