📄 newroutinemeeting.asp

📁 物业管理和办公自动化系统
💻 ASP
字号:
<%
'************************************************************************************************
' 文件名: newroutinemeeting.asp
' Copyright(c) 2001-2002 上海阿尔卡特网络支援系统有限公司
'
' 　创建人 : 蔡晓燕
' 　日　期 : 2002-07-24
' 修改历史 :
'   ****年**月**日 ****** 修改内容:**************************************************
' 功能描述 :用户通过本页面添加新的例会，供申请召开例会的时候选择，同时也可以通过本也面对例会进行维护
' 　版　本 :V1.0
'************************************************************************************************
option explicit
Response.CacheControl = "no-cache"
Response.AddHeader "Pragma", "no-cache"
Response.Expires = -1
%>

<!-- #include file="../include/config.inc" -->
<!-- #include file="../include/common.inc" -->
<!-- #include file="../include/debug.inc" -->
<!-- #include file="../include/db.inc" -->
<!-- #include file="../include/date.inc" -->
<!-- #include file="../include/datahandle.inc" -->
<!-- #include file="../include/recordlist.inc" -->
<!-- #include file="../include/security.inc" -->
<!-- #include file="../common/commonpage.inc" -->
<!-- #include file="../include/emp.inc" -->
<!-- #include file="newroutinemeeting.inc" -->
<!-- #include file="tablelink.inc" -->

<%
call CheckSecurity()
'*********************************************************************************************************
'获取参数：例会的序列号。如果该参数为空，置为0，表示新增例会
'********************************************************************************************************
dim iMeetingSerial	:	iMeetingSerial = GetParam("meetingserial")
if IsEmpty(iMeetingSerial) then iMeetingSerial = 0

'********************************************************************************************************
' 如果是提交，则调用函数UpdateMeeting()更新数据库
if UCase(Request.ServerVariables("REQUEST_METHOD") = "POST") then
	UpdateMeeting()
end if

%>

<html>
<head>
<title>会议管理——例会管理</title>
<meta http-equiv="Content-Type" content="text/html; charset=gb2312">
<link rel="stylesheet" href="../common/common.css" type="text/css">

<script language="javascript" src="../include/common.js"></script>
<script language="vbscript" src="../task/taskremind.vbs"></script>
<script language="VBScript" src="../common/validate.vbs"></script>
<script language="VBScript">
	sub btnSubmit_Onclick()
	'   输入合法性检查  
		if trim(frmnewroutinemeeting.mtName.value) = "" then
			msgbox"请输入例会名称！"
			frmnewroutinemeeting.mtName.focus()
			exit sub
		end if
		if trim(frmnewroutinemeeting.mtTask.value) = "" then
			msgbox"请输入会议内容！"
			frmnewroutinemeeting.mtTask.focus()
			exit sub
		end if
		if LEN(frmnewroutinemeeting.mtTask.value) > 3500 then
			msgbox"会议任务太多，请减少字数（最多3500个中文字符）！"
			frmnewroutinemeeting.mtTask.focus()
			exit sub
		end if
		if trim(frmnewroutinemeeting.department.value) = "" then
			msgbox"请输入召开部门！"
			frmnewroutinemeeting.department.focus()
			exit sub
		end if
		if trim(frmnewroutinemeeting.meeting_room.value) = "" then
			msgbox"请输入召开地点！"
			frmnewroutinemeeting.meeting_room.focus()
			exit sub
		end if
		if trim(frmnewroutinemeeting.presider.value) = "" then
			msgbox"请输入会议主持人！"
			frmnewroutinemeeting.presider.focus()
			exit sub
		end if
		if trim(frmnewroutinemeeting.start_time.value) = "" then
			msgbox"请输入召开时间！"
			frmnewroutinemeeting.start_time.focus()
			exit sub
		end if
		if trim(frmnewroutinemeeting.remindbeforedays.value) = "" then
			msgbox"请选择提醒方式！"
			frmnewroutinemeeting.remindbeforedays.focus()
			exit sub
		end if
		Dim v_length,i	'v_length,i为临时变量
		v_length = frmnewroutinemeeting.attendee.length
		if v_length = 0 then
			msgbox"请输入参会人员！"
			frmnewroutinemeeting.attendee.focus()
			exit sub
		else
			for i = 0 to v_length - 1 
			   frmnewroutinemeeting.attendee.options(i).selected = true
			next
		end if
		'rm表示RemindMethod,rt表示RemindTime
		dim x'临时变量
		x = (frmnewroutinemeeting.meeting_day.value + 7 - frmnewroutinemeeting.remindbeforedays.value )mod(7)
		if x = 0 then x = 7
		frmnewroutinemeeting.rm.value = "080"&x&"0000"
		frmnewroutinemeeting.rt.value = FirstRemindTime(frmnewroutinemeeting.rm.value, date())
		frmnewroutinemeeting.formaction.value = "add"
		frmnewroutinemeeting.submit()
	end sub

	sub btnDelete_Onclick()
	'   删除例会
		if  DeleteConfirm("该例会") then
			frmnewroutinemeeting.formaction.value = "del"
			frmnewroutinemeeting.submit()
		end if
	end sub

	sub btnCancel_Onclick()
	'   重新输入 
		frmnewroutinemeeting.reset()
	end sub

	sub btnReset_Onclick()
	'   重新输入 
		frmnewroutinemeeting.reset()
	end sub
</script>
</head>

<body bgcolor="#FFFFFF" leftmargin="0" topmargin="0" marginwidth="0" marginheight="0" background="../images/bg/bg0.jpg">
<br>

<%
Response.Write OuterTableHeader
Response.Write HeaderWithMenu
Response.Write InnerTableHeader
'********************************************************************************************************
' 主体从这里开始
'-------------------------------------------------------------------------------------------------------------------------------------
'Response.write "iMeetingserial="&iMeetingSerial
'response.end
Response.write FormMeetingTable(iMeetingSerial)
Response.write TableLink2()
'-------------------------------------------------------------------------------------------------------------------------------------
' 主体到这里结束
'********************************************************************************************************
Response.Write InnerTableTailer
Response.Write Footer
Response.Write OuterTableTailer
%>

</body>
</html>
⌨️ 快捷键说明

复制代码 Ctrl + C
搜索代码 Ctrl + F
全屏模式 F11
切换主题 Ctrl + Shift + D
显示快捷键 ?
增大字号 Ctrl + =
减小字号 Ctrl + -