msg_common.inc

物业管理和办公自动化系统

<%
Dim conMsgBulletin			: conMsgBulletin = 0
Dim conMsgCommon		: conMsgCommon = 1
Dim conMsgTaskRemind	: conMsgTaskRemind = 3
Dim conMsgRMRemind	: conMsgRMRemind = 4		' Routine Meeting Remind
%>

<%
function getEmps()
	Dim RS, optSuffix, valPrefix, valSuffix, opts
	openrs RS, "select Emp_id, Name from T_Employee where Emp_id <> " & ToSQL(Session("UserID"),"Text") & " and dismissed = 0 and co_id = "&session("co_id")&" and isdummy=0 order by Emp_id"
	optSuffix = "</OPTION>" & vbNewLine 
	valPrefix = "<OPTION Value='" 
	valSuffix = "'>" 
	opts = RS.GetString( , , valSuffix, optSuffix & valPrefix, "--error--" ) 
	opts = Left( opts, Len(opts)-Len(valPrefix) )  'This line is the key to it! 
'	getEmps = "<select name=employee multiple size=6 style='width:80px'>" & vbNewLine & valPrefix & opts & "</select>"
	getEmps = valPrefix & opts
	rs.close
	Set rs = nothing
end function

function getReceivers()
	' 选取所有未离职的员工发布公告信息
	Dim RS, optSuffix, valPrefix, valSuffix, opts
	openrs RS, "select Emp_id from T_Employee where dismissed = 0 and co_id = " & session("co_id") & " and isdummy=0 order by Emp_id"
	Dim empSuffix : empSuffix = ","
	emps = RS.GetString( , , "", empSuffix, "--error--" ) 
	emps = Left( emps, Len(emps) - 1 )
	getReceivers = emps
	rs.close
	Set rs = nothing
end function

function newMessage(paramMessageType, paramSubject, paramContent, paramSender, paramReceiver, paramParent)
	Set cmd = Server.CreateObject("ADODB.Command")
	cmd.CommandType = adCmdStoredProc
	cmd.CommandText = "Proc_NewMessage"
	cmd.ActiveConnection = cn

	Dim prcRet:Set prcRet = Server.CreateObject("ADODB.Parameter")
	prcRet.Direction = adParamReturnValue
	prcRet.Type = adInteger

	Dim MessageType:Set MessageType = Server.CreateObject("ADODB.Parameter")
	MessageType.Type = adInteger
	MessageType.Value = paramMessageType
	MessageType.Direction = adParamInput

	Dim Subject:Set Subject = Server.CreateObject("ADODB.Parameter")
	Subject.Type = adVarChar
	Subject.Value = paramSubject
	Subject.Direction = adParamInput
	Subject.Size = 50

	Dim Content:Set Content = Server.CreateObject("ADODB.Parameter")
	Content.Type = adVarChar
	Content.Value = paramContent
	Content.Direction = adParamInput
	Content.Size=1024

	Dim Sender:Set Sender=Server.CreateObject("ADODB.Parameter")
	Sender.Type = adVarChar
	Sender.Value = paramSender
	Sender.Direction = adParamInput
	Sender.Size=20

	Dim Receiver:Set Receiver = Server.CreateObject("ADODB.Parameter")
	Receiver.Type = adVarChar
	Receiver.Value = paramReceiver
	Receiver.Direction = adParamInput
	Receiver.Size = 1024

	Dim Parent:Set Parent = Server.CreateObject("ADODB.Parameter")
	Parent.Type = adInteger
	Parent.Value = paramParent
	Parent.Direction = adParamInput

	cmd.Parameters.Append(prcRet)
	cmd.Parameters.Append(MessageType)
	cmd.Parameters.Append(Subject)
	cmd.Parameters.Append(Content)
	cmd.Parameters.Append(Sender)
	cmd.Parameters.Append(Receiver)
	cmd.Parameters.Append(Parent)

	cmd.Execute NULL,NULL,adCmdStoredProc
	
	newMessage = prcRet

	Set cmd = nothing
	Set prcRet = nothing
	Set MessageType = nothing
	Set Subject = nothing
	Set Content = nothing
	Set Sender = nothing
	Set Receiver = nothing
end function
%>