📄 routinemeeting.asp
字号:
<%
'************************************************************************************************
' 文件名: routinemeeting.asp
' Copyright(c) 2001-2002 上海阿尔卡特网络支援系统有限公司
'
' 创建人 : 蔡晓燕
' 日 期 : 2002-07-25
' 修改历史 :
' ****年**月**日 ****** 修改内容:**************************************************
' 功能描述 :用户通过本页面申请召开例会，成功以后直接发送消息给各参会人员
' 版 本 :V1.0
'************************************************************************************************
option explicit
Response.CacheControl = "no-cache"
Response.AddHeader "Pragma", "no-cache"
Response.Expires = -1
%>
<!-- #include file="../include/config.inc" -->
<!-- #include file="../include/common.inc" -->
<!-- #include file="../include/debug.inc" -->
<!-- #include file="../include/db.inc" -->
<!-- #include file="../include/date.inc" -->
<!-- #include file="../include/datahandle.inc" -->
<!-- #include file="../include/recordlist.inc" -->
<!-- #include file="../include/security.inc" -->
<!-- #include file="../common/commonpage.inc" -->
<!-- #include file="../include/emp.inc" -->
<!-- #include file="routinemeeting.inc" -->
<!-- #include file="tablelink.inc" -->
<!-- #include file="../include/message.inc" -->
<%
call CheckSecurity()
'*********************************************************************************************************
'如果该当前没有设置好的例会模板，则不能召开例会
'********************************************************************************************************
dim sSQL, rs, crs
sSQL = "select * from t_routinemeeting"
set crs = New CRecordset
set rs = crs.open(dbLocal,sSQL)
if rs.eof then
response.write "<script language=""javascript"">alert('对不起，目前还没有例会供召开，请先增加例会1！')</script>"
response.write "<script language = vbscript>window.navigate(""newroutinemeeting.asp"")</script>"
response.end
end if
dim iMeetingSerial
iMeetingSerial = GetParam("meetingserial")
if IsEmpty(iMeetingSerial) then iMeetingSerial = crs.GetValue("meeting_serial")
'response.write "first = "&iMeetingSerial
'response.end
'********************************************************************************************************
' 如果是提交，则调用函数UpdateMeeting()更新数据库
if UCase(Request.ServerVariables("REQUEST_METHOD") = "POST") then
UpdateMeeting()
end if
%>
<html>
<head>
<title>会议管理——召开例会</title>
<meta http-equiv="Content-Type" content="text/html; charset=gb2312">
<link rel="stylesheet" href="../common/common.css" type="text/css">
<!-- 日历 -->
<IFRAME style="display:none;position:absolute;width:148;height:194;z-index=100" ID="CalFrame" MarginHeight=0 MarginWidth=0 noresize frameborder=0 scrolling=no src="../common/cal/calendar.htm"></IFRAME>
<script language="javascript" src="../common/cal/calendar.js"></script>
<script for=document event="onclick()">
<!--
document.all.CalFrame.style.display="none";
//-->
</script>
<!-- 日历 -->
<script language="javascript" src="../include/common.js"></script>
<script language="VBScript">
sub mtName_OnChange()
dim temp
temp = frmroutinemeeting.mtName.value
window.navigate("routinemeeting.asp?meetingserial="&temp)
end sub
sub btnSubmit_Onclick()
' 输入合法性检查
if trim(frmroutinemeeting.mtSubject.value) = "" then
msgbox"请输入会议主题！"
frmroutinemeeting.mtSubject.focus()
exit sub
end if
if trim(frmroutinemeeting.mtName.value) = "" then
msgbox"请输入会议名称！"
frmroutinemeeting.mtName.focus()
exit sub
end if
if trim(frmroutinemeeting.mtTask.value) = "" then
msgbox"请输入会议内容！"
frmroutinemeeting.mtTask.focus()
exit sub
end if
if LEN(frmroutinemeeting.mtTask.value) > 3500 then
msgbox"会议任务太多，请减少字数（最多3500个中文字符）！"
frmroutinemeeting.mtTask.focus()
exit sub
end if
if trim(frmroutinemeeting.department.value) = "" then
msgbox"请输入召开部门！"
frmroutinemeeting.department.focus()
exit sub
end if
if trim(frmroutinemeeting.meeting_room.value) = "" then
msgbox"请输入召开地点！"
frmroutinemeeting.meeting_room.focus()
exit sub
end if
if trim(frmroutinemeeting.presider.value) = "" then
msgbox"请输入会议主持人！"
frmroutinemeeting.presider.focus()
exit sub
end if
if trim(frmroutinemeeting.budget.value) = "" then
msgbox"请输入费用预算！"
frmroutinemeeting.budget.focus()
exit sub
end if
if not IsNumeric(frmroutinemeeting.budget.value) then
msgbox"费用预算必须是数字！"
frmroutinemeeting.budget.focus()
exit sub
end if
if trim(frmroutinemeeting.start_time.value) = "" then
msgbox"请输入开始时间！"
frmroutinemeeting.start_time.focus()
exit sub
end if
if not Isdate(frmroutinemeeting.start_time.value) then
msgbox"请输入正确的时间格式（yyyy-mm-dd hh:mm:ss）！"
frmroutinemeeting.start_time.focus()
exit sub
end if
if trim(frmroutinemeeting.stop_time.value) = "" then
msgbox"请输入结束时间！"
frmroutinemeeting.stop_time.focus()
exit sub
end if
if not Isdate(frmroutinemeeting.stop_time.value) then
msgbox"请输入正确的时间格式（yyyy-mm-dd hh:mm:ss）！"
frmroutinemeeting.stop_time.focus()
exit sub
end if
Dim v_length,i 'v_length,i为临时变量
v_length = frmroutinemeeting.attendee.length
if v_length = 0 then
msgbox"请输入参会人员！"
frmroutinemeeting.attendee.focus()
exit sub
else
for i = 0 to v_length - 1
frmroutinemeeting.attendee.options(i).selected = true
next
end if
frmroutinemeeting.formaction.value = "apply"
frmroutinemeeting.submit()
end sub
sub btnCancel_Onclick()
' 重新输入
frmroutinemeeting.reset()
end sub
</script>
</head>
<body bgcolor="#FFFFFF" leftmargin="0" topmargin="0" marginwidth="0" marginheight="0" background="../images/bg/bg0.jpg">
<br>
<%
Response.Write OuterTableHeader
Response.Write HeaderWithMenu
Response.Write InnerTableHeader
'********************************************************************************************************
' 主体从这里开始
'-------------------------------------------------------------------------------------------------------------------------------------------------
Response.write FormMeetingTable(iMeetingSerial)
Response.write TableLink2()
'-------------------------------------------------------------------------------------------------------------------------------------------------
' 主体到这里结束
'********************************************************************************************************
Response.Write InnerTableTailer
Response.Write Footer
Response.Write OuterTableTailer
%>
</body>
</html>
⌨️ 快捷键说明
复制代码
Ctrl + C
搜索代码
Ctrl + F
全屏模式
F11
切换主题
Ctrl + Shift + D
显示快捷键
?
增大字号
Ctrl + =
减小字号
Ctrl + -