ccard_l.asp

物业管理和办公自动化系统

<%
'************************************************************************************************
' 文件名: ccard_l.asp
' Copyright(c) 2001-2002 上海阿尔卡特网络支援系统有限公司
'
' 　创建人 : 周秋舫
' 　日　期 : 2002-05-13
' 修改历史 :
'   ****年**月**日 ****** 修改内容:**************************************************
' 功能描述 : 通讯录查询列表
' 　版　本 :
'************************************************************************************************
option explicit
Response.CacheControl = "no-cache"
Response.AddHeader "Pragma", "no-cache"
Response.Expires = -1
'response.end
%>

<!-- #include file="../include/config.inc" -->
<!-- #include file="../include/common.inc" -->
<!-- #include file="../include/debug.inc" -->
<!-- #include file="../include/db.inc" -->
<!-- #include file="../include/date.inc" -->
<!-- #include file="../include/datahandle.inc" -->
<!-- #include file="../include/recordlist.inc" -->
<!-- #include file="../include/security.inc" -->

<!-- #include file="../common/commonpage.inc" -->
<!-- #include file="ccard_l.inc" -->

<%
call CheckSecurity()

'********************************************************************************************************
' 服务器端代码

'-------------------------------------------------------------------------------------------------------------------------------------------------
' 分页相关的变量定义
'-------------------------------------------------------------------------------------------------------------------------------------------------
Dim sSQL, sWhere, sOrderby
Dim sFileName			: sFileName = "ccard_l.asp"
Dim iTotalRecords		: iTotalRecords = 0			' 分页
Dim iRecordsPerPage	: iRecordsPerPage = 12
Dim iTotalPages			: iTotalPages = 0
Dim iCols					: iCols = 5
Dim iCurrentPage		: iCurrentPage = GetParam("Page")
Dim iSort					: iSort = GetParam("Sorting")
Dim iSorted				: iSorted = GetParam("Sorted")
Dim sSortParams		: sSortParams = ""
Dim sFormParams		: sFormParams = ""
Dim sDirection			: sDirection = ""

'-----------------------------------------------------------------------------------------------------'
' 查询参数，组，是否公开，姓名关键字，单位名称关键字
'-----------------------------------------------------------------------------------------------------
dim pCardGroup			: pCardGroup = GetParam("card_group")
if IsEmpty(pCardGroup) then pCardGroup = -1

dim pContactPerson	: pContactPerson	= GetParam("contact_person")
dim pCompanyName	: pCompanyName	= GetParam("name")
dim pCompanyAddr	: pCompanyAddr	= GetParam("address")

sFormParams = "card_group=" & pCardGroup & "&contact_person=" & pContactPerson & "&name=" & pCompanyName & "&address=" & pCompanyAddr & "&"


''********************************************************************************************************
'' 构造分页的SQL语句
''********************************************************************************************************
sSQL = "select t1.serial, t2.group_desp as card_group_desp, t1.name, t1.address, t1.zip, t1.contact_person, t1.contact_phone, t1.fax, t1.email, t1.remark from t_customercard t1, t_customercardgroup t2"

'' 我的个人名片
sWhere = "  where t1.card_group = t2.group_id"

sOrderby = " order by t1.serial desc"

''********************************************************************************************************
'' 查询条件限制
''********************************************************************************************************
if pCardGroup >= 0 then sWhere = sWhere & " and card_group = " & pCardGroup
if Not IsEmpty(pContactPerson) then sWhere = sWhere & " and contact_person like " & ToSQL("%" & pContactPerson & "%","Text")
if Not IsEmpty(pCompanyName) then sWhere = sWhere & " and name like " & ToSQL("%" & pCompanyName & "%","Text")

'********************************************************************************************************
' 分页SQL语句构造完毕，调用PrepareListData进行分页前的准备
'-------------------------------------------------------------------------------------------------------------------------------------------------
dim arrayFields(7), sDelimiter
sDelimiter = "*"
arrayFields(0) = "name"
arrayFields(1) = "contact_phone"
arrayFields(2) = "contact_person"
arrayFields(3) = "fax"
arrayFields(4) = "email"
arrayFields(5) = "address"
arrayFields(6) = "zip"
arrayFields(7) = "card_group"
call PrepareListData(sSQL & sWhere & sOrderby, Join(arrayFields, sDelimiter), sDelimiter)
'********************************************************************************************************
%>

<html>
<head>
<title>上海信息大楼 Shanghai Information Tower</title>
<meta http-equiv="Content-Type" content="text/html; charset=gb2312">
<link rel="stylesheet" href="../common/common.css" type="text/css">

<script language="VBScript">
Sub btnSearch_OnClick()
	document.all.frmSearch.submit()
End Sub
</script>
</head>

<body bgcolor="#FFFFFF" leftmargin="0" topmargin="0" marginwidth="0" marginheight="0" background="../images/bg/bg0.jpg">
<br>

<%
Response.Write OuterTableHeader
Response.Write HeaderWithMenu
Response.Write InnerTableHeader
'********************************************************************************************************
' 主体从这里开始
'-------------------------------------------------------------------------------------------------------------------------------------------------
Response.Write TableSearch

Response.Write TableHeader
Response.Write TableRecords(sSQL & sWhere & sOrderby, iCols, iRecordsPerPage, iTotalRecords, iCurrentPage, iTotalPages, sFileName, sFormParams, sSortParams )

Response.Write TableLink
'-------------------------------------------------------------------------------------------------------------------------------------------------
' 主体到这里结束
'********************************************************************************************************
Response.Write InnerTableTailer
Response.Write Footer
Response.Write OuterTableTailer
%>

</body>
</html>