list_meetingeffect.inc

物业管理和办公自动化系统

<%
'************************************************************************************************
' 函数名　: TableHeader()
' 输　入　: 
' 输　出　: 一个用于显示待落实的会议落实事项列表的表头
' 功能描述: 
' 调用模块: list_meetingeffect.asp
' 作　者　: 蔡晓燕
' 日　期　: 2002-07-22
' 版　本　: 
'************************************************************************************************
Function TableHeader()
	Response.Write TableTitle("等候落实的会议落实事项列表", 600, "", "#0040a0")
	TableHeader = _
		"<table cellspacing=0 cellpadding=0 width=600 align=center class=tablelist style=""table-layout:fixed"">" & _
		"<tr>" & _
		"<td class=tdHead width=210>&nbsp;<img src=""../images/bg/ar-y.gif"" width=8 height=8>&nbsp;" & TableHeaderField(sFileName, "meeting_name", "会议名称", sFormParams, iSort, iSorted) & "</td>" & _
		"<td class=tdHead width=210>&nbsp;" & TableHeaderField(sFileName, "subject", "会议主题", sFormParams, iSort, iSorted) & "</td>" & _
		"<td class=tdHead width=70>&nbsp;" & TableHeaderField(sFileName, "proposer", "申请人", sFormParams, iSort, iSorted) & "</td>" & _
		"<td class=tdHead width=*>&nbsp;" & TableHeaderField(sFileName, "apply_time", "申请时间", sFormParams, iSort, iSorted) & "</td>" & _
		"</tr>"
End Function

'************************************************************************************************
' 函数名　: TableRecords(sSQL, iCols, iRecordsPerPage, iTotalRecords, iCurrentPage, iTotalPages,
'          sFileName, sFormParams, sSortParams)
' 输　入　: 查询语句，栏目数量，每页记录条数，总记录条数，当前页码，总页数，文件名，查询表单参数，排序参数
' 输　出　: 显示待审批的会议列表
' 功能描述: 根据输入参数，显示相应的结果
' 调用模块: list_meetingeffect.asp
' 作　者　: 蔡晓燕
' 日　期　: 2002-07-11
' 版　本　: 
'************************************************************************************************
Function TableRecords(sSQL, iCols, iRecordsPerPage, iTotalRecords, iCurrentPage, iTotalPages, sFileName, sFormParams, sSortParams)
	dim sTemp	: sTemp = ""	' 临时字符串变量
	dim j					' 临时循环变量

	'------------------------------------
	' 分页所需的变量定义
	'------------------------------------
	Dim iCounter		: iCounter = 1
	Dim iPrevPage, iNextPage
	
	'------------------------------------
	' 获取数据库连接
	'------------------------------------
	dim crs	: set crs = New CRecordset
	dim rs	: set rs = crs.open(dbLocal,sSQL)
	dim sMeetingname, sSubject, sProposer, sApply_time, iSerial
	
	' 如果未到记录尾，将记录定位到你翻到的页面的第一个记录，否则显示空行
	if Not rs.EOF then	
		rs.Move (iCurrentPage - 1) * iRecordsPerPage
	end if
	while not rs.EOF and iCounter <= iRecordsPerPage
		sMeetingname				= crs.GetValue("meeting_name")
		sSubject			= crs.GetValue("subject")
		sProposer		= crs.GetValue("proposer")
		sApply_time			= crs.GetValue("apply_time")
		iSerial				= crs.GetValue("meeting_serial")
		sTemp = sTemp & "<tr>" & _
				"<td class=tdlist nowrap  title=""" & Tohtml(sMeetingname) & """ style=""cursor:hand""><a href=""meetingeffect.asp?meetingserial=" & iserial & """><img border=0 src=""../images/bg/ar-g.gif"" width=8 height=8> &nbsp;" & ToHtml(sMeetingname) & "&nbsp;</td>" & _
				"<td class=tdlist nowrap title="""& Tohtml(sSubject) & """ align=left >&nbsp;" & ToHTML(sSubject) & "&nbsp;</td>" & _
				"<td class=tdlist nowrap title= """&TransEmpSerial(dbLocal,sProposer) &""" align=left>&nbsp;" & TransEmpSerial(dbLocal,sProposer) & "&nbsp;</td>" & _
				"<td class=tdlist align=left  >" & Formatdt(sApply_time,"yyyy-mm-dd hh:mm") & "</a>&nbsp;</td>" & _
				"</tr>"
		iCounter = iCounter + 1
		rs.movenext
	wend
	crs.Close()

	' 填补空白行
	sTemp = sTemp & WhiteRows(iCols, iCounter, iRecordsPerPage)

	' 首页、前页、后页、尾页等分页信息
	sTemp = sTemp & "<tr><td class=tdlist colspan=" & iCols & " align=right>" & _
				Paginate(sFileName, sFormParams, sSortParams, iCurrentPage, iTotalPages) & _
				"&nbsp;</td></tr>"
	TableRecords = sTemp&"</table>"
End Function


'************************************************************************************************
' 函数名　: TableLink()
' 输　入　: 
' 输　出　: 
' 功能描述: 	会议申请表页面上到其他页面的连接
' 调用模块: applymeeting.asp
' 作　者　: 蔡晓燕
' 日　期　: 2002-07-11
' 版　本　: 
'************************************************************************************************
Function TableLink()
	TableLink = _
		"<table width=600 cellspacing=0 cellpadding=0 border=0 align=center>" & _
		"<tr height=30>" & _ 
		"	<td width=600><img src=""../images/bg/line.gif"" width=600 height=3></td>" & _
		"</tr>" & _
		"<tr height=30>" & _
		"	<td width=600>&nbsp;" & _
		"		<img src=""../images/goto.gif"" width=11 height=11>&nbsp;<a href=""applymeeting.asp"">填写会议申请</a>" & _
		"		&nbsp;&nbsp;&nbsp;" & _
		"		<img src=""../images/goto.gif"" width=11 height=11>&nbsp;<a href=""list_meetingeffect.asp"">审批会议申请</a>" & _
		"		&nbsp;&nbsp;&nbsp;" & _
		"		<img src=""../images/goto.gif"" width=11 height=11>&nbsp;<a href=""list_querymeeting.asp"">会议处理</a>" & _
		"		&nbsp;&nbsp;&nbsp;" & _
		"		<img src=""../images/goto.gif"" width=11 height=11>&nbsp;<a href=""list_weekmeeting.asp"">一周会议申请</a>" & _
		"		&nbsp;&nbsp;&nbsp;" & _
		"		<img src=""../images/goto.gif"" width=11 height=11>&nbsp;<a href=""list_endmeeting.asp"">填写会议纪要</a>" & _
		"		&nbsp;&nbsp;&nbsp;" & _
		"		<img src=""../images/goto.gif"" width=11 height=11>&nbsp;<a href=""list_reapplymeeting.asp"">修改会议申请表</a></td>" & _
		"</tr>" & _
		"</table>"
End Function
%>