vfpfptrap.s

realview22.rar

;;; vfpfptrap.s
;;; VFP IEEE FP Trap handler
;;; called by the computation engine:
;;; a wrapper around the standard _fp_trap handler in the C Library
;;; Copyright (C) ARM Limited, 2002. All rights reserved.

        IMPORT _fp_trap

        AREA |.text._vfp_fp_trap|, CODE, READONLY

        CODE32
        PRESERVE8

_vfp_fp_trap PROC
        EXPORT _vfp_fp_trap

        STMFD sp!, {r14}
        FRAME PUSH {r14}

;;; Save callee-save VFP registers
        FSTMFDX sp!, {d0-d7}
        FRAME PUSH 8*8+4

;;; allocate space for _fp_trap stack args
;;; and preserve 8 byte stack alignment
        SUB sp, sp, #8
        FRAME PUSH 8

;;; copy stack args (uint32 edata)
        LDR ip, [sp, #(4 + 8*8+4 + 8)]
        STR ip, [sp, #0]

        BL _fp_trap

        ADD sp, sp, #8
        FRAME POP 8

;;; Restore callee-save VFP registers
        FLDMFDX sp!, {d0-d7}
        FRAME POP 8*8+4

        LDMFD sp!, {pc}
        FRAME POP {pc}

        ENDP

        END
;;; end of file vfpfptrap.s