applymeeting.inc

物业管理和办公自动化系统

<%
'************************************************************************************************
' 函数名　: FormMeetingTable(iMeetingSerial)
' 输　入　: iMeetingSerial:会议序列号，如果是新申请会议，那么iMeetingSerial=0，表示一张空的表
' 输　出　: 一张会议申请表（新的或者是旧的供修改的），可以提交
' 功能描述: 根据会议序列号，画出相应的会议申请表显示出来
' 调用模块: applymeeting.inc
' 作　者　: 蔡晓燕
' 日　期　: 2002-07-11
' 版　本　: 
'************************************************************************************************
Function FormMeetingTable(iMeetingSerial)
	'------------------------------------
	' 根据会议的MeetingSerial,画出相应的会议申请表，显示原来的会议信息，供修改
	'------------------------------------
	dim sSQL, iExecuter, sMeetingName, sSubject, sTask, iDepartment, sMeetingRoom, sPresider, dStart_time, dApply_time
	dim dStop_time, fBudget, sAttendee, sGuest, iProposer, rt, rm, sError, sComment
	dim sTemp, sTempButtons
	dim crs, rs
	sSQL = "select * from T_MeetingPrepare where meeting_serial = "& iMeetingSerial
	set crs = New CRecordset
	set rs = crs.open(dbLocal,sSQL)
	if not rs.eof then 
		sMeetingName = crs.GetValue("meeting_name")
		sSubject = crs.GetValue("subject")
		sTask = crs.GetValue("task")
		sMeetingRoom = crs.GetValue("meeting_room")
		sPresider = crs.GetValue("presider")
		fBudget = crs.GetValue("budget")
		dStart_time = crs.GetValue("start_time")
		dStop_time = crs.GetValue("stop_time")
		dStart_time = Formatdt(dStart_time,"yyyy-mm-dd hh:mm")
		dStop_time = Formatdt(dStop_time,"yyyy-mm-dd hh:mm")
		sGuest = crs.GetValue("guest")
		iDepartment = crs.GetValue("department")
		sAttendee = crs.GetValue("attendee")
		sComment = crs.GetValue("comment")
		sTempButtons=_
		"		<img border=0 src=""../images/button/submit.gif"" style=""cursor:hand"" name=btnSubmit>" & _
		"		<img border=0 src=""../images/button/delete.gif"" style=""cursor:hand"" name=btnDelete>" & _
		"		<img border=0 src=""../images/button/reset.gif"" style=""cursor:hand"" name=btnReset>" 
	else
		sMeetingName = ""
		sSubject = ""
		sTask = ""
		sMeetingRoom = ""
		sPresider = ""
		fBudget = 0
		dStart_time = left(now(),len(now())-3)
		dStop_time = left(now(),len(now())-3)
		sGuest = ""
		iDepartment = 0
		sAttendee = ""
		sTempButtons=_
		"		<img border=0 src=""../images/button/submit.gif"" style=""cursor:hand"" name=btnSubmit>" & _
		"		<img border=0 src=""../images/button/clear.gif"" style=""cursor:hand"" name=btnCancel>"
	end if

	FormMeetingtable=_
		TableTitle("会议申请表", 600, "", "#0040a0") & _
		"<table cellspacing=0 cellpadding=0 width=600 align=center border=0 >" & _
		"<form name=""frmApplymeeting"" method=post action=""applymeeting.asp"">"  
		if not rs.eof then
			FormMeetingTable = FormMeetingTable & _
			"<tr height=30>" & _
			"	<td width=115 align=right>审批意见：</td>"&_
			"	<td width=485 colspan=4>" & scomment & "</td>"& _
			"</tr>" 
		end if
		FormMeetingTable = FormMeetingTable & _
		"<tr height=30>" & _
		"	<td width=115 align=right>会议主题：</td>"&_
		"	<td width=485 colspan=4><input name=""mtSubject"" value=""" & sSubject & """ size=64  type=""text"" maxlength=128></td>"& _
		"</tr>" & _
		"<tr height=30>" & _
		"	<td width=115 align=right>会议名称：</td>" & _
		"	<td width=485 colspan=4><input name=""mtName""  value=""" & sMeetingName & """ size=64  type=""text"" maxlength=128></td>"&_
		"</tr>" & _
		"<tr height = 1><td colspan=2>&nbsp;</td></tr>"&_
		"<tr height=30>" & _
		"	<td width=115 align=right>会议内容：</td>" & _
		"	<td width=485 colspan=4><textarea class=""FlatCtrl"" name=""mtTask"" rows=10 cols=62>"&sTask&"</textarea></td>"&_
		"</tr>" & _
		"<tr height=30>" & _
		"	<td width=115 align=right>召开部门：</td>" & _
		"	<td width=170><select name=department style=""WIDTH:170px"">" & OwnerDepartmentSelectOptions(iDepartment) & "</select></td>" & _
		"	<td width=80 align=right>召开地点：</td>" & _
		"	<td width=235><input name=""meeting_room"" value="""& sMeetingRoom &""" type=""text"" size=21 maxlength=25 >"& _
		"	</td>" & _
		"</tr>" & _
		"<tr height=30>" & _
		"	<td width=115 align=right>主持人：</td>" & _
		"	<td width=170><input name=presider value=""" & sPresider & """ type=""text"" size=21 maxlength=10 >"& _
		"	<td width=80 align=right>费用预算：</td>" & _
		"	<td width=235><input name=""budget"" type=""text"" size=21 maxlength=8 value=""" & fBudget & """></td>"& _
		"</tr>" & _
		"<tr height=30>" & _
		"	<td width=115 align=right>开始时间：</td>" & _
		"	<td width=170><input name=""start_time"" type=""text"" size=21 maxlength=19 value="""& dStart_time &""">" &"</td>"& _
		"	<td width=80 align=right>结束时间：</td>" & _
		"	<td width=235><input name=""stop_time"" type=""text"" size=21 maxlength=19 value="""& dStop_time &""">" &"</td>"& _
		"</tr>" & _
		"<tr height=30>" & _
		"	<td colspan=2 width=300 align=center>&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;（输入格式：2001-10-1 08:20）</td>" & _
		"	<td colspan=2 width=300 align=center>（输入格式：2001-10-1 08:20）&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;</td>" & _
		"</tr>" & _
		"<tr height=30>" & _
		"	<td width=115 align=right>公司内部&nbsp;&nbsp;<br>参会人员：</td>" & _
		"	<td width=170><select style=""width:140px"" multiple size=6 name=employee>" & GetRemainlist(sAttendee) & "</select>"& _
		"	<td width=80 align=left	><input type=button name=AddAtt value=""--->"" onclick=""JavaScript:MoveOptions(document.all.frmApplymeeting.employee,document.all.frmApplymeeting.attendee)""> <br>" & _
		"		<br><input type=button name=DelAtt value=""<---"" onclick=""JavaScript:MoveOptions(document.all.frmApplymeeting.attendee,document.all.frmApplymeeting.employee)""> </td>" & _
		"	<td width=235><select style=""width:140px""multiple size=6 name=attendee>"& GetAttendeelist(sAttendee) &"</select></td>"& _
		"</tr>" & _
		"<tr height=30>" & _
		"	<td width=115 align=right>外部人员：</td>"&_
		"	<td width=485 colspan=4><input name=""guest"" value=""" & sGuest & """ size=64  type=""text"" maxlength=100></td>"& _
		"<tr height=50>" & _
		"	<td colspan=4 align=center>" & sTempButtons & _
		"	</td>" & _
		"</tr>" & _
		"<tr height=30>" & _
		"   <input type=hidden name=rt>" & _
		"   <input type=hidden name=rm>" & _
		"   <input type=hidden name=formaction>" & _
		"   <input type=hidden name=meetingserial value="""&iMeetingSerial&""">" & _
		"</tr>" & _
		"</form>" & _
		"</table>" 
End Function


'************************************************************************************************
' 函数名　: UpdateMeeting()
' 输　入　: 
' 输　出　: 
' 功能描述: 	新增或者更新会议的数据处理，根据meetingserial的值，采取不同的操作:
'			iMeetingserial=0：新的会议申请
'			iMeetingserial<>0 :重新会议申请
' 调用模块: applymeeting.asp
' 作　者　: 蔡晓燕
' 日　期　: 2002-07-11
' 版　本　: 
'************************************************************************************************
Sub UpdateMeeting()
'	定义变量
	dim sSQL, iExecuter, sMeeting_Name, sSubject, sTask, iDepartment, sMeeting_room, sPresider, dStart_time, dApply_time
	dim dStop_time, fBudget, sAttendee, sGuest, iProposer, rt, rm, sError, sFormaction, crs, rs
'   获取表单的数据 
	iExecuter = Getofficer
	iProposer = GetEmpSerial
	sFormaction = GetParam("formaction")
	sMeeting_Name = GetParam("mtName")
	sSubject = GetParam("mtSubject")
	sTask   = GetParam("mtTask")
	iDepartment = GetParam("department")
	sMeeting_room = GetParam("meeting_room")
	sPresider = GetParam("presider")
	dStart_time = GetParam("start_time")
	dStop_time = GetParam("stop_time")
	fBudget = GetParam("budget")
	sAttendee = GetParam("attendee")
	sGuest = GetParam("guest")
	dApply_time = now()
	rt = GetParam("rt")
	rm = GetParam("rm")
'response.write "iMeetingSerial="&iMeetingSerial
'response.end
	select case sFormaction
	case "apply"
		if iMeetingserial = 0 then
			'定义新增会议的sSQL语句
			sSQL = "insert into T_MeetingPrepare(meeting_name,subject,task,department,proposer,meeting_room,"&_
				"presider,start_time,stop_time,budget,attendee,guest,meeting_status,apply_time,isconfirmed) values("&ToSQL(sMeeting_Name,"text")&_
				","&ToSQL(sSubject,"text")&","&ToSQL(sTask,"text")&","&ToSQL(iDepartment,"Number")&","&_
				ToSQL(iProposer,"Number")&","&ToSQL(sMeeting_room,"text")&","&ToSQL(sPresider,"text")&","&_
				ToSQL(dStart_time,"text")&","&ToSQL(dStop_time,"text")&","&ToSQL(fBudget,"number")&","&_
				ToSQL(sAttendee,"text")&","&ToSQL(sGuest,"text")&", 2,"&ToSQL(dApply_time,"text")&",0)"
			'执行新增会议
			sError = ExecuteSQL(dbLocal, sSQL)
			if sError <> "" then
				response.write "<script language=""javascript"">alert('对不起，添加会议申请失败！')</script>"
			else
				response.write "<script language=""javascript"">alert('会议申请已经提交办公室主任审批，请等候审批结果！')</script>"
				call CommonSendMsg(MSG_MEETING,"",sMeeting_name,"请审批我提交的会议申请！",iProposer,iExecuter)
			end if
			response.write "<script language=vbscript>window.navigate(""applymeeting.asp"")</script>"
		else
			sSQL = "select * from T_MeetingPrepare where meeting_serial = "& iMeetingSerial &" and meeting_status = 1"
			set crs = New CRecordset
			set rs = crs.open(dbLocal,sSQL)
			if not rs.eof then 
				'定义更新会议的sSQL语句
				sSQL = "update T_MeetingPrepare set meeting_name = "& ToSQL(sMeeting_Name,"text") & ", subject = " & ToSQL(sSubject,"text") &_
				", task = " & ToSQL(sTask,"text") & ", department = " & ToSQL(iDepartment,"Number") & ", meeting_room = " &_
				ToSQL(sMeeting_room,"text") & ", presider = " & ToSQL(sPresider,"text") & ", start_time = " & ToSQL(dStart_time,"text") &_
				", stop_time = " & ToSQL(dStop_time,"text") & ", budget = " & ToSQL(fBudget,"number") & ", attendee = " &_
				ToSQL(sAttendee,"text") & ", guest = " & ToSQL(sGuest,"text") & ", isconfirmed=0, meeting_status = 2  where meeting_serial=" & _
				iMeetingSerial & " and meeting_status = 1 " 
				'执行会议申请的更新
				sError = ExecuteSQL(dbLocal, sSQL)
				if sError <> "" then
					response.write "<script language=""javascript"">alert('对不起，会议重新申请失败！')</script>"
				else
					response.write "<script language=""javascript"">alert('会议申请已经提交办公室主任审批，请等候审批结果！')</script>"
				call CommonSendMsg(MSG_MEETING,"",sMeeting_name,"请审批我重新提交的会议申请！",iProposer,iExecuter)
				end if
				response.write "<script language=vbscript>window.navigate(""list_reapplymeeting.asp"")</script>"
			else
				response.write "<script language=""javascript"">alert('对不起，不存在该会议或者该会议已经重新申请过了！')</script>"
				response.write "<script language = vbscript>window.navigate(""list_reapplymeeting.asp"")</script>"
			end if
		end if
	case "del"
		sSQL = "delete from T_Meetingprepare where meeting_serial = "&iMeetingSerial
		sError = ExecuteSQL(dbLocal, sSQL)
		if sError <> "" then
			response.write "<script language=""javascript"">alert('对不起，会议申请删除失败！')</script>"
		else
			response.write "<script language=""javascript"">alert('会议申请删除成功！')</script>"
		end if
		response.write "<script language=vbscript>window.navigate(""list_reapplymeeting.asp"")</script>"
	end select
End Sub

%>