📄 list_weekmeeting.inc
字号:
<%
'************************************************************************************************
' 函数名 : TableSearch()
' 输 入 :
' 输 出 : 一个用于查询一周会议安排表的表单
' 功能描述:
' 调用模块: list_weekmeeting.asp
' 作 者 : 蔡晓燕
' 日 期 : 2002-07-18
' 版 本 :
'************************************************************************************************
Function TableSearch()
'' 开始日期的日历，DrawCal函数定义在../common/commonpage.inc
'' 结束日期的日历
TableSearch = _
TableTitle("设置查询条件", 600, "", "") & _
"<table cellspacing=0 cellpadding=0 width=600 align=center border=0 >" & _
"<form name=""frmSearchMeeting"" method=post action=""list_weekmeeting.asp"">" & _
"<tr height=20>" & _
" <td width=200>" & DrawCal("开始日期", pDay1, "day1", "dateimg1") & " </td>" & _
" <td width=200>" & DrawCal("结束日期", pDay2, "day2", "dateimg2") & "</td>" & _
" <td width=200><span id=btnSearch style=""cursor:hand"" title=""设置查询条件，然后点击查询按钮进行查询""><img border=0 src=""../images/search.gif"" style=""vertical-align:middle"">查询</span></td></tr>" & _
"<tr height=10><td colspan=3 width=600> </td></tr>" & _
"</form>" & _
"</table>"
End Function
'************************************************************************************************
' 函数名 : TableHeader()
' 输 入 :
' 输 出 : 一个用于显示一段时间内的会议列表的表头(包括5列：时间、地点、出席、会议名称、会议状态)
' 功能描述:
' 调用模块: list_weekmeeting.asp
' 作 者 : 蔡晓燕
' 日 期 : 2002-07-18
' 版 本 :
'************************************************************************************************
Function TableHeader()
Response.Write TableTitle("会议安排表", 600, "", "#0040a0")
TableHeader = _
"<table cellspacing=0 cellpadding=0 width=600 align=center class=tablelist style=""table-layout:fixed"">" & _
"<tr>" & _
"<td class=tdHead width=140 align=center> " & TableHeaderField(sFileName, "start_time", "时间", sFormParams, iSort, iSorted) & "</td>" & _
"<td class=tdHead width=70 align=center> " & TableHeaderField(sFileName, "meeting_room", "地点", sFormParams, iSort, iSorted) & "</td>" & _
"<td class=tdHead width=160 align=center> 出席 </td>" & _
"<td class=tdHead width=100> <img src=""../images/bg/ar-y.gif"" width=8 height=8> " & TableHeaderField(sFileName, "meeting_name", "会议名称", sFormParams, iSort, iSorted) & "</td>" & _
"<td class=tdHead width=130 align=center> " & TableHeaderField(sFileName, "meeting_status", "会议状态", sFormParams, iSort, iSorted) & "</td>" & _
"</tr>"
End Function
'************************************************************************************************
' 函数名 : TableRecords(sSQL, iCols, iRecordsPerPage, iTotalRecords, iCurrentPage, iTotalPages,
' sFileName, sFormParams, sSortParams)
' 输 入 : 查询语句，栏目数量，每页记录条数，总记录条数，当前页码，总页数，文件名，查询表单参数，排序参数
' 输 出 : 显示满足查询条件的会议列表
' 功能描述: 根据输入参数，显示相应的结果
' 调用模块: list_weekmeeting.asp
' 作 者 : 蔡晓燕
' 日 期 : 2002-07-18
' 版 本 :
'************************************************************************************************
Function TableRecords(sSQL, iCols, iRecordsPerPage, iTotalRecords, iCurrentPage, iTotalPages, sFileName, sFormParams, sSortParams)
dim sTemp : sTemp = "" ' 临时字符串变量
dim j ' 临时循环变量
'------------------------------------
' 分页所需的变量定义
'------------------------------------
Dim iCounter : iCounter = 1
Dim iPrevPage, iNextPage
'------------------------------------
' 获取数据库连接
'------------------------------------
dim crs : set crs = New CRecordset
dim rs : set rs = crs.open(dbLocal,sSQL)
dim sMeetingname, sAttendee, iProposer, sStart_time, iSerial, sMeetingroom, sGuest, iMeetingstatus
' 如果未到记录尾，将记录定位到你翻到的页面的第一个记录，否则显示空行
if Not rs.EOF then
rs.Move (iCurrentPage - 1) * iRecordsPerPage
end if
while not rs.EOF and iCounter <= iRecordsPerPage
sMeetingname = crs.GetValue("meeting_name")
sAttendee = crs.GetValue("attendee")
sGuest = crs.GetValue("guest")
sStart_time = crs.GetValue("start_time")
sMeetingroom = crs.GetValue("meeting_room")
iProposer = crs.GetValue("proposer")
iMeetingstatus = crs.GetValue("meeting_status")
iSerial = crs.GetValue("meeting_serial")
sTemp = sTemp & "<tr>" & _
"<td class=tdlist align=center > " & sStart_time & " </td>" & _
"<td class=tdlist nowrap title=""" & Tohtml(sMeetingroom) & """ align=left > " & ToHTML(sMeetingroom) & " </td>" & _
"<td class=tdlist nowrap title=""" & TransEmpSerial(dbLocal,sAttendee)&","&sGuest & """align=center> " & TransEmpSerial(dbLocal,sAttendee)&","&sGuest& " </td>" & _
"<td class=tdlist nowrap style=""cursor:hand"" title=""" & Tohtml(sMeetingname) & """ align=left ><a href=""weekmeeting.asp?meetingserial=" & iserial & """><img border=0 src=""../images/bg/ar-g.gif"" width=8 height=8> " & ToHTML(sMeetingname) & " </td>" & _
"<td class=tdlist nowrap title=""" & TransMeetingstatus(dbLocal,iMeetingstatus) & """ align=left> " & TransMeetingstatus(dbLocal,iMeetingstatus) & " </td>" & _
"</tr>"
iCounter = iCounter + 1
rs.movenext
wend
crs.Close()
' 填补空白行
sTemp = sTemp & WhiteRows(iCols, iCounter, iRecordsPerPage)
' 首页、前页、后页、尾页等分页信息
sTemp = sTemp & "<tr><td class=tdlist colspan=" & iCols & " align=right>" & _
Paginate(sFileName, sFormParams, sSortParams, iCurrentPage, iTotalPages) & _
" </td></tr>"
TableRecords = sTemp&"</table>"
End Function
'************************************************************************************************
' 函数名 : TableLink()
' 输 入 :
' 输 出 :
' 功能描述: 会议申请表页面上到其他页面的连接
' 调用模块: applymeeting.asp
' 作 者 : 蔡晓燕
' 日 期 : 2002-07-11
' 版 本 :
'************************************************************************************************
Function TableLink()
TableLink = _
"<table width=600 cellspacing=0 cellpadding=0 border=0 align=center>" & _
"<tr height=30>" & _
" <td width=600><img src=""../images/bg/line.gif"" width=600 height=3></td>" & _
"</tr>" & _
"<tr height=30>" & _
" <td width=600> " & _
" <img src=""../images/goto.gif"" width=11 height=11> <a href=""applymeeting.asp"">填写会议申请</a>" & _
" " & _
" <img src=""../images/goto.gif"" width=11 height=11> <a href=""list_weekmeeting.asp"">一周会议列表</a>" & _
" " & _
" <img src=""../images/goto.gif"" width=11 height=11> <a href=""list_checkmeeting.asp"">审批会议申请</a>" & _
" " & _
" <img src=""../images/goto.gif"" width=11 height=11> <a href=""list_querymeeting.asp"">会议处理</a>" & _
" " & _
" <img src=""../images/goto.gif"" width=11 height=11> <a href=""list_endmeeting.asp"">填写会议纪要</a>" & _
" " & _
" <img src=""../images/goto.gif"" width=11 height=11> <a href=""list_reapplymeeting.asp"">修改会议申请表</a></td>" & _
"</tr>" & _
"</table>"
End Function
%>⌨️ 快捷键说明
复制代码
Ctrl + C
搜索代码
Ctrl + F
全屏模式
F11
切换主题
Ctrl + Shift + D
显示快捷键
?
增大字号
Ctrl + =
减小字号
Ctrl + -