node_oe.inc

物业管理和办公自动化系统

<%
function TableFormNode()

	'' 新增岗位或新增部门信息，修改岗位或修改部门信息
	dim sDesp, sFunc, sOther
	dim sParent
	if pNodeLevel = 2 then
			sDesp = "部门名称"
			sFunc = "部门职能"
	elseif pNodeLevel = 3 then
			sDesp = "岗位名称"
			sFunc = "岗位职责"
	end if
	
	
	dim sButtons
	if IsEmpty(pNodeId) then		'' 新增
		if pNodeLevel = 2 then 
				sParentNodeId = DLookUp(dbLocal, "t_node", "min(node_id)", "co_id=" & GetCoId)
		end if
		sButtons = "<tr><td colspan=2 align=center>" & vbLF & _
						"<img border=0 src=""../images/button/add.gif"" name=""btnAdd"" style=""cursor:hand"">" & vbLF & _
						"&nbsp;&nbsp;" & vbLF & _
						"<img border=0 src=""../images/button/clear.gif"" name=""btnReset"" style=""cursor:hand"">" & vbLF & _
						"</td></tr>" & vbLF
	else										'' 修改/删除
		sParentNodeId = DLookUp(dbLocal, "t_node", "parent_node_id", "node_id=" & pNodeId)
		sButtons = "<tr><td colspan=2 align=center>" & vbLF & _
						"<img border=0 src=""../images/button/update.gif"" name=""btnUpdate"" style=""cursor:hand"">" & vbLF & _
						"&nbsp;&nbsp;" & vbLF & _
						"<img border=0 src=""../images/button/delete.gif"" name=""btnDelete"" style=""cursor:hand"">" & vbLF & _
						"&nbsp;&nbsp;" & vbLF & _
						"<img border=0 src=""../images/button/reset.gif"" name=""btnReset"" style=""cursor:hand"">" & vbLF
	end if

	if pNodeLevel = 2 then
			'' 部门
			sParent = "<tr style=""display:none"">" & vbLF & _
						"		<td colspan=2><input type=""hidden"" name=""parent_node_id"" value=""" & sParentNodeId & """></td></tr>" & vbLF
	else
			'' 岗位，有对应的职务
			sOther = "<tr>" & vbLF & _
						"		<td align=center>对应职务：</td>" & vbLF & _
						"		<td><select name=""pos"">" & vbLF & _
										selectOptions(dbLocal, "t_position", "position_id", "position_desc", sPos, "") & vbLF & _
						"					</select></td></tr>" & vbLF

			sParent = "<tr>" & vbLF & _
						"		<td align=center>所属部门：</td>" & vbLF & _
						"		<td><select name=""parent_node_id"" style=""width:300"">" & _
										selectOptions(dbLocal, "t_node", "node_id", "node_name", sParentNodeId, "node_level=2 and co_id = " & GetCoId) & vbLF & _
						"				</select></td></tr>" & vbLF

	end if

	TableFormNode = _
		"<table cellspacing=1 cellpadding=3 bgcolor=""white"" border=0 align=center width=400>" & vbLF & _
			sParent & _
		"<tr>" & vbLF & _
		"		<td width=70 align=center>" & sDesp & "：</td>" & vbLF &  _
		"		<td width=310><input type=""text"" name=""node_name"" value=""" & sNodeName & """></td></tr>" & vbLF & _
		"<tr>" & vbLF & _
		"		<td width=70 align=center>" & sFunc & "：</td>" & vbLF & _
		"		<td width=310><textarea name=""node_func"" rows=10 cols=48>" & sNodeFunc & "</textarea></td></tr>" & vbLF & _
		sButtons & _
		"</table>" & vbLF

end function


sub DoAction()
	dim sFormAction	 : sFormAction = GetParam("FormAction")
	dim sSQL, sWhere
	dim iRows

	if pNodeLevel = 2 then sPos = 0
	if IsEmpty(pNodeId) then	'' 作新增操作
			sSQL = "insert into t_node(node_level, node_name, node_func, parent_node_id, pos, co_id)" & _
						" values(" & ToSQL(pNodeLevel, "Number") & _
						", " & ToSQL(sNodeName, "Text") & _
						", " & ToSQL(sNodeFunc, "Text") & _
						", " & ToSQL(sParentNodeId, "Number") & _
						", " & ToSQL(sPos, "Number") & _
						", " & ToSQL(GetCoId, "Number") & _
						")"
	else									'' 作修改或删除操作
			if sFormAction = "update" then
				sSQL = "update t_node set node_name = " & ToSQL(sNodeName, "Text") & _
							", node_func = " & ToSQL(sNodeFunc, "Text") & _
							", parent_node_id = " & ToSQL(sParentNodeId, "Number") & _
							", pos = " & ToSQL(sPos, "Number") & _
							" where node_id = " & ToSQL(pNodeId, "Number")
			elseif sFormAction = "delete" then

				'' 删除前先作检查，看t_employee表中是否有相应的部门岗位信息，如果有，则不作删除
				if pNodeLevel = 2 then	'' 删除部门信息
					sWhere = "node_id in (select node_id from t_node where parent_node_id = " &  pNodeId & ")"
				elseif pNodeLevel = 3 then	'' 删除岗位信息
					sWhere = "node_id = " & pNodeId & " and dismissed=0"
				end if
				
				iRows = DLookUp(dbLocal, "t_employee", "count(*)", sWhere)
				if iRows > 0 then		'' 有相关记录，不能删除
					Response.Write "<script language=""javascript"">alert('有在职员工属于该部门/岗位，不能删除');</script>"
					exit sub
				end if

				'' 如果删除部门，检查是否有跟该部门相关的会议，如果有，则不能删除
				if pNodeLevel = 2 then
					iRows = DLookUp(dbLocal, "t_meetingprepare", "count(*)", "department = " & pNodeId)
					if iRows > 0 then
						Response.Write "<script language=""javascript"">alert('有属于该部门的会议，因此不能删除该部门');</script>"
						exit sub
					end if
				end if
				
				if pNodeLevel = 2 then ''	 删除部门
					sSQL = "delete from t_node" & _
							" where node_id = " & ToSQL(pNodeId, "Number") & _
							" or parent_node_id = " & ToSQL(pNodeId, "Number")
				elseif pNodeLevel = 3 then	 '' 删除岗位
					sSQL = "delete from t_node where node_id = " & ToSQL(pNodeId, "Number")
				end if
			end if
	end if

	if sSQL <> "" then
		'response.write "sql statement:<br>" & sSQL & "<br>"
		call ExecuteSQL(dbLocal, sSQL)
		Response.Write "<script language=""javascript"">window.parent.location.href='node_o.asp';</script>"
	end if
end sub
%>