📄 ccard_g.asp

📁 物业管理和办公自动化系统
💻 ASP
字号:
<%
'************************************************************************************************
' 文件名: ccard_g.asp
' Copyright(c) 2001-2002 上海阿尔卡特网络支援系统有限公司
'
' 　创建人 : 周秋舫
' 　日　期 : 2002-05-13
' 修改历史 :
'   ****年**月**日 ****** 修改内容:**************************************************
' 功能描述 : 通讯录类别管理页面
' 　版　本 :
'************************************************************************************************
option explicit
Response.CacheControl = "no-cache"
Response.AddHeader "Pragma", "no-cache"
Response.Expires = -1
'response.end
%>

<!-- #include file="../include/config.inc" -->
<!-- #include file="../include/common.inc" -->
<!-- #include file="../include/debug.inc" -->
<!-- #include file="../include/db.inc" -->
<!-- #include file="../include/date.inc" -->
<!-- #include file="../include/datahandle.inc" -->
<!-- #include file="../include/recordlist.inc" -->
<!-- #include file="../include/security.inc" -->

<!-- #include file="../common/commonpage.inc" -->
<!-- #include file="ccard_g.inc" -->

<%
call CheckSecurity()

'' 如果不是单位名录管理员，则无权进入本页
if Not IsCustomerAdmin then
	Response.Clear
	Response.Redirect("../common/error.asp?error=只有单位名录管理员才能进行单位名录管理&")
	Response.end
end if


'********************************************************************************************************
' 服务器端代码
Dim pGroupId : pGroupId = GetParam("group_id")
Dim sGroupDesp
if Not IsEmpty(pGroupId) then
	sGroupDesp = DLookUp(dbLocal, "t_customercardgroup", "group_desp", "group_id = " & ToSQL(pGroupId, "Number"))
	if sGroupDesp = "" then
		Response.Redirect "../common/error.asp"
		Response.end
	end if
end if

'********************************************************************************************************
' 如果是提交，则调用函数InsertGroup或UpdateGroup或DeleteGroup更新数据库
Dim sFormAction
if UCase(Request.ServerVariables("REQUEST_METHOD") = "POST") then
	sFormAction = GetParam("FormAction")
	sGroupDesp = GetParam("group_desp")
	select case sFormAction
	case "insert":
		call AddGroup()
	case "update":
		call UpdateGroup()
	case "delete":
		call DeleteGroup()
	end select
end if

'-------------------------------------------------------------------------------------------------------------------------------------------------
' 分页相关的变量定义
'-------------------------------------------------------------------------------------------------------------------------------------------------
Dim sSQL, sWhere, sOrderby
Dim sFileName			: sFileName = "ccard_g.asp"
Dim iTotalRecords		: iTotalRecords = 0			' 分页
Dim iRecordsPerPage	: iRecordsPerPage = 12
Dim iTotalPages			: iTotalPages = 0
Dim iCols					: iCols = 1
Dim iCurrentPage		: iCurrentPage = GetParam("Page")
Dim iSort					: iSort = GetParam("Sorting")
Dim iSorted				: iSorted = GetParam("Sorted")
Dim sSortParams		: sSortParams = ""
Dim sFormParams		: sFormParams = ""
Dim sDirection			: sDirection = ""

''********************************************************************************************************
'' 构造分页的SQL语句
''********************************************************************************************************
sSQL = "select group_id, group_desp from t_customercardgroup order by group_desp"

'********************************************************************************************************
' 分页SQL语句构造完毕，调用PrepareListData进行分页前的准备
'-------------------------------------------------------------------------------------------------------------------------------------------------
dim arrayFields(1), sDelimiter
sDelimiter = "*"
arrayFields(0) = "group_desp"
call PrepareListData(sSQL, Join(arrayFields, sDelimiter), sDelimiter)
'********************************************************************************************************
%>

<html>
<head>
<title>上海信息大楼 Shanghai Information Tower</title>
<meta http-equiv="Content-Type" content="text/html; charset=gb2312">
<link rel="stylesheet" href="../common/common.css" type="text/css">
<style type="text/css">
input {color:blue;border-width:1}
</style>
<script language="javascript" src="ccard_g.js"></script>
</head>

<body bgcolor="#FFFFFF" leftmargin="0" topmargin="0" marginwidth="0" marginheight="0" background="../images/bg/bg0.jpg">
<br>

<%
Response.Write OuterTableHeader
Response.Write HeaderWithMenu
Response.Write InnerTableHeader
'********************************************************************************************************
' 主体从这里开始
'-------------------------------------------------------------------------------------------------------------------------------------------------
Response.Write _
	"<table cellspacing=1 cellpadding=0 border=0 bgcolor=navy>" & _
	"<tr>" & _
	"<td width=300 valign=top>" & _
			ListTableHeader & _
			ListTableRecords(sSQL, iCols, iRecordsPerPage, iTotalRecords, iCurrentPage, iTotalPages, sFileName, sFormParams, sSortParams ) & _
			ListTableTailer() & _
	"</td>" & _
	"<td width=300 valign=top>" & _
			FormTable & _
	"</td></tr></table>"

Response.Write TableLink
'-------------------------------------------------------------------------------------------------------------------------------------------------
' 主体到这里结束
'********************************************************************************************************
Response.Write InnerTableTailer
Response.Write Footer
Response.Write OuterTableTailer
%>

</body>
</html>
⌨️ 快捷键说明

复制代码 Ctrl + C
搜索代码 Ctrl + F
全屏模式 F11
切换主题 Ctrl + Shift + D
显示快捷键 ?
增大字号 Ctrl + =
减小字号 Ctrl + -