postmessagegetu.pas

DelphiWin32核心API参考光盘内容.是学习书籍中的源码,便于学习.

unit PostMessageGetU;

interface

uses
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
  StdCtrls, ComCtrls;

var
  UserMessage: UINT;

type
  TForm1 = class(TForm)
    Label1: TLabel;
    ProgressBar1: TProgressBar;
    Label2: TLabel;
    Label3: TLabel;
    procedure FormCreate(Sender: TObject);
  private
    { Private declarations }
    procedure DefaultHandler(var Msg); override;
  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation

{$R *.DFM}

procedure TForm1.DefaultHandler(var Msg);
var
  iLoop: Integer;      // a general loop control variable
begin
  {allow default message handling to occur}
  inherited DefaultHandler(Msg);

  {if the message was our user defined message...}
  if TMessage(Msg).Msg=UserMessage then
  begin
    {...turn on some user interface components}
    ProgressBar1.Visible := TRUE;
    Label2.Visible := TRUE;

    {indicate if the message was sent via one of the SendMessage functions}
    if InSendMessage then Label3.Visible := TRUE;

    {repaint the form}
    Form1.Repaint;

    {animate the progress bar for a short amount of time}
    for iLoop := 0 to 100 do
    begin
      ProgressBar1.Position := iLoop;
      Sleep(10);
    end;

    {turn off the user interface elements}
    ProgressBar1.Visible := FALSE;
    Label2.Visible := FALSE;
    Label3.Visible := FALSE;

    {indicate the message was handled}
    TMessage(Msg).Result := 1;
  end;
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  {register a user defined message}
  UserMessage := RegisterWindowMessage('PostMessage Test Message');
end;


end.