booklist.asp

物业管理和办公自动化系统

<%
'################################################################################################
'#
'#	 文件名	 : booklist.asp	
'#	Copyright(c) 2001-2002 上海阿尔卡特网络支援系统有限公司
'#
'#	 创建人	 : BinZha
'# 　日　期	 : 2002-07-19
'#
'#	修改历史  : ****年**月**日 ****** 修改内容:**************************************************
'#
'#	功能描述	 : 图书列表
'#   版 　本	 :
'#
'################################################################################################

'----------------------------------------------------------
' 服务器端设置
'----------------------------------------------------------
option explicit
Response.CacheControl = "no-cache"
Response.AddHeader "Pragma", "no-cache"
Response.Expires = -1
%>

<!-- include files begin -->

<!-- #include file="../include/config.inc" -->
<!-- #include file="../include/common.inc" -->
<!-- #include file="../include/debug.inc" -->
<!-- #include file="../include/db.inc" -->
<!-- #include file="../include/date.inc" -->
<!-- #include file="../include/datahandle.inc" -->
<!-- #include file="../include/recordlist.inc" -->
<!-- #include file="../include/security.inc" -->

<!-- #include file="../common/commonpage.inc" -->

<!-- #include file="booklist.inc" -->

<!-- include files end -->

<%
'call CheckSecurity()

'********************************************************************************************************
' 服务器端代码
'
'-------------------------------------------------------------------------------------------------------
' 分页相关的变量定义
'-----------------------------------------------------------------------------------------------------------
Dim sSQL, sWhere, sOrderby
Dim sFileName			: sFileName			= "booklist.asp"
Dim iEmpSerial			: iEmpSerial		= GetEmpSerial
Dim sEmpName			: sEmpName			= GetUserName
Dim iTotalRecords		: iTotalRecords		= 0			' 分页
Dim iRecordsPerPage		: iRecordsPerPage	= 10
Dim iTotalPages			: iTotalPages		= 0
Dim iCols				: iCols				= 5
Dim iCurrentPage		: iCurrentPage		= GetParam("Page")
Dim iSort				: iSort				= GetParam("Sorting")
Dim iSorted				: iSorted			= GetParam("Sorted")
Dim sSortParams			: sSortParams		= ""
Dim sFormParams			: sFormParams		= ""
Dim sDirection			: sDirection		= ""

'-----------------------------------------------------------------------------------------------------'
' 查询参数，组，是否公开，姓名关键字，单位名称关键字
'-----------------------------------------------------------------------------------------------------
dim pName				: pName				= GetParam("name")
dim pAuthor				: pAuthor			= GetParam("author")
dim pPublisher			: pPublisher		= GetParam("publisher")
dim pType				: pType				= GetParam("type")
dim pStatus				: pStatus			= GetParam("status")

sFormParams = "name=" & pName & "&author=" & pAuthor & "&publisher=" & pPublisher & "&type=" & pType & "&status=" & pStatus & "&"

'********************************************************************************************************
' 构造分页的SQL语句
'--------------------------------------------------------------------------------------------------------
sSQL = "select T1.ID as ID, T1.Name as Name, T1.Author as Author, T1.Publisher as Publisher, T2.Title as Type, T3.Name as UserName, ReturnDate as ReturnDate" & _
		" from T_Library T1 left join T_Library_Type T2 on T1.TypeID = T2.ID" & _
		" left join T_Employee as T3 on T1.UserName = T3.Serial" 
sWhere = " where 1 = 1" 
sOrderby = " order by ID desc"

'********************************************************************************************************

'********************************************************************************************************
' 查询条件限制
'--------------------------------------------------------------------------------------------------------
if Not IsEmpty(pName) then sWhere = sWhere & " and T1.Name like " & ToSQL("%" & pName & "%","Text")
if Not IsEmpty(pAuthor) then sWhere = sWhere & " and T1.Author like " & ToSQL(pAuthor,"Text")
if Not IsEmpty(pPublisher) then sWhere = sWhere & " and T1.Publisher like " & ToSQL(pPublisher,"Text")
if Not IsEmpty(pType) then sWhere = sWhere & " and T1.TypeID in (select ID from T_Library_Type where Title like " & ToSQL("%" & pType & "%","Text") & ")"
if Not (IsEmpty(pStatus) or pStatus = "*") then
	if pStatus = "过期" then 
		sWhere = sWhere & " and T1.ReturnDate < " & ToSQL(date,"Text")
	else
		sWhere = sWhere & " and T1.status like " & ToSQL(pStatus,"Text")
	end if
end if
'********************************************************************************************************

'********************************************************************************************************
' 分页SQL语句构造完毕，调用PrepareListData进行分页前的准备
'--------------------------------------------------------------------------------------------------------
dim arrayFields(5), sDelimiter
sDelimiter = "*"
arrayFields(0)	=	"Name"
arrayFields(1)	=	"Author"
arrayFields(2)	=	"Publisher"
arrayFields(3)	=	"Type"
arrayFields(4)	=	"UserName"

call PrepareListData(sSQL & sWhere & sOrderby, Join(arrayFields, sDelimiter), sDelimiter)
'********************************************************************************************************
%>

<html>
<head>
<title>上海信息大楼 Shanghai Information Tower</title>
<meta http-equiv="Content-Type" content="text/html; charset=gb2312">
<link rel="stylesheet" href="../common/common.css" type="text/css">

<!-- 日历 begin -->
<IFRAME style="display:none;position:absolute;width:148;height:194;z-index=100" ID="CalFrame" MarginHeight=0 MarginWidth=0 noresize frameborder=0 scrolling=no src="../common/cal/calendar.htm"></IFRAME>
<script language="javascript" src="../common/cal/calendar.js"></script>
<script for=document event="onclick()">
<!--
document.all.CalFrame.style.display="none";
//-->
</script>
<!-- 日历 end -->

<script language="VBScript">
Sub btnSearch_OnClick()
	document.all.frmSearch.submit()
End Sub
</script>
</head>

<body bgcolor="#FFFFFF" leftmargin="0" topmargin="0" marginwidth="0" marginheight="0" background="../images/bg/bg0.jpg">
<br>

<%
Response.Write OuterTableHeader
Response.Write HeaderWithMenu
Response.Write InnerTableHeader
'********************************************************************************************************
' 主体从这里开始
'--------------------------------------------------------------------------------------------------------
Response.Write TableSearch

Response.Write TableHeader("图书列表")

Response.Write TableRecords(sSQL & sWhere & sOrderby, iCols, iRecordsPerPage, iTotalRecords, iCurrentPage, iTotalPages, sFileName, sFormParams, sSortParams )


Response.Write TableLink
'--------------------------------------------------------------------------------------------------------
' 主体到这里结束
'********************************************************************************************************
Response.Write InnerTableTailer
Response.Write Footer
Response.Write OuterTableTailer
%>

</body>
</html>