booklist.inc

物业管理和办公自动化系统

<%
'#############################################################################################
'#
'#	文件名	 : booklist.inc
'#	Copyright(c) 2001-2002 上海阿尔卡特网络支援系统有限公司
'#
'#	创建人	 : BinZha
'#  日　期	 : 2002-07-19
'#
'#	修改历史  : ****年**月**日 ****** 修改内容:**********************************************
'#
'#	功能描述	 : 图书列表函数文件
'#  版  　本	 :
'#
'#############################################################################################

Function TableSearch()
	'' 申请日期的日历，DrawCal函数定义在../common/commonpage.inc

	TableSearch = _
		TableTitle("设 置 查 询 条 件", 600, "", "") & _
		"<table cellspacing=0 cellpadding=0 width=600 align=center border=0>" & _
		"<form name=""frmSearch"" method=post action=""booklist.asp"">" & _
		"<tr height=30>" & _
		"	<td width=220>书名：&nbsp;<input type='text' name='name' value='" & pName & "'>" & "</td>" & _
		"	<td width=200>类别：&nbsp;&nbsp;<input type='text' name='type' value='" & pType & "'>" & "</td>" & _
		"	<td width=180>状态：&nbsp;<select name=""status"" style=""width:100px"">" & _
		"					<option value='*'>全部</option>" & _
					                SelectOptions(dbLocal,"t_library_status","status","status",""&pStatus&"","") & _
		"						   </select></td>" & _
		"</tr>" & _
		"<tr height=30>" & _
		"	<td width=220>作者：&nbsp;<input type=text name='author' value='" & pAuthor & "'>" & "</td>" & _
		"	<td width=200>出版社：<input type=text name='publisher' value='" & pPublisher & "'>" & "</td>" & _	
		"	<td width=180>&nbsp;&nbsp;&nbsp;&nbsp;<span id=btnSearch style=""cursor:hand"" title=""设置查询条件，然后点击查询按钮进行查询""><img border=0 src=""../images/search.gif"" style=""vertical-align:middle"">查询</span></td>" & _
		"</tr>" & _
		"<tr height=10><td colspan=3</td></tr>" & _
		"</form>" & _
		"</table>"
End Function

Function TableHeader(sHeader)
	TableHeader = _
		"<table cellspacing=0 cellpadding=0 width=600 align=center class=tablelist>" & _
		"<tr>" & _
		"<td colspan=" & iCols & " bgcolor=""#0040a0"" align=center style=""color:white;font-weight:600"" height=20 >" & sHeader & "</td></tr>" & _
		"<tr>" & _
		"<td class=tdHead width=160>&nbsp;<img src=""../images/bg/ar-y.gif"" width=8 height=8>&nbsp;" & TableHeaderField(sFileName, "Name", "书名", sFormParams, iSort, iSorted) & "</td>" & _
		"<td class=tdHead width=100>&nbsp;" & TableHeaderField(sFileName, "Author", "作者", sFormParams, iSort, iSorted) & "</td>" & _
		"<td class=tdHead width=160>&nbsp;" & TableHeaderField(sFileName, "Publisher", "出版社", sFormParams, iSort, iSorted) & "</td>" & _
		"<td class=tdHead width=70>&nbsp;" & TableHeaderField(sFileName, "Type", "类别", sFormParams, iSort, iSorted) & "</td>" & _
		"<td class=tdHead width=60>&nbsp;" & TableHeaderField(sFileName, "UserName", "借阅人", sFormParams, iSort, iSorted) & "</td>" & _
		"</tr>"
End Function

