📄 list_historymeeting.inc
字号:
<%
'************************************************************************************************
' 函数名 : TableSearch()
' 输 入 :
' 输 出 : 一个用于查询会议的表单
' 功能描述:
' 调用模块: list_historymeeting.asp
' 作 者 : 蔡晓燕
' 日 期 : 2002-07-23
' 版 本 :
'************************************************************************************************
Function TableSearch()
'' 开始日期的日历，DrawCal函数定义在../common/commonpage.inc
'' 结束日期的日历
TableSearch = _
TableTitle("设置查询条件", 600, "", "") & _
"<table cellspacing=0 cellpadding=0 width=600 align=center border=0 >" & _
"<form name=""frmSearchMeeting"" method=post action=""list_historymeeting.asp"">" & _
"<tr height=30>"&_
" <td colspan=3 width=600>查询类型：<select name=""querytype"" style=""width:86px"">" & _
" <option value=0>所有会议</option>" & _
" <option value=1>历史会议</option>" & _
" <option value=2>等候召开的会议</option>" & _
" <option value=3>其余会议</option>" & _
" </select>" & _
" <script language=""javascript"">document.all.querytype.selectedIndex=" & (iType)& "</script>" & _
" </td>" & _
"</tr>"&_
"<tr height=20>" & _
" <td width=200>" & DrawCal("开始日期", pDay1, "day1", "dateimg1") & " </td>" & _
" <td width=200>" & DrawCal("结束日期", pDay2, "day2", "dateimg2") & "</td>" & _
" <td width=200><span id=btnSearch style=""cursor:hand"" title=""设置查询条件，然后点击查询按钮进行查询""><img border=0 src=""../images/search.gif"" style=""vertical-align:middle"">查询</span></td></tr>" & _
"<tr height=10><td colspan=3 width=600> </td></tr>" & _
"</form>" & _
"</table>"
End Function
'************************************************************************************************
' 函数名 : TableHeader()
' 输 入 :
' 输 出 : 一个用于显示一段时间内的会议列表的表头(包括5列：时间、地点、出席、会议名称)
' 功能描述:
' 调用模块: list_historymeeting.asp
' 作 者 : 蔡晓燕
' 日 期 : 2002-07-18
' 版 本 :
'************************************************************************************************
Function TableHeader()
Response.Write TableTitle("会议表", 600, "", "#0040a0")
TableHeader = _
"<table cellspacing=0 cellpadding=0 width=600 align=center class=tablelist style=""table-layout:fixed"">" & _
"<tr>" & _
"<td class=tdHead width=110 align=center> " & TableHeaderField(sFileName, "start_time", "时间", sFormParams, iSort, iSorted) & "</td>" & _
"<td class=tdHead width=100 align=center> " & TableHeaderField(sFileName, "meeting_room", "地点", sFormParams, iSort, iSorted) & "</td>" & _
"<td class=tdHead width=150 align=center> 出席 </td>" & _
"<td class=tdHead width=130 align=center> <img src=""../images/bg/ar-y.gif"" width=8 height=8> " & TableHeaderField(sFileName, "meeting_name", "会议名称", sFormParams, iSort, iSorted) & "</td>" & _
"<td class=tdHead width=110 align=center> " & TableHeaderField(sFileName, "meeting_status", "会议状态", sFormParams, iSort, iSorted) & "</td>" & _
"</tr>"
End Function
'************************************************************************************************
' 函数名 : TableHeader1()
' 输 入 :
' 输 出 : 一个用于显示一段时间内的会议列表的表头(包括5列：时间、地点、出席、会议名称)
' 功能描述: 用于查看所有会议，会议名称不需要连接
' 调用模块: list_historymeeting.asp
' 作 者 : 蔡晓燕
' 日 期 : 2002-08-13
' 版 本 :
'************************************************************************************************
Function TableHeader1()
Response.Write TableTitle("会议表", 600, "", "#0040a0")
TableHeader1 = _
"<table cellspacing=0 cellpadding=0 width=600 align=center class=tablelist style=""table-layout:fixed"">" & _
"<tr>" & _
"<td class=tdHead width=110 align=center> " & TableHeaderField(sFileName, "start_time", "时间", sFormParams, iSort, iSorted) & "</td>" & _
"<td class=tdHead width=100 align=center> " & TableHeaderField(sFileName, "meeting_room", "地点", sFormParams, iSort, iSorted) & "</td>" & _
"<td class=tdHead width=150 align=center> 出席 </td>" & _
"<td class=tdHead width=130 align=center> " & TableHeaderField(sFileName, "meeting_name", "会议名称", sFormParams, iSort, iSorted) & "</td>" & _
"<td class=tdHead width=110 align=center> " & TableHeaderField(sFileName, "meeting_status", "会议状态", sFormParams, iSort, iSorted) & "</td>" & _
"</tr>"
End Function
'************************************************************************************************
' 函数名 : TableRecords(sSQL, iCols, iRecordsPerPage, iTotalRecords, iCurrentPage, iTotalPages,
' sFileName, sFormParams, sSortParams)
' 输 入 : 查询语句，栏目数量，每页记录条数，总记录条数，当前页码，总页数，文件名，查询表单参数，排序参数
' 输 出 : 显示满足查询条件的会议列表
' 功能描述: 根据输入参数，显示相应的结果
' 调用模块: list_historymeeting.asp
' 作 者 : 蔡晓燕
' 日 期 : 2002-07-18
' 版 本 :
'************************************************************************************************
Function TableRecords(sSQL, iCols, iRecordsPerPage, iTotalRecords, iCurrentPage, iTotalPages, sFileName, sFormParams, sSortParams)
dim sTemp : sTemp = "" ' 临时字符串变量
dim j ' 临时循环变量
'------------------------------------
' 分页所需的变量定义
'------------------------------------
Dim iCounter : iCounter = 1
Dim iPrevPage, iNextPage
'------------------------------------
' 获取数据库连接
'------------------------------------
dim crs : set crs = New CRecordset
dim rs : set rs = crs.open(dbLocal,sSQL)
dim quanxian '判断当前用户对于查询结果是否具有查看权限
dim sMeetingname, sAttendee, iProposer, sStart_time, iSerial, sMeetingroom, sGuest, iMeetingstatus, sPriorgroup
' 如果未到记录尾，将记录定位到你翻到的页面的第一个记录，否则显示空行
if Not rs.EOF then
rs.Move (iCurrentPage - 1) * iRecordsPerPage
end if
while not rs.EOF and iCounter <= iRecordsPerPage
sMeetingname = crs.GetValue("meeting_name")
sAttendee = crs.GetValue("attendee")
sGuest = crs.GetValue("guest")
sStart_time = crs.GetValue("start_time")
sMeetingroom = crs.GetValue("meeting_room")
iProposer = crs.GetValue("proposer")
iMeetingstatus = crs.GetValue("meeting_status")
sPriorgroup = crs.GetValue("priorgroup")
iSerial = crs.GetValue("meeting_serial")
select case iType
case 0'如果是查看所有会议
quanxian = true
' quanxian = Isattendee(sAttendee,Getempserial) or Getempserial = Getofficer
case 1
'如果是查看历史会议(iType=1)，那么只有当本人属于priorgroup（即会议纪要分发对象）或者是办公室主任时才可以查看
quanxian = Isattendee(sPriorgroup,Getempserial) or Getempserial = Getofficer
case 2
'如果是查看正在进行(iType=2/iType=3)的会议，那么只有当本人属于attendee（即会议参会人员）或者是办公室主任时才可以查看
quanxian = Isattendee(sAttendee,Getempserial) or Getempserial = Getofficer
case 3
'如果是查看正在进行(iType=2/iType=3)的会议，那么只有当本人属于attendee（即会议参会人员）或者是办公室主任时才可以查看
quanxian = Isattendee(sAttendee,Getempserial) or Getempserial = Getofficer
end select
if quanxian then
sTemp = sTemp & "<tr>" & _
"<td class=tdlist align=center nowrap> " & Formatdt(sStart_time,"yyyy-mm-dd hh:mm") & " </td>" & _
"<td class=tdlist nowrap title=""" & Tohtml(sMeetingroom) & """align=left > " & ToHTML(sMeetingroom) & " </td>" & _
"<td class=tdlist nowrap title=""" & TransEmpSerial(dbLocal,sAttendee)&","&sGuest & """align=center> " & TransEmpSerial(dbLocal,sAttendee)&","&sGuest& " </td>"
select case iType
case 0'所有会议
if Isattendee(sAttendee,Getempserial) or Getempserial = Getofficer then
sTemp = sTemp & _
"<td class=tdlist nowrap title=""" & Tohtml(sMeetingname) & """ style=""cursor:hand"" align=left ><a href=""weekmeeting.asp?meetingserial=" & iserial & """><img border=0 src=""../images/bg/ar-g.gif"" width=8 height=8> " & ToHTML(sMeetingname) & " </td>"
else
sTemp = sTemp & "<td class=tdlist nowrap title=""" & Tohtml(sMeetingname) & """ align=left >"&_
ToHtml(sMeetingname)&" </td>"
end if
case 1'历史会议，连接到historymeeting.asp
sTemp = sTemp & _
"<td class=tdlist nowrap title=""" & Tohtml(sMeetingname) & """ style=""cursor:hand"" align=left ><a href=""historymeeting.asp?meetingserial=" & iserial & """><img border=0 src=""../images/bg/ar-g.gif"" width=8 height=8> " & ToHTML(sMeetingname) & " </td>"
case 2'等候召开的会议，连接到weekmeeting.asp
sTemp = sTemp & _
"<td class=tdlist nowrap title=""" & Tohtml(sMeetingname) & """ style=""cursor:hand"" align=left ><a href=""weekmeeting.asp?meetingserial=" & iserial & """><img border=0 src=""../images/bg/ar-g.gif"" width=8 height=8> " & ToHTML(sMeetingname) & " </td>"
case 3'其余会议，连接到weekmeeting.asp
sTemp = sTemp & _
"<td class=tdlist nowrap title=""" & Tohtml(sMeetingname) & """ style=""cursor:hand"" align=left ><a href=""weekmeeting.asp?meetingserial=" & iserial & """><img border=0 src=""../images/bg/ar-g.gif"" width=8 height=8> " & ToHTML(sMeetingname) & " </td>"
end select
sTemp = sTemp&"<td class=tdlist nowrap title=""" & TransMeetingstatus(dbLocal,iMeetingstatus)& """align=center> " & TransMeetingstatus(dbLocal,iMeetingstatus)& " </td></tr>"
iCounter = iCounter + 1
end if
rs.movenext
wend
crs.Close()
' 填补空白行
sTemp = sTemp & WhiteRows(iCols, iCounter, iRecordsPerPage)
' 首页、前页、后页、尾页等分页信息
sTemp = sTemp & "<tr><td class=tdlist colspan=" & iCols & " align=right>" & _
Paginate(sFileName, sFormParams, sSortParams, iCurrentPage, iTotalPages) & _
" </td></tr>"
TableRecords = sTemp&"</table>"
End Function
'************************************************************************************************
' 函数名 : TableLink()
' 输 入 :
' 输 出 :
' 功能描述: 会议申请表页面上到其他页面的连接
' 调用模块: applymeeting.asp
' 作 者 : 蔡晓燕
' 日 期 : 2002-07-11
' 版 本 :
'************************************************************************************************
Function TableLink()
TableLink = _
"<table width=600 cellspacing=0 cellpadding=0 border=0 align=center>" & _
"<tr height=30>" & _
" <td width=600><img src=""../images/bg/line.gif"" width=600 height=3></td>" & _
"</tr>" & _
"<tr height=30>" & _
" <td width=600> " & _
" <img src=""../images/goto.gif"" width=11 height=11> <a href=""applymeeting.asp"">填写会议申请</a>" & _
" " & _
" <img src=""../images/goto.gif"" width=11 height=11> <a href=""list_historymeeting.asp"">一周会议列表</a>" & _
" " & _
" <img src=""../images/goto.gif"" width=11 height=11> <a href=""list_checkmeeting.asp"">审批会议申请</a>" & _
" " & _
" <img src=""../images/goto.gif"" width=11 height=11> <a href=""list_querymeeting.asp"">会议处理</a>" & _
" " & _
" <img src=""../images/goto.gif"" width=11 height=11> <a href=""list_endmeeting.asp"">填写会议纪要</a>" & _
" " & _
" <img src=""../images/goto.gif"" width=11 height=11> <a href=""list_reapplymeeting.asp"">修改会议申请表</a></td>" & _
"</tr>" & _
"</table>"
End Function
%>⌨️ 快捷键说明
复制代码
Ctrl + C
搜索代码
Ctrl + F
全屏模式
F11
切换主题
Ctrl + Shift + D
显示快捷键
?
增大字号
Ctrl + =
减小字号
Ctrl + -