list_routinemeeting.inc

物业管理和办公自动化系统

<%
'************************************************************************************************
' 函数名　: TableHeader()
' 输　入　: 
' 输　出　: 一个用于显示例会列表的表头
' 功能描述: 
' 调用模块: list_routinemeeting.asp
' 作　者　: 蔡晓燕
' 日　期　: 2002-07-25
' 版　本　: 
'************************************************************************************************
Function TableHeader()
	Response.Write TableTitle("例会列表", 600, "", "#0040a0")
	TableHeader = _
		"<table cellspacing=0 cellpadding=0 width=600 align=center class=tablelist style=""table-layout:fixed"">" & _
		"<tr>" & _
		"<td class=tdHead width=250>&nbsp;<img src=""../images/bg/ar-y.gif"" width=8 height=8>&nbsp;" & TableHeaderField(sFileName, "meeting_name", "例会名称", sFormParams, iSort, iSorted) & "</td>" & _
		"<td class=tdHead width=100>&nbsp;" & TableHeaderField(sFileName, "meeting_day", "召开日", sFormParams, iSort, iSorted) & "</td>" & _
		"<td class=tdHead width=100>&nbsp;" & TableHeaderField(sFileName, "meeting_time", "召开时间", sFormParams, iSort, iSorted) & "</td>" & _
		"<td class=tdHead width=150>&nbsp;" & TableHeaderField(sFileName, "meeting_room", "召开地点", sFormParams, iSort, iSorted) & "</td>" & _
		"</tr>"
End Function

'************************************************************************************************
' 函数名　: TableRecords(sSQL, iCols, iRecordsPerPage, iTotalRecords, iCurrentPage, iTotalPages,
'          sFileName, sFormParams, sSortParams)
' 输　入　: 查询语句，栏目数量，每页记录条数，总记录条数，当前页码，总页数，文件名，查询表单参数，排序参数
' 输　出　: 显示待审批的会议列表
' 功能描述: 根据输入参数，显示相应的结果
' 调用模块: list_routinemeeting.asp
' 作　者　: 蔡晓燕
' 日　期　: 2002-07-11
' 版　本　: 
'************************************************************************************************
Function TableRecords(sSQL, iCols, iRecordsPerPage, iTotalRecords, iCurrentPage, iTotalPages, sFileName, sFormParams, sSortParams)
	dim sTemp	: sTemp = ""	' 临时字符串变量
	dim j					' 临时循环变量

	'------------------------------------
	' 分页所需的变量定义
	'------------------------------------
	Dim iCounter		: iCounter = 1
	Dim iPrevPage, iNextPage
	
	'------------------------------------
	' 获取数据库连接
	'------------------------------------
	dim crs	: set crs = New CRecordset
	dim rs	: set rs = crs.open(dbLocal,sSQL)
	dim sMeetingname, sMeeting_day, sMeeting_time, sMeeting_room, iSerial
	
	' 如果未到记录尾，将记录定位到你翻到的页面的第一个记录，否则显示空行
	if Not rs.EOF then	
		rs.Move (iCurrentPage - 1) * iRecordsPerPage
	end if
	while not rs.EOF and iCounter <= iRecordsPerPage
		sMeetingname				= crs.GetValue("meeting_name")
		sMeeting_day			= crs.GetValue("meeting_day")
		sMeeting_time		= crs.GetValue("meeting_time")
		sMeeting_room			= crs.GetValue("meeting_room")
		iSerial				= crs.GetValue("meeting_serial")
		sTemp = sTemp & "<tr>" & _
				"<td class=tdlist nowrap  title=""" & Tohtml(sMeetingname) & """ style=""cursor:hand""><a href=""newroutinemeeting.asp?meetingserial=" &_
				iSerial & """><img border=0 src=""../images/bg/ar-g.gif"" width=8 height=8> &nbsp;" & sMeetingname & "&nbsp;</td>" & _
				"<td class=tdlist nowrap align=left>&nbsp;" & TransMeetingday(sMeeting_day) & "&nbsp;</td>" & _
				"<td class=tdlist align=left>&nbsp;" & ToHTML(sMeeting_time) & "&nbsp;</td>" & _
				"<td class=tdlist align=left>&nbsp;" & ToHtml(sMeeting_room) & "&nbsp;</td>" & _
				"</tr>"
		iCounter = iCounter + 1
		rs.movenext
	wend
	crs.Close()

	' 填补空白行
	sTemp = sTemp & WhiteRows(iCols, iCounter, iRecordsPerPage)

	' 首页、前页、后页、尾页等分页信息
	sTemp = sTemp & "<tr><td class=tdlist colspan=" & iCols & " align=right>" & _
				Paginate(sFileName, sFormParams, sSortParams, iCurrentPage, iTotalPages) & _
				"&nbsp;</td></tr>"
	TableRecords = sTemp&"</table>"
End Function


'************************************************************************************************
' 函数名　: TableLink()
' 输　入　: 
' 输　出　: 
' 功能描述: 	会议申请表页面上到其他页面的连接
' 调用模块: applymeeting.asp
' 作　者　: 蔡晓燕
' 日　期　: 2002-07-11
' 版　本　: 
'************************************************************************************************
Function TableLink()
	TableLink = _
		"<table width=600 cellspacing=0 cellpadding=0 border=0 align=center>" & _
		"<tr height=30>" & _ 
		"	<td width=600><img src=""../images/bg/line.gif"" width=600 height=3></td>" & _
		"</tr>" & _
		"<tr height=30>" & _
		"	<td width=600>&nbsp;" & _
		"		<img src=""../images/goto.gif"" width=11 height=11>&nbsp;<a href=""newroutinemeeting.asp"">新增例会</a>" & _
		"		&nbsp;&nbsp;&nbsp;" & _
		"		<img src=""../images/goto.gif"" width=11 height=11>&nbsp;<a href=""list_checkmeeting.asp"">审批会议申请</a>" & _
		"		&nbsp;&nbsp;&nbsp;" & _
		"		<img src=""../images/goto.gif"" width=11 height=11>&nbsp;<a href=""list_routinemeeting.asp"">修改会议申请表</a></td>" & _
		"</tr>" & _
		"</table>"
End Function
%>