uploadface.asp

自由领域ASP+WAP同学录(V1.0)系统是一套仿ChinaRen的即可用电脑浏览又可以用手机访问的互动同学录单班级系统。这套系统同学录系统可以满足现在WAP普及的今天同学用手机上网交流的需求

<!--#include file=../INC/txlconst.asp-->
<!--#include file=../INC/txlfun.asp-->
<!--
<pre>
┌─ 自由领域ASP+WAP同学录系统 ─────────────────┐
│                                                               │
│  感谢你使用 自由领域ASP+WAP同学录系统(测试版）                │
│  使用本免费源码您必须遵守以下规定                             │
│    不得公开发表代码 不得用做商业用途，不得向其他使用者收费。  │
│                                                               │
│  使用时，请保留此段信息，谢谢配合                             │
│                                                               │
│                                       2004/12/19              │
│                                                               │
└────────────────  http://99167.jahee.com ───┘
</per>
-->
<%
dim const_txl_HomeUrl,errstr,login_username
login_username=Session("username")
If login_username="" Then 
	Call SiteHead2 (const_txlname&"-上传头像")
	Response.write "<center><font style='font-size:12px;color:red' ><br><br>还没有登录或连接会话超时，请先登录！<br><a href=javascript:window.close()>[关闭窗口]</a></font></center>"
	Call SiteBottom2
	Response.End
End If
errstr=""
const_txl_HomeUrl="../"
OpenDatabase
SiteHead2 const_txlname&"-"&login_username&"-上传头像"
call online
Select Case Request.QueryString("action")
	Case "upload":
		Call uploadface
	Case Else:
		Call main
End Select 
CloseDatabase
Call SiteBottom2
Sub main
	
%>
<div align="center">
  <form action="?action=upload" method="post" enctype="multipart/form-data" name="form1">
    【限<font color="red"><%=const_MaxUploadFaceSize%></font>K,.jpg,.gif,.bmp】<br>
    <input type="file" name="file">
    &nbsp; 
    <input type="submit" name="Submit" value="上传">
    <br>
  </form>
  【<a href="javascript:window.close()">关闭窗口</a>】</div>
<%
End Sub

Sub uploadface
	if outsitesubmit Then
		Call printerror ("上传头像出错","<li>请不要外部提交数据！</li>",400)
		exit sub
	End If
	if const_EnableUploadface<>1 then
		errstr=errstr&"<li>同学录当前设置<font color='red'>不能上传头像</font>!</li>"
		errstr=errstr&"<li>如果还有疑问请与管理员联系!</li>"
		Call printerror("上传头像出错！",errstr,400)
		Exit Sub
	End If
%>
<!--#include file=../INC/upload_5xsoft.inc-->
<%
	'on error resume next
	Dim upload,file,formName,FileExp,iCount,TotalSize,filename
	set upload=new upload_5xsoft
	If not isobject(upload) Then
		Call printerror ("上传头像出错","<li>服务器不支持该上传对象！</li>",400)
		upflag=False
		exit sub
	End If
	iCount=0
	For each formName in upload.objFile 
		Set file=upload.file(formName)  
		If file.FileSize>0 Then         
			FileExp=Right(file.FileName,Len(file.FileName)-InstrRev(file.FileName,".")+1)
			FileExp=lcase(FileExp)
			if FileExp<>".jpg" and FileExp<>".gif" and FileExp<>".bmp" then
				Call printerror ("上传头像出错","<li>不能上传该格式的文件！</li>",400)
				exit sub
			End IF
			TotalSize=file.FileSize/1024
			If TotalSize>const_MaxUploadFaceSize Then
				Call printerror ("上传头像出错","<li>所传文件已经大于同学录设定的允许值<font color=red>"&const_MaxUploadFaceSize&"K</font>，当前所传文件大小"&FormatNumber(TotalSize,1)&"Kb！</li>",400)
				exit sub
			End If
			randomize
			filename="face_"&hour(now)&minute(now)&Cstr(Int(1000*rnd))&FileExp
			File.SaveAs Server.mappath(const_txl_HomeUrl&const_faceuploadurl2&filename)   ''保存文件
			iCount=iCount+1
		Else 
			Call printerror ("上传头像出错","<li>上传数据为空，请检查该文件是否存在！</li>",400)
			exit sub
		 End If
		Set File=nothing
	next
	set upload=nothing  ''删除此对象
	Response.write "<script>"&Vbcrlf
	Response.write "opener.document.txlfrm.faceimg.src='../"&const_faceuploadurl2&filename&"';"&Vbcrlf
	Response.write "opener.document.txlfrm.txl_FaceUrl.value='"&const_faceuploadurl2&filename&"';"&Vbcrlf
	Response.write "alert('上传成功!');"&Vbcrlf
	Response.write "window.close();"&Vbcrlf
	Response.write "</script>"&Vbcrlf
End Sub


function SiteBottom2
	Response.Write "<a name=bottom></a>"&vbcrlf
	Response.Write "<table width='98%' border='0' cellspacing='0' cellpadding='0' align='center' bgcolor='#ffffff'>"&vbcrlf
  	Response.Write "	<tr>"&vbcrlf 
	Response.Write "		<td height=8 background='"&const_txl_HomeUrl&"images/nevb.gif'></td>"&vbcrlf
  	Response.Write "	</tr>"&vbcrlf
  	Response.Write "	<tr>"&vbcrlf 
   	Response.Write "		<td  style='border:#e6e6e6 1px solid;font-size:12px;text-align:center;line-height:1.8;'>"&vbcrlf
    Response.Write 			const_copyright&vbcrlf
    Response.Write 			"<br>"&vbcrlf
    Response.Write "		Copyright &copy;2003 <a href='http://99167.jahee.com' target='_blank'><font face=Verdana, Arial, Helvetica, sans-serif style=font-size:10px><b>自由领域</b></font></a>  Powered by ：<a href=http://99167.jahee.com/ target=_blank title='同学录'><font color=gray style='text-DECORATION: none'> V2.0</font></a>"&vbcrlf
 	Response.Write " 		页面执行时间:" & fix(abs(CDBL(Timer)*1000 - DEF_PageExeTime1)) & "ms"&vbcrlf
    Response.Write "		</td>"&vbcrlf
  	Response.Write "	</tr>"&vbcrlf
	Response.Write "</table>"&vbcrlf
	Response.Write "</BODY>"&vbcrlf
	Response.Write "</HTML>"&vbcrlf
end function
%>