user.inc

物业管理和办公自动化系统

<%
'************************************************************************************************
' 函数名　: FormUser(sAccountid)
' 输　入　: sAccountid:用户名
' 输　出　: 相关用户的信息表单，并且提供修改用户角色和重置密码的功能
' 功能描述: 提供相关用户的修改用户角色和重置密码的功能
' 调用模块: user.asp
' 作　者　: 蔡晓燕
' 日　期　: 2002-08-02
' 版　本　: 
'************************************************************************************************
Function FormUser(sAccountid)
	'----------------------------------------------------------
	' 根据用户名，显示相关用户的信息，提供修改用户角色和重置密码的功能
	'----------------------------------------------------------
	dim sSQL, sTemp, sTempButtons, sAssociate, crs, rs, iRoleid
	sSQL = "select * from T_account where account_id = "& Tosql(sAccountid,"text")
'	response.write sSQL
'	response.end
	set crs = New CRecordset
	set rs = crs.open(dbLocal,sSQL)
	if not rs.eof then 
		iRoleid = crs.GetValue("role_id")
		sTempButtons=_
		"		<img border=0 src=""../images/button/update.gif"" style=""cursor:hand"" name=btnUpdate>" &_
		"		<img border=0 src=""../images/button/resetpwd.gif"" style=""cursor:hand"" name=btnResetpwd>" &_
		"		<img border=0 src=""../images/button/return.gif"" style=""cursor:hand"" name=btnReturn>" 
	else
		response.write "<script language=""javascript"">alert('对不起，不存在该用户！')</script>"
		response.write "<script language = vbscript>window.navigate(""list_user.asp"")</script>"
	end if

	FormUser=_
		"<table cellspacing=0 cellpadding=0 width=600 align=center border=1>" & _
		"<tr><td>"&_
		TableTitle("用户信息维护", 600, "", "#0040a0") & _
		"<table cellspacing=0 cellpadding=0 width=600 align=center border=0 class=tablelist>" & _
		"<form name=""frmuser"" method=post action=""user.asp"">" &_
		"<tr height=30>" & _
		"	<td width=115 class=tdlist align=right>用户名：</td>"&_
		"	<td width=485 class=tdlist >"&sAccountid&"</td>"& _
		"</tr>" & _
		"<tr height=30>" & _
		"	<td width=115 class=tdlist align=right>用户姓名：</td>"&_
		"	<td width=485 class=tdlist >"&TransEmpId(dbLocal,sAccountid)&"</td>"& _
		"</tr>" & _
		"<tr height=30>" & _
		"	<td width=115 class=tdlist align=right>用户原角色：</td>"&_
		"	<td width=485 class=tdlist >"&TransRole(dbLocal,iRoleid)&"</td>"& _
		"</tr>" & _
		"<tr height=30>" & _
		"	<td width=115 class=tdlist align=right>用户新角色：</td>"&_
		"	<td width=485 class=tdlist ><select name=""roleid"" style=""width:86px"">" &_
		RoleSelectOptions(iRoleid)&_
		"		</select>" & _
		"	</td>" & _
		"</tr>" & _
		"<tr>" &_
		"   <input type=hidden name=formaction>" & _
		"   <input type=hidden name=page value="""&iPage&""">" & _
		"   <input type=hidden name=roleid1 value="""&iRoleid1&""">" & _
		"   <input type=hidden name=status value="""&iStatus&""">" & _
		"   <input type=hidden name=accountid value="""&sAccountid&""">" & _
		"</tr>"&_
		"<tr height=50>" & _
		"	<td colspan=2 align=center>" & sTempButtons & _
		"	</td>" & _
		"</tr>" & _
		"</form>"&_
		"</table>"
End Function

'************************************************************************************************
' 函数名　: TableLink()
' 输　入　: 
' 输　出　: 
' 功能描述: 	会议申请表页面上到其他页面的连接
' 调用模块: user.asp
' 作　者　: 蔡晓燕
' 日　期　: 2002-07-11
' 版　本　: 
'************************************************************************************************
Function TableLink()
	TableLink = _
		"<table width=600 cellspacing=0 cellpadding=0 border=0 align=center>" & _
		"<tr height=30>" & _ 
		"	<td width=600><img src=""../images/bg/line.gif"" width=600 height=3></td>" & _
		"</tr>" & _
		"<tr height=30>" & _
		"	<td width=600>&nbsp;" & _
		"		<img src=""../images/goto.gif"" width=11 height=11>&nbsp;<a href=""user.asp"">填写会议申请</a>" & _
		"		&nbsp;&nbsp;&nbsp;" & _
		"		<img src=""../images/goto.gif"" width=11 height=11>&nbsp;<a href=""list_checkmeeting.asp"">审批会议申请</a>" & _
		"		&nbsp;&nbsp;&nbsp;" & _
		"		<img src=""../images/goto.gif"" width=11 height=11>&nbsp;<a href=""list_reuser.asp"">修改会议申请表</a></td>" & _
		"</tr>" & _
		"</table>"
End Function

'************************************************************************************************
' 函数名　: UpdateUser()
' 输　入　: 
' 输　出　: 
' 功能描述: 更新用户信息
' 调用模块: user.asp
' 作　者　: 蔡晓燕
' 日　期　: 2002-08-02
' 版　本　: 
'************************************************************************************************
Sub UpdateUser()
'	定义变量
	dim sSQL, sError, sFormaction, crs, rs, sAccountid, iRoleid
'   获取表单的数据
	sAccountid = GetParam("accountid")
	iRoleid = GetParam("roleid")
	sFormaction = GetParam("formaction")
	select case sFormaction
	case "resetpwd"
'		response.write "resetpwd of "&sAccountid
		sSQL = "update t_account set password = " & Tosql(sAccountid,"text") & "where account_id=" & Tosql(sAccountid,"text")
		sError = ExecuteSQL(dbLocal, sSQL)

		sSQL = "update t_email set password = " & Tosql(sAccountid,"text") & "where userid=" & Tosql(sAccountid,"text")
		sError = ExecuteSQL(dbLocal, sSQL)
		
		if sError <> "" then
			Response.Write "<script language=""javascript"">alert('对不起，重置用户密码出错，请查看数据库！')</script>"
		else 
			Response.Write "<script language=""javascript"">alert('重置用户密码成功！')</script>"
		end if

	case "updaterole"
'		response.write "update role of "& sAccountid&" to "&Transrole(dbLocal, iRoleid)
		sSQL = "update t_account set role_id =" & Tosql(iRoleid,"number") & "where account_id=" & Tosql(sAccountid,"text")
		sError = ExecuteSQL(dbLocal, sSQL)
		if sError <> "" then
			Response.Write "<script language=""javascript"">alert('对不起，更新用户角色出错，请查看数据库！')</script>"
		else
			Response.Write "<script language=""javascript"">alert('更新用户角色成功！')</script>"
		end if
	end select
'	response.write "<script language=vbscript>window.navigate(""list_user.asp?roleid="&iRoleid1&"&status="&iStatus&"&page="&iPage&""")</script>"
	response.write "<script language=vbscript>window.navigate(""list_user.asp?page="&iPage&""")</script>"
End Sub

%>