meetingeffect.inc

物业管理和办公自动化系统

<%
' ==================================================================
' 函数名称：GetInvisibleChar(strData)
' 函数功能：显示原字符串，包括其中的不可见字符：空格和回车
' 输入参数：字符串：strData
' 返回值：  字符串：GetInvisibleChar
' ==================================================================
function GetInvisibleChar(strData)
	Dim strGetSpace
	Dim strGetAll
	if  Isnull(strData) then
		response.write "strData为null!"
		response.end
	else
		strGetSpace = unescape(Replace(escape(strData),"%20","&nbsp;"))
		strGetAll = unescape(Replace(escape(strGetSpace),"%0D%0A","<br>"))
	end if
	GetInvisibleChar = strGetAll
end function


'************************************************************************************************
' 函数名　: FormMeetingEffect(iMeetingSerial)
' 输　入　: iMeetingSerial:会议序列号
' 输　出　: 一次会议的详细信息表
' 功能描述: 根据会议序列号，给出相应的会议详细信息
' 调用模块: meetingeffect.inc
' 作　者　: 蔡晓燕
' 日　期　: 2002-07-22
' 版　本　: 
'************************************************************************************************
Function FormMeetingEffect(iMeetingSerial)
	'------------------------------------
	' 根据会议的MeetingSerial,显示相应的会议落实事项
	'------------------------------------
	dim sSQL, iExecuter, sMeetingName, sSubject, sMeetingeffect, iHandler, sHandle_deadline, sAssociate
	dim dStop_time, fBudget, sAttendee, sGuest, iProposer, rt, rm, sError
	dim sTemp, sTempButtons
	dim crs, rs
	sSQL = "select * from T_MeetingPrepare where meeting_status = 9 and meeting_serial = "& iMeetingSerial
	set crs = New CRecordset
	set rs = crs.open(dbLocal,sSQL)
	if not rs.eof then 
		sMeetingName = crs.GetValue("meeting_name")
		sSubject = crs.GetValue("subject")
	else
		response.write "<script language=""javascript"">alert('对不起，不存在该会议或者该会议落实事项已经处理过了！')</script>"
		response.write "<script language = vbscript>window.navigate(""list_meetingeffect.asp"")</script>"
	end if
	crs.close()
	sSQL = "select * from T_MeetingEffect where meeting_serial = "& iMeetingSerial
	set crs = New CRecordset
	set rs = crs.open(dbLocal,sSQL)
	if not rs.eof then 
		sMeetingeffect = crs.GetValue("effect_item")
		iHandler = crs.GetValue("handler")
		sHandle_deadline = crs.GetValue("handle_deadline")
		sAssociate = crs.GetValue("associate")
	else
		response.write "<script language=""javascript"">alert('对不起，不存在该会议或者该会议落实事项已经处理过了！')</script>"
		response.write "<script language = vbscript>window.navigate(""list_meetingeffect.asp"")</script>"
	end if
	crs.close()
	sTempButtons=_
		"		<img border=0 src=""../images/button/submit.gif"" style=""cursor:hand"" name=btnSubmit>" & _
		"		<img border=0 src=""../images/button/clear.gif"" style=""cursor:hand"" name=btnCancel>" & _
		"		<img border=0 src=""../images/button/return.gif"" style=""cursor:hand"" name=btnReturn>" 	
	FormMeetingEffect=_
		"<table cellspacing=0 cellpadding=0 width=600 align=center border=1>" & _
		"<tr><td>"&_
		TableTitle("会议落实事项", 600, "", "#0040a0") & _
		"<table cellspacing=0 cellpadding=0 width=600 align=center border=0>" & _
		"<form name=""frmEffect"" method=post action=""meetingeffect.asp"">"  & _
		"<tr height=30>" & _
		"	<td class=tdlist width=115 align=right>会议名称：</td>" & _
		"	<td class=tdlist width=485 colspan=3> &nbsp;"  & sMeetingName & "</td>"&_
		"</tr>" & _
		"<tr height=30>" & _
		"	<td class=tdlist width=115 align=right>会议主题：</td>"&_
		"	<td class=tdlist width=485 colspan=3> &nbsp;"  & sSubject & "</td>" & _
		"</tr>" & _
		"<tr height=30>" & _
		"	<td class=tdlist width=115 align=right>落实事项：</td>" & _
		"	<td class=tdlist width=485 colspan=3> &nbsp;" & GetInvisibleChar(sMeetingeffect) & "</td>"&_
		"</tr>" & _
		"<tr height=30>" & _
		"	<td class=tdlist width=115 align=right>督办人员：</td>" & _
		"	<td class=tdlist width=485 colspan = 3> &nbsp;" &  TransEmpSerial(dbLocal,iHandler) & "</td>"& _
		"</tr>" & _
		"<tr height=30>" & _
		"	<td class=tdlist width=115 align=right>处理时限：</td>" & _
		"	<td class=tdlist width=485 colspan = 3> &nbsp;" & sHandle_deadline &"</td>"& _
		"</tr>" & _
		"<tr height=30>" & _
		"	<td class=tdlist width=115 align=right>相关人员：</td>" & _
		"	<td class=tdlist width=485 colspan=3> &nbsp;"  & TransEmpSerial(dbLocal,sAssociate) & "</td>"& _
		"   <input type=hidden name=meetingserial value="""&iMeetingSerial&""">" & _
		"</tr>" 
	if GetEmpSerial = iHandler then
		FormMeetingEffect = FormMeetingEffect & _
		"<tr height=50>" & _
		"	<td colspan=4 align=center style=""color:red"">请督办人员填写执行结果： "& _
		"	</td>" & _
		"<tr height=30>" & _
		"	<td width=115 align=right>执行结果：</td>" & _
		"	<td width=485 colspan=3><textarea class=""FlatCtrl"" name=""handle_result"" rows=10 cols=62></textarea></td>"&_
		"</tr>" & _
		"	<td width=115 align=right>备注：</td>"&_
		"	<td width=485 colspan=3><input name=""remark""  size=64  type=""text"" maxlength=512></td>"& _
		"</tr>" & _
		"<tr height=30>" & _
		"	<td width=115 align=right>处理日期：</td>" & _
		"	<td width=485 colspan=3><input name=""handled_date"" size=64  type=""text"" maxlength=20></td>"&_
		"</tr>" & _
		"<tr height=50>" & _
		"	<td colspan=4 align=center>" & sTempButtons & _
		"	</td>" & _
		"</tr>"
	else
		sTempButtons = 	"	<img border=0 src=""../images/button/return.gif"" style=""cursor:hand"" name=btnReturn>" 
		FormMeetingEffect = FormMeetingEffect & _
		"<tr height=50>" & _
		"	<td colspan=4 align=center>" & sTempButtons & _
		"	</td>" & _
		"</tr>"
	end if
	FormMeetingEffect = FormMeetingEffect & _
		"</form>" & _
		"</table></td></tr>"&_
		"</table>" 
End Function

'************************************************************************************************
' 函数名　: TableLink()
' 输　入　: 
' 输　出　: 
' 功能描述: 	会议申请表页面上到其他页面的连接
' 调用模块: applymeeting.asp
' 作　者　: 蔡晓燕
' 日　期　: 2002-07-11
' 版　本　: 
'************************************************************************************************
Function TableLink()
	TableLink = _
		"<table width=600 cellspacing=0 cellpadding=0 border=0 align=center>" & _
		"<tr height=30>" & _ 
		"	<td width=600><img src=""../images/bg/line.gif"" width=600 height=3></td>" & _
		"</tr>" & _
		"<tr height=30>" & _
		"	<td width=600>&nbsp;" & _
		"		<img src=""../images/goto.gif"" width=11 height=11>&nbsp;<a href=""applymeeting.asp"">填写会议申请</a>" & _
		"		&nbsp;&nbsp;&nbsp;" & _
		"		<img src=""../images/goto.gif"" width=11 height=11>&nbsp;<a href=""list_meetingeffect.asp"">审批会议申请</a>" & _
		"		&nbsp;&nbsp;&nbsp;" & _
		"		<img src=""../images/goto.gif"" width=11 height=11>&nbsp;<a href=""list_reapplymeeting.asp"">修改会议申请表</a></td>" & _
		"</tr>" & _
		"</table>"
End Function

'************************************************************************************************
' 函数名　: UpdateMeeting()
' 输　入　: 
' 输　出　: 
' 功能描述: 	新增或者更新会议的数据处理，根据meetingserial的值，采取不同的操作:
'			iMeetingserial=0：新的会议申请
'			iMeetingserial<>0 :重新会议申请
' 调用模块: applymeeting.asp
' 作　者　: 蔡晓燕
' 日　期　: 2002-07-11
' 版　本　: 
'************************************************************************************************
Sub UpdateMeeting()
'	定义变量
	dim sSQL, sSQL1, iMeetingserial, sError
	dim crs, rs
	dim sMeetingname, sPrior, iHandler, sAssociate, sMeetingeffect, sHandle_result, sHandled_date, sRemark

'   获取表单的数据 
	iMeetingserial = GetParam("meetingserial")
	sHandle_result = GetParam("handle_result")
	sHandled_date = GetParam("handled_date")
	sRemark = GetParam("remark")

'	获取相关会议以及落实事项的参数
	sSQL = "SELECT * FROM T_MeetingPrepare where meeting_serial = "& iMeetingserial 
	set crs = New CRecordset
	set rs = crs.open(dbLocal,sSQL)
	sMeetingname = crs.GetValue("meeting_name")
	sPrior = crs.GetValue("priorgroup")
	crs.close()

	sSQL = "SELECT * FROM T_MeetingEffect where meeting_serial = "& iMeetingserial 
	set crs = New CRecordset
	set rs = crs.open(dbLocal,sSQL)
	sAssociate = crs.GetValue("associate")
	iHandler = crs.GetValue("handler")
	sMeetingeffect = crs.GetValue("effect_item")
'	response.write sMeetingeffect
'	response.end
	if not rs.eof then
	'存在该会议落实事项，作处理
		'1.先填写落实事项的执行结果
		sSQL = "update t_meetingeffect set handle_result = "& ToSQL(sHandle_result,"text") &", remark = " & ToSQL(sRemark,"text") & _
		", handled_date = "& ToSQL(sHandled_date,"text") & " where meeting_serial = "&iMeetingserial
		sError = ExecuteSQL(dbLocal, sSQL)
		if sError <> "" then
			Response.Write "<script language=""javascript"">alert('对不起，会议落实事项信息修改出错，请查看数据库！')</script>"
		end if
		'2.再修改会议的状态
		sSQL = "update t_meetingprepare set meeting_status = 10 where meeting_serial = "&iMeetingserial
		sError = ExecuteSQL(dbLocal, sSQL)
		if sError <> "" then
			Response.Write "<script language=""javascript"">alert('对不起，会议信息修改出错，请查看数据库！')</script>"
		end if
		'3.发送消息，通知相关人员查看
'		sMeetingname ="会议:<"&sMeetingname&">的落实事项已经处理完毕，请查看！"
		call CommonSendMsg(MSG_MEETING,"",sMeetingname,"会议落实事项处理完毕，请您到历史会议中查看处理结果！", iHandler, sAssociate)
	else
	'不存在该会议，给出出错信息
		response.write "<script language=""javascript"">alert('对不起，不存在该会议或者该会议落实事项已经处理过了！')</script>"
		response.write "<script language = vbscript>window.navigate(""list_meetingeffect.asp"")</script>"
	end if
	response.write "<script language=vbscript>window.navigate(""list_meetingeffect.asp"")</script>"
End Sub

%>