Function TableRecords(sSQL, iCols, iRecordsPerPage, iTotalRecords, iCurrentPage, iTotalPages, sFileName, sFormParams, sSortParams)
	dim sTemp				: sTemp = ""	' 临时字符串变量
	dim j					' 临时循环变量

	'------------------------------------
	' 分页所需的变量定义
	'------------------------------------
	Dim iCounter			: iCounter = 1
	Dim iPrevPage, iNextPage
	
	'------------------------------------
	' 获取数据库连接
	'------------------------------------
	dim crs					: set crs = New CRecordset
	dim rs					: set rs = crs.open(dbLocal,sSQL)
	dim ID, sName, sAuthor, sPublisher, sType, sUserName, sReturnDate

	' 如果未到记录尾，将记录定位到你翻到的页面的第一个记录，否则显示空行
	if Not rs.EOF then	
		rs.Move (iCurrentPage - 1) * iRecordsPerPage
	end if
	while not rs.EOF and iCounter <= iRecordsPerPage
		ID					= crs.GetValue("ID")
		sName				= crs.GetValue("Name")
		sAuthor				= crs.GetValue("Author")
		sPublisher			= crs.GetValue("Publisher")
		sType				= crs.GetValue("Type")
		sUserName			= crs.GetValue("UserName")
		sReturnDate			= crs.GetValue("ReturnDate")

		if sReturnDate < date then
			sTemp = sTemp & _
					"<tr bgcolor=white>" & _
					"	<td class=tdlist title=""" & sName & """ style=""cursor:hand"" onclick=""javascript:location.href='bookinfo.asp?id=" & ID & "';"">&nbsp;<img src=""../images/bg/ar-g.gif"" width=8 height=8><font color=red><strong>&nbsp;" & Bref(sName,18) & "&nbsp;</strong></font></td>" & _
					"	<td class=tdlist title=""" & sAuthor & """ align=left><font color=red><strong>&nbsp;" & Bref(sAuthor,10) & "&nbsp;</strong></font></td>" & _
					"	<td class=tdlist title=""" & sPublisher & """ align=left><font color=red><strong>&nbsp;" & Bref(sPublisher,18) & "&nbsp;</strong></font></td>" & _
					"	<td class=tdlist title=""" & sType & """ align=left><font color=red><strong>&nbsp;" & Bref(sType, 8) & "&nbsp;</strong></font></td>" & _
					"	<td class=tdlist title=""" & sUserName & """><font color=red><strong>&nbsp;" & Bref(sUserName, 8) & "&nbsp;</strong></font></td>" & _
					"</tr>"
		else
			sTemp = sTemp & _
					"<tr bgcolor=white>" & _
					"	<td class=tdlist title=""" & sName & """ style=""cursor:hand"" onclick=""javascript:location.href='bookinfo.asp?id=" & ID & "';"">&nbsp;<img src=""../images/bg/ar-g.gif"" width=8 height=8>&nbsp;" & Bref(sName,18) & "&nbsp;</td>" & _
					"	<td class=tdlist title=""" & sAuthor & """ align=left>&nbsp;" & Bref(sAuthor,10) & "&nbsp;</td>" & _
					"	<td class=tdlist title=""" & sPublisher & """ align=left>&nbsp;" & Bref(sPublisher,18) & "&nbsp;</td>" & _
					"	<td class=tdlist title=""" & sType & """ align=left>&nbsp;" & Bref(sType, 8) & "&nbsp;</td>" & _
					"	<td class=tdlist title=""" & sUserName & """>&nbsp;" & Bref(sUserName, 8) & "&nbsp;</td>" & _
					"</tr>"
		end if
		iCounter = iCounter + 1
		rs.movenext
	wend
	crs.Close()

	' 填补空白行
	sTemp = sTemp & WhiteRows(iCols, iCounter, iRecordsPerPage)

	' 首页、前页、后页、尾页等分页信息
	sTemp = sTemp & "<tr bgcolor=white><td class=tdlist colspan=" & iCols & " align=right>" & _
				Paginate(sFileName, sFormParams, sSortParams, iCurrentPage, iTotalPages) & _
				"&nbsp;</td></tr></table>"
	TableRecords = sTemp
End Function


Function TableLink()
	if IsLibraryAdmin() then
		TableLink = _
			"<table width=600 cellspacing=0 cellpadding=0 border=0 align=center>" & _
			"<tr height=10>" & _ 
			"	<td width=600><img src=""../images/bg/line.gif"" width=600 height=3></td>" & _
			"</tr>" & _
			"<tr height=20>" & _
			"	<td width=600>&nbsp;" & _
			"		<img src=""../images/goto.gif"">&nbsp;<a href=""bookedit.asp"">新增图书</a>&nbsp;&nbsp;&nbsp;" & _
				"	<img src=""../images/goto.gif"">&nbsp;<a href=""booktype.asp"">类别管理</a>" & _
			"	</td>" & _
			"</tr>" & _
			"</table>"
	end if
End Function
%